Simple Examples

Community Forums/Monkey2 Talk/Simple Examples

impixi

(Posted 2016) [#1]

Here are some simple examples demonstrating a few of Monkey 2's language features. Hopefully self explanatory but let me know if not...

I'll post more examples later as I get the time.

(Not sure if I should post this thread here or on the Monkey2 dev forums?)

********
Pointers
********

pointers1.monkey2


'Pointers Simple Example 
'Reference(s):
'https://en.wikipedia.org/wiki/Pointer_(computer_programming)

'NOTE: It is NOT recommended to use pointers to Monkey2 objects.
'This code is for demonstration purposes only, and may 'break' in a future
'MX2 compiler release.

#Import "<std.monkey2>"

Using std

Function Main()
	
	Local obj1 := New MyClass("Object 1")
	Local obj2 := New MyClass("Object 2")
	
	Local ptrObj:MyClass Ptr 
	
	ptrObj=Varptr(obj1)
	Print Cast<MyClass Ptr>(ptrObj)[0].Label
	
	ptrObj = Varptr(obj2)
	Print Cast<MyClass Ptr>(ptrObj)[0].Label

End

Class MyClass
	Private 
		Field _label:String
		
	Public
		Method New(label:String)
			Label = label
		End
	
		Property Label:String()
			Return _label
		Setter (label:String)
			_label = label
		End
End

pointers2.monkey2


'Pointers Simple Example 2
'Reference(s):
'https://en.wikipedia.org/wiki/Pointer_(computer_programming)

#Import "<std.monkey2>"

Using std

Function Main()

	Local myInt:Int = 5
	Print "Before modification: " + myInt
	
	ModifyByAddress(Varptr(myInt))
	Print "After modification: " + myInt
	
End

Function ModifyByAddress:Void(pInt:Int Ptr)
	Cast<Int Ptr>(pInt)[0] = 10
End

*****************
Function Pointers
*****************

fp1.monkey2


'Function Pointers Simple Example
'Reference(s):
'https://en.wikipedia.org/wiki/Function_pointer

#Import "<std.monkey2>"

Using std

Function Main()

	Local n1:Int = 7
	Local n2:Int = 5
	
	Print n1 + " + " + n2 + " = " + Operation(n1, n2, Add)
	Print n1 + " - " + n2  + " = " + Operation(n1, n2, Subtract) 

End

Function Add:int(first:Int, second:Int)
	Return first+second
End

Function Subtract:int(first:Int, second:Int)
	Return first-second
End

Function Operation:Int(first:Int, second:Int, func:Int(Int, Int))
	Return func(first, second)
End

fp2.monkey2


'Function Pointers Simple Example 2
'Reference(s):
'https://en.wikipedia.org/wiki/Function_pointer

#Import "<std.monkey2>"

Using std

Function Main()

	Local n1:Int = 7
	Local n2:Int = 5
	
	Print n1 + " + " + n2 + " = " + Operation<Int>(n1, n2, Add)
	Print n1 + " - " + n2  + " = " + Operation<Int>(n1, n2, Subtract) 

	Local n3:Double = 19.25
	Local n4:Double = 10.5

	Print n3 + " + " + n4 + " = " + Operation<Double>(n3, n4, Add)
	Print n3 + " - " + n4  + " = " + Operation<Double>(n3, n4, Subtract) 

End

Function Add<T>:T(first:T, second:T)
	Return first+second
End

Function Subtract<T>:T(first:T, second:T)
	Return first-second
End

Function Operation<T>:T(first:T, second:T, func:T(T, T))
	Return func(first, second)
End

*****************
Generics
*****************

gen1.monkey2


'Generics Simple Example
'Reference(s):
'https://en.wikipedia.org/wiki/Generic_programming

#Import "<std.monkey2>"

Using std

Function Main()

	Local v1:Int = 10
	Local v2:Int = 14
	Print "Maximum of " +v1+ " and " + v2 + " is " + Max<Int>(v1, v2)
	
	Local v3:Float = 19.25
	Local v4:Float = 12.5
	Print "Maximum of " +v3+ " and " + v4 + " is " + Max<Float>(v3, v4)

End

Function Max<T>:T(a:T, b:T)
	Return (a < b) ? b Else a
End

gen2.monkey2



'Generics Simple Example 2
'Reference(s):
'https://docs.oracle.com/javase/tutorial/java/generics/types.html

#Import "<std.monkey2>"

Using std

Function Main()
	
	Local myBox := New Box<Int>
	myBox.Item = 12
	Print "Box item: " + myBox.Item
	 
	Local myBox2 := New Box<MyClass>
	Print "Box item: " + myBox2.Item.ToString()
	
End

Class Box<T>
	
	Private 
	
	Field _item:T
	
	Public
		
	Property Item:T()
		Return _item
	Setter (item:T)
		_item=item
	End

End

Class MyClass
	Public
	Method ToString:String()
		Return "This is my class!"
	End
End

impixi

(Posted 2016) [#2]

******************
Enumerated Types
******************

enum1.monkey2


'Enumerated Type Simple Example
'Reference(s):
'https://en.wikipedia.org/wiki/Enumerated_type

#Import "<std.monkey2>"

Using std

Enum CardSuit
	Clubs, Diamonds, Spades, Hearts
End

Function Main()
	Local suit:CardSuit = CardSuit.Hearts
	Print Cast<UInt>(suit) + ": " + CardSuitLabel(suit)
End

Function CardSuitLabel:String(suit:CardSuit)
	Select suit
		Case CardSuit.Clubs
			Return "Clubs"
		Case CardSuit.Diamonds
			Return "Diamonds"
		Case CardSuit.Spades
			Return "Spades"
		Case CardSuit.Hearts
			Return "Hearts"
	End
	Return ""
End

enum2.monkey2



'Enumerated Type Simple Example 2
'Reference(s):
'https://en.wikipedia.org/wiki/Enumerated_type

#Import "<std.monkey2>"

Using std

Enum ItemFlag
	Moveable = 1
	Carryable = 2
	Equipable = 4
	Destructable = 8
End

Function Main()

	Local item1:=New Item("Sword", Cast<UByte>(ItemFlag.Moveable) | Cast<UByte>(ItemFlag.Carryable))
	item1.SetFlag(ItemFlag.Equipable)
	Print item1.ToString()
	
	Local item2:=New Item("Table")
	item2.SetFlag(ItemFlag.Moveable)
	Print item2.ToString()
	
End

Class Item

	Private
		Field _label:String
		Field _flags:UByte
		
	Public
		Method New(label:String, flags:UByte = 0)
			Label = label
			_flags = flags
		End
		
		Property Label:String()
			Return _label
			Setter (label:String)
				_label = label
		End
		
		Method SetFlag:void(flag:ItemFlag)
			_flags |= (Cast<UByte>(flag))
		End
		
		Method CheckFlag:Bool(flag:ItemFlag)
			Return (_flags & Cast<UByte>(flag))
		End
		
		Method FlagToString:String(flag:ItemFlag)
			Local str:String = "ERR"
			If CheckFlag(flag) 
				str = "True" 
			Else 
				str = "False"
			endif
			Return str
		End
		
		Method ToString:String()
			Local str:String = "-----------------------~n" + Label
			str += "~n-----------------------~n"
			str += ("Moveable: " + FlagToString(ItemFlag.Moveable) + "~n")
			str += ("Carryable: " + FlagToString(ItemFlag.Carryable) + "~n")
			str += ("Equipable: " + FlagToString(ItemFlag.Equipable) + "~n")
			str += ("Destructable: " + FlagToString(ItemFlag.Destructable) + "~n")
			Return str
		End
End

marksibly

(Posted 2016) [#3]

Nice examples!

One thing to note is that you have to be *very* careful when using Varptr with 'class objects'.

A 'Ptr' wont keep an object alive GC-wise, so unless a normal variable is also keeping the object alive, there's a chance it will be GC'd 'behind your back'. I'd consider the pointer1.monkey2 example to be borderline dodgy for this reason - the 'obj1' var is, strictly speaking, 'dead' before the pointer is used. It'll work, but only because of how compilers work...

Also, an object var is already a pointer, ie: "sizeof( blah )" where blah is an instance of a class/interface will always return 4/8, so Varptr blah is sort of redundant for what I think I most people will instinctively want to use it for.

Varptr with a struct is also dangerous - but marginally less so, and it's a necessary evil for the sake of integrating with 3rd party stuff. Also, note that you can still cast 'extends void' objects to 'void ptr' (it's an automatic conversion in fact) so you still get to play with pointers when dealing with non-mx2 classes.

But I'm not sure it's a good idea with pure mx2 class objects, so I'm tempted to disallow it entirely. If you DO have to mess with pointers to mx2 objects, there is probably some native glue code involved so perhaps it's best to just leave that stuff for the glue code?

I do think a general, safe mechanism for dealing with 'variable references' (the one sensible use I can think of for Varptr obj) would be a very use feature though, and I do have a few ideas here. Raw pointers are a crappy way to achieve this though and one I don't really want to encourage.

impixi

(Posted 2016) [#4]

Thanks for the info, Mark!

But I'm not sure it's a good idea with pure mx2 class objects, so I'm tempted to disallow it entirely. If you DO have to mess with pointers to mx2 objects, there is probably some native glue code involved so perhaps it's best to just leave that stuff for the glue code?

Yep, I'd agree with that.

EDIT: I put a little note in the pointers1.monkey2 example.

impixi

(Posted 2016) [#5]

******************
Lambda Functions
******************

lambda1.monkey2


'Lambda Function Simple Example
'Reference(s):
'http://monkey2.monkey-x.com/forums/topic/what-the-sam-hill-is-a-lambda-function/
'https://en.wikipedia.org/wiki/Anonymous_function

#Import "<std.monkey2>"

Using std

Function Main()
	Local sqr := Lambda:Int(v:int) 
		Return (v * v)
	End
	
	Print sqr(5)
	Print sqr(8)
End

lambda2.monkey2


'Lambda Function Simple Example 2
'Reference(s):
'http://monkey2.monkey-x.com/forums/topic/what-the-sam-hill-is-a-lambda-function/
'https://en.wikipedia.org/wiki/Anonymous_function
'https://dzone.com/articles/why-we-need-lambda-expressions

#Import "<std.monkey2>"

Using std

Function Main()
	
	Local values := New Int[](8, 5, 2, 6, 1, 6)
	
	Local str:String = "~nData set: "
	For Local v:=Eachin values
		str += (v + ", ")
	Next
	str = str.Slice(0, str.Length-2)
	Print str + "~n"
	
	Print "Sum of all values = ~t" + SumAll(values, Lambda:Bool(v:Int) 
		Return True 
	End)

	Print "Sum of even values = ~t" + SumAll(values, Lambda:Bool(v:Int) 
		Return ((v Mod 2 = 0) ? 1 Else 0)
	End)
	
	Print "Sum of values <= 5 = ~t" + SumAll(values, Lambda:Bool(v:Int) 
		Return ((v <= 5) ? 1 Else 0)
	End)
	
End

Function SumAll:Int(vals:Int[], filter:bool(int))
	Local sum:Int = 0
   	For Local v:= Eachin vals
   		If (filter(v)) 
            		sum += v
        		Endif
        	Next
	Return sum
End

impixi

(Posted 2016) [#6]

**************
External C
**************

Place all files in the same folder and run exte1.monkey2.

utils.h

#if _WIN32
	#include <windows.h>
#else
	#if __APPLE__
		#include <mach/mach_time.h>
	#else
		#include <time.h>
	#endif
#endif

//THANKS Danilo!
#ifdef __cplusplus
	extern "C" {
#endif

	unsigned long GetSysSeed(void);

#ifdef __cplusplus
	}
#endif

utils.c

#include "utils.h"

unsigned long GetSysSeed(void)
{
	#if _WIN32
		return (unsigned long)GetTickCount();
	#else
		#if __APPLE__
			return (unsigned long)mach_absolute_time(); 
		#else
			struct timespec tm;
			clock_gettime(CLOCK_MONOTONIC, &tm);
			return (unsigned long)tm.tv_nsec;
		#endif
	#endif
}

utils.monkey2


Namespace utils

#Import "utils.h"
#Import "utils.c"

Extern

Function GetSysSeed:ULong()

exte1.monkey2


'External C Code Access Simple Example

'NOTE: Linux untested, but the principle is the same
'on all platforms.

#Import "utils.monkey2"
#Import "<std.monkey2>"

Using std
Using std.random

Using utils

Function Main()

	'Get a time-related value from the wrapped C function.
	'Use it to seed the random number generator.
	Local seed := GetSysSeed()
	SeedRnd(seed)
	
	'--- Work around some unwanted behavior that happens when setting a new seed.
	RndULong()
	RndULong()
	'---

	For Local set := 1 To 9	
		Local str:String = "Set #" + set + ": ~t"
		For Local vals := 1 To 10
			str += String(Rand(-9, 9)) + "~t"
		Next
		Print str
	Next
	
End

'Return a random int within a given range (min and max inclusive)
Function Rand:Int(min:Int, max:Int)
	Return (min + (Cast<Int>(RndULong()) Mod (max+1) - min))
End

EDIT (22-Mar-16): Finally had a chance to test this on a Mac - fixed a bug in utils.h and utils.c and it now runs okay...

impixi

(Posted 2016) [#7]

**************
Operator Overloading
**************
opover1.monkey2


'Operator Overloading Example
'Reference(s):
'http://monkey2.monkey-x.com/forums/topic/operator-overloading/
'https://en.wikipedia.org/wiki/Operator_overloading

'https://msdn.microsoft.com/en-us/library/5tk49fh2.aspx

#Import "<std.monkey2>"

Using std

Function Main()
	
	Local a := New Complex(1.25, 2.25)
   	Local b := New Complex(5.5, 3.25)
   	Local c:Complex
	
	c = a + b
	
	Print "a= ~t" + a.ToString()
	Print "b= ~t" + b.ToString()
	Print "a+b= ~t" + c.ToString()
	
End

Struct Complex

	Private
		
		Field _re:Double
		Field _im:Double 

	Public
	
		Method New(re:Double, im:Double) 
			_re = re
			_im = im
		End
   
   		Operator+:Complex(other:Complex)
   			Return New Complex(Re + other.Re, Im + other.Im)
   		End
   		
   		Property Re:Double()
   			Return _re
   		End
   		
   		Property Im:Double()
   			Return _im
   		End
   		
   		Method ToString:String()
   			Return Re + ", " + Im
   		End
   		
End

opover2.monkey2


'Operator Overloading Example 2
'Reference(s):
'http://monkey2.monkey-x.com/forums/topic/operator-overloading/
'https://en.wikipedia.org/wiki/Operator_overloading

#Import "<std.monkey2>"

Using std

Function Main()
	
	Local objA:=New MyClass("Gold", 100)
	Local objB:=New MyClass("Silver", 33)
	
	Print ""
	
	If (objA > objB) Then Print objA.Label + " > " + objB.Label
	If (objA < objB) Then Print objA.Label + " < " + objB.Label

	If (objA = objB) Then Print objA.Label + " = " + objB.Label
	If (objA <> objB) Then Print objA.Label + " <> " + objB.Label

	Print ""
	
End


Class MyClass
	
	Private
	
		Field _label:String
		Field _value:UByte
	
	Public
		
		Method New(label:String, value:UByte)
			Label = label
			_value = value
		End
		
		Property Label:String()
			Return _label
		Setter(label:String)
			_label = label
		End
		
		
		Operator<=>:Int(o2:MyClass)
			Return (Self._value <=> o2._value)
		End
		
		'Overloading <=> is shorthand for overloading all 
		'the comparison operators:
		
		#rem
		Operator>:Bool(o2:MyClass)
			Return Self._value > o2._value
		End
	
		Operator<:Bool(o2:MyClass)
			Return Self._value < o2._value
		End
	
		Operator=:Bool(o2:MyClass)
			Return Self._value = o2._value
		End
		
		Operator<>:Bool(o2:MyClass)
			Return Self._value <> o2._value
		End
		#end
		
End

**************
Struct
**************

struct1.monkey2


'Struct Example

#Import "<std.monkey2>"

Using std

Function Main()
	
	'Structs are allocated on the stack and passed by value.
	Local ms:=New MyStruct(3,6)
	Print "Original Struct object before processing function: " + ms.col + ", " + ms.row
	ProcessMyStruct(ms, -1, -2)
	Print "Original Struct object after processing function: " + ms.col + ", " + ms.row + " (No change)"
	
	'Classes are allocated on the heap and passed by reference.
	Local mc:=New MyClass(3,6)
	Print "Original Class object before processing function: " + mc.col + ", " + mc.row
	ProcessMyClass(mc, -1, -2)
	Print "Original Class object after processing function: " + mc.col + ", " + mc.row
	
End

'----

Struct MyStruct

	Public

	Field col:Int, row:Int
	
	Method New(c:Int, r:Int)
		col = c
		row = r
	End
	
End

Function ProcessMyStruct(ms:MyStruct, c:Int, r:Int)
	ms.col = c
	ms.row = r
End

'----

Class MyClass

	Public

	Field col:Int, row:Int
	
	Method New(c:Int, r:Int)
		col = c
		row = r
	End
	
End

Function ProcessMyClass(mc:MyClass, c:Int, r:Int)
	mc.col = c
	mc.row = r
End

struct2.monkey2


'Struct Example 2
'Reference(s):
'https://en.wikipedia.org/wiki/Stack-based_memory_allocation

#Import "<std.monkey2>"
#Import "<libc.monkey2>"

Using std
Using libc

Function Main()
	
	'Qty too high might cause stack overflow?
	Local qty := 10000000
	
	'Try running in "release" mode too...
	
	Local tm0 := clock()
	For Local n := 1 To qty
		Local ms:=New MyStruct(3, 6)
	Next
	Local tm1 := clock()
	Local diff:Double = Cast<Double>((Double(tm1) - Double(tm0)) / CLOCKS_PER_SEC)
	Print "Time taken to allocate and initialize " + qty + " struct items (stack) = " + diff + " seconds"
	
	tm0 = clock()
	For Local n := 1 To qty
		Local mc:=New MyClass(3, 6)
	Next
	tm1 = clock()
	diff = Cast<Double>((Double(tm1) - Double(tm0)) / CLOCKS_PER_SEC)
	Print "Time taken to allocate and initialize " + qty + " class objects (heap) = " + diff + " seconds"
	
End


'----

Struct MyStruct

	Private

		Field _col:UInt, _row:UInt
		
	Public
	
	Method New(col:UInt, row:UInt)
		Col = col
		Row = row
	End
	
	Property Col:Int()
		Return _col
	Setter (col:UInt)
		_col = col
	End
	
	Property Row:Int()
		Return _row
	Setter (row:UInt)
		_row = row
	End
	
End



'----

Class MyClass

	Private

		Field _col:UInt, _row:UInt
		
	Public
	
	Method New(col:UInt, row:UInt)
		Col = col
		Row = row
	End
	
	Property Col:Int()
		Return _col
	Setter (col:UInt)
		_col = col
	End
	
	Property Row:Int()
		Return _row
	Setter (row:UInt)
		_row = row
	End
	
End

EDIT (27 Mar 2016): Updated opover2.monkey2 to overload the <=> operator.

impixi

(Posted 2016) [#8]

********************
Abstract Class
********************

ab1.monkey2


'Abstract Class Example
'Reference(s):
'https://en.wikipedia.org/wiki/Abstract_type

#Import "<std.monkey2>"

Using std

Function Main()

	Local shapes:Shape[] = New Shape[](New Rectangle(5.0, 15.0), New Circle(4.0), New Rectangle(2.0, 4.0), New Circle(2.5))

	For Local s := eachin shapes
		Print s.ToString()
	Next

End


'----


'Abstract classes must be used as a base/super class;
'they cannot be instantiated themselves.

Class Shape Abstract

	Private
		Field _label:String

	Public

		Property Label:String()
			Return _label
		Setter(label:String)
			_label = label
		End

	'Members marked Virtual can be overridden by subclasses. 

	Method Area:Double() Virtual
		Return 0
	End
	
	Method ToString:String() Virtual
		Return ""
	End
	
End


'----


'Subclasses should implement their superclass's virtual members.

Class Rectangle Extends Shape
	
	Private
		Field _width:Double, _length:Double
	
	Public
	
	Method New(width:Double, length:Double)
		Label = "Rectangle"
		Width = width
		Length = length
	End
	
	Property Width:Double()
		Return _width
	Setter (width:Double)
		_width = width
	End

	Property Length:Double()
		Return _length
	Setter (length:Double)
		_length = length
	End

	'The Override keyword must be used when overriding a superclass's virtual members.
	
	Method Area:Double() Override
		Return (Width * Length)
	End
	
	Method ToString:String() Override
		Return (Label + " area = w*l: " + Width + "*" + Length + "= " + Area()) 
	End
	
End


'----


Class Circle Extends Shape
	
	Private
		Field _radius:Double
	
	Public
	
	Method New(radius:Double)
		Label = "Circle"
		Radius = radius
	End
	
	Property Radius:Double()
		Return _radius
	Setter (radius:Double)
		_radius = radius
	End
	
	Method Area:Double() Override
		Return Pi * Radius * Radius
	End
	
	Method ToString:String() Override
		Return (Label + " area = pi*r*r: " + Pi + "*" + Radius + "* " + Radius + "= " + Area()) 
	End
	
End

kmac	(Posted 2016) [#9]

This is great. I have a few hard deadlines over the next few days but will definitely study these next week.

marksibly

(Posted 2016) [#10]

Great stuff!

A quick comment re: comparison overloads: you only need to overload Operator<=> to implement ALL comparisons. This is very convenient and something people should probably know about.

impixi

(Posted 2016) [#11]

@Mark:

Wouldn't that only work for sorting-relating comparisons? The result of a <=> comparison can be -1, 0, or +1. Useful to determine whether a given value is less than, equal to, or greater than another given value.

The >, <, <> and = comparisons return either true (1) or false (0). How could I overload <=> so that all those checks would present the correct boolean result when used, for example, in an If statement?

I've experimented with my opover2.monkey2 example above but just cannot think how to make it work. It's probably something obvious I'm overlooking, so apologies in advance. ;)

marksibly

(Posted 2016) [#12]

Basically, "X op Y" is transformed to "(X<=>Y) op 0" where op is one of <, >, <= etc.

So "5<8" is transformed to "(5<=>8)<0" and "p>=q" is transformed to "(p<=>q)>=0" etc.

If you think it through it works!

So you should be able to replace your 3 operators with:

Operator<=>:Int( o2:MyClass )
Return Self._value<=>o2._value
End

...which is really doing the same thing as...

Operator<=>:Int( o2:MyClass )
If Self._value<o2._value Return -1
If Self._value>o2_value Return 1
Return 0
End

Note also that the compiler 'writes' a version of <=> for structs (but yours is a class...) that don't already have one. This applies <=> to all members, and returns the first non-0 result. If there is no non-0 result, it returns 0. For classes, the default '<=>' simply subtracts pointers.

You can actually derive all comparisons with just '<' (or '>' ), eg:

"x>y" -> "y<x"
"x<>y" -> "x<y or y<x"
"x=y" -> "not (x<y or y<x)"

...etc. but I thought adding "<=>" would be simpler to understand and more flexible/useful. Also, the '<' approach can result in 2 operator method calls for some comparisons (although those methods would probably be simpler).

Pakz	(Posted 2016) [#13]

Keep em coming! :D

impixi

(Posted 2016) [#14]

@Mark

Thanks for the explanation! Your logic seems correct. However...

So you should be able to replace your 3 operators with:

Operator<=>:Int( o2:MyClass )
Return Self._value<=>o2._value
End

That's the first thing I tried but it produces incorrect results in my example (which is why I thought overloading <=> might be more involved than I assumed).

The original opover2.monkey2 produces the following output (correct).

Gold > Silver
Gold <> Silver

A modified version, simply commenting out the <, >, and = overloads and adding the above <=> overload produces:

Gold < Silver
Gold <> Silver

That is incorrect. Altering the initial values also produces incorrect results for most combinations (whereas the original code produces correct results).

@Pakz:

Off the top of my head, I still need to write some Interface examples. Maybe some String and Array initialization and manipulation examples. I do have a more advanced Extern example "completed", except for one remaining bug I haven't yet squashed.

Any other MX2 language-related items I should write examples for?

tiresius

(Posted 2016) [#15]

These are great!!! You covered all the topics I wondered about for Monkey2. If there are any others that would be cool, too!

Pakz	(Posted 2016) [#16]

I wonder how mx2 has the arrays done. This is something I use a lot.
2 dimensional arrays, 3 dimensional arrays, 2 dimensional data (tilemap) in a array.

marksibly

(Posted 2016) [#17]

> That's the first thing I tried but it produces incorrect results in my example (which is why I thought overloading <=> might be more involved than I assumed).

It's a bug! Found and fixed, will github soon.

There are likely to be a bunch of little things like this still in there, so if something looks like it should be working but isn't, chances are pretty good that it's my fault, not yours! So please let me if you discover any other issues like this in future. Even if it's not a bug, if it's confusing or inconsistent that's worth checking out too.

marksibly

(Posted 2016) [#18]

> 2 dimensional arrays, 3 dimensional arrays, 2 dimensional data (tilemap) in a array.

2+ dimensional arrays are supported, but not as well as 1d yet.

You can create and index them using...

Local t:=New Int[10,20]
Print t[5,5]

...but you can't yet create them using 'New Int[](...)' syntax, or slice them etc. I'm not sure yet how much you'll be able to do with them, but they will at least be in there.

marksibly

(Posted 2016) [#19]

Ok, I've pushed the fix for Operator<=> to github.

tiresius

(Posted 2016) [#20]

For some reason I thought arrays would be the same as Monkey1, good to know.
This makes more sense to my brain than the "array of arrays" we had earlier.

Pakz	(Posted 2016) [#21]

So it's

Local t:=New Int[10,20,3]
Print t[5,5,0]

for a 3 dimensional array?

Is easier then in monkey 1.

The tilemap data I put in 2 dimensional arrays since there is no read data in monkey 1 afaik.

marksibly

(Posted 2016) [#22]

Here's a little 'LoadMap2d' demo that uses a JSON file to store data.

Note: it requires the latest version of mx2cc on github - just fixed a few array issues.

'----- loadmap2d.monkey2 -----

#Import "<std>"

#Import "map2d.json"

Using std.json
Using std.stringio

Function LoadMap2d:Int[,]( path:String )

	Local src:=LoadString( "asset::map2d.json" )
	
	Local json:=New JsonParser( src ).ParseJson()
	
	Local w:=json["width"].ToInt()
	Local h:=json["height"].ToInt()
	
	Local map:=New Int[w,h]
	
	For Local y:=0 Until h
		For Local x:=0 Until w
			map[x,y]=json["data"][y][x].ToInt()
		Next
	Next
	
	Return map
End

Function Main()

	Local map:=LoadMap2d( "asset::map2d.json" )
	
	Local w:=map.Size( 0 )
	Local h:=map.Size( 1 )
	
	Print "w="+w
	Print "h="+h

	For Local y:=0 Until h
		Local str:=""
		For Local x:=0 Until w
			str+=","+map[x,y]
		Next
		Print str.Slice( 1 )
	Next

End

'----- map2d.json -----

{
	"width":10,
	"height":10,
	"data":[
		[1,2,3,4,5,6,7,8,9,10],
		[2,3,4,5,6,7,8,9,10,1],
		[3,4,5,6,7,8,9,10,1,2],
		[4,5,6,7,8,9,10,1,2,3],
		[5,6,7,8,9,10,1,2,3,4],
		[6,7,8,9,10,1,2,3,4,5],
		[7,8,9,10,1,2,3,4,5,6],
		[8,9,10,1,2,3,4,5,6,7],
		[9,10,1,2,3,4,5,6,7,8],
		[10,1,2,3,4,5,6,7,8,9]
	]
}

impixi

(Posted 2016) [#23]

Ok, I've pushed the fix for Operator<=> to github.

Thanks. Now it works as expected.

PS: I like the new documentation layout, linked to and described in the MX2 dev blog. The logo is cool too...

impixi

(Posted 2016) [#24]

***********
Interfaces
***********

inter1.monkey2

'Interface Example

#Import "<std.monkey2>"

Using std

Function Main()
	
	Local beast := New Beast()
	Local npc := New NPC()
	Local a:Actor
	Local conv:Conversor

	Print "-----"

	a = beast
	a.Move()
	a.Attack()
	a.Flee()
	
	Print "-----"
	
	a = npc
	a.Move()
	a.Attack()
	a.Flee()
	
	conv = npc
	conv.ParsePhrase("BLAH BLAH")
	
	Print "-----"
	
	Local beast_npc := New BeastNPC()
	beast_npc.Move()
	beast_npc.ParsePhrase("BLAH BLAH")
	beast_npc.Emote()
	
	Print "-----"
	
End

'Interfaces are purely abstract and cannot be instantiated themselves.

'All Interface members are public and virtual by default.
Interface Actor
	Method Move:Void()
	Method Attack:Void()
	Method Flee:Void()
End

Interface Conversor
	Method ParsePhrase:Void(src:String)
End

'Classes "implement" Interfaces.
'A class must implement ALL of the interface's methods.
Class Beast Implements Actor
	Method Move:Void()
		Print "Beast Move!"
	End
	Method Attack:Void()
		Print "Beast Attack!"
	End
	Method Flee:Void()
		Print "Beast Flee!"
	End
End

'A class can implement more than one interface.
Class NPC Implements Actor, Conversor
	Method Move:Void()
		Print "NPC Move!"
	End
	Method Attack:Void()
		Print "NPC Attack!"
	End
	Method Flee:Void()
		Print "NPC Flee!"
	End
	Method ParsePhrase:Void(src:String)
		Print "I am an NPC and I know all about " + src + ", but I'm not tellin'!"
	End
End

'Subinterfaces can be declared by extending an existing interface.
'The same principles of class inheritance apply to interface inheritance.
'(Except interfaces can extend more than one interface, whereas classes
'cannot extend more than one class.) 

Interface ActorConversor Extends Actor, Conversor
	Method Emote:Void()
End

Class BeastNPC Extends Beast Implements ActorConversor 

	Method ParsePhrase:Void(src:String)
		Print "I am a BEAST - I know nothing about " + src + "!"
	End
	
	Method Emote:Void()
		Print ":hiss:"
	End

End

impixi

(Posted 2016) [#25]

**************
External C++
**************

Place all files in the same folder and run exte2.monkey2.

cpprand.h


#ifndef CPP_RAND_INTS
#define CPP_RAND_INTS

//Import the bbmonkey.h header file.
#include <bbmonkey.h>

#include <random>

//Inherit bbObject.
class random_ints : public bbObject
{
	private:
		unsigned int _qty;
		int* _data;
		
		std::random_device _rd;	
		
	public:
		random_ints(unsigned int qty);
		~random_ints();
		unsigned int getQty();
		int* generate(int min, int max);
		int* getDataPtr();
};

#endif

cpprand.cpp


#include "cpprand.h"

random_ints::random_ints(unsigned int qty)
{
	_qty = qty;
	if (_qty <= 0)
		_qty = 1;
	
	_data = NULL;
	_data = new int[_qty]();
}

random_ints::~random_ints()
{
	if (_data != NULL)
		delete[] _data;
    
    puts("~random_ints");
}

unsigned int random_ints::getQty()
{
	return _qty;
}

int* random_ints::generate(int min, int max)
{
	if (_data == NULL)
		return NULL;
	
	std::mt19937 gen(_rd());
	std::uniform_int_distribution<int> dist(min, max);
	
	for (unsigned int i=0; i<_qty; i++)
		_data[i] = dist(gen);

	return _data;
}

int* random_ints::getDataPtr()
{
	return _data;
}

cpprand.monkey2


Namespace CppRand

#Import "cpprand.h"
#Import "cpprand.cpp"

Extern

'The quoted strings are the names of our c++ class equivalents.
Class RandomInts = "random_ints"
	Method New(qty:UInt)
	Property Qty:UInt()="getQty"
	Method Generate:Int Ptr(min:Int, max:Int)="generate"
	Method GetDataPtr:Int Ptr()="getDataPtr"
	
	'Declare a function so we can trigger the c++ class destructor.
	Function Destroy:Void(ris:RandomInts) = "delete"
End

exte2.monkey2


'External C++ Code Access Simple Example

#Import "<std.monkey2>"
#Import "cpprand.monkey2"

Using std
Using CppRand

Function Main()

	Local ris:= New RandomInts(UInt(10))
	
	Print "First Batch of random integers:"
	Local data:= ris.Generate(-10, 10)

	For Local i:Int = 0 Until ris.Qty
		Print data[i]
	Next
	
	Print "Second batch of random integers:"
	ris.Generate(100, 200)
	data = ris.GetDataPtr()
	
	For Local i:Int = 0 Until ris.Qty
		Print data[i]
	Next
	
	'Explicitly destroy the object so its memory is freed. 
	RandomInts.Destroy(ris)
	
End