A quick platformer

Community Forums/Monkey Talk/A quick platformer

therevills

(Posted 2011) [#1]

http://www.therevillsgames.com/monkey/platformer/

slenkar

(Posted 2011) [#2]

its a bit buggy laddie,
mario gets stuck in the landscape and falls through it

therevills

(Posted 2011) [#3]

I saw that once, but couldnt reproduce it... can you? Still WIP :P

Edit:

LOL - just loaded it up and I can repeat all the time now... jump of the highest block to the left...

I changed the gravity to be stronger, so when Mario falls, the check to see if he should stop sometimes miss a block, therefore he falls thru...

Last edited 2011

Dabhand

(Posted 2011) [#4]

I like making platformers... I've never made a major platform game, but, slopes make all the difference.

I'd just use usually array checking (Well, I use bit-shifting for the bonus optimization), but, when objects are on screen, I performed pixel checking on tiles that where used as slopes, it was a much simpler way then fannying on with arrays checking.

Now, over the years, when I've discussed the subject, people have harped on that 'bit-shifting is overkill', which the usual reply from myself was "I don't care"! ;)

Then, people whinged that "Well, pixel collision wont work when enemies are off screen", which is fair do's, but, my approach to that is simple... When an enemy is off screen, pause their movements!

This was about the best approach for platformers that I found without going into the realms of mucking about.

I'd love to make another and release it, but a project like that is waaayyyyy above my head in terms of making my own media, so, I'll probably never bother! :D

Dabz

Last edited 2011

therevills

(Posted 2011) [#5]

I hate doing slopes!!!

Ive updated the example... hopefully you cant fall through it now... I hope..

Dabhand

(Posted 2011) [#6]

I hate doing slopes!!!

Slopes are easy, I'd knock out an in-depth explanation on it, but the last time I remembered someone doing that (Vic-e-babes), the entire tutorial was greeted with as much enthusiasm as Col. Gaddafi at a rebel tea-party!

Dabz

GW	(Posted 2011) [#7]

Just tried it, in the HTML version the character gets stuck a lot in the blocks.

You have to make sure that (CurrentPos + Velocity) is always less than the size of a block.

therevills

(Posted 2011) [#8]

:(

This is my logic:


if KeyDown(KEY_LEFT)
	direction = LEFT
	Local tempx# = x - xSpeed*dt.delta
	if getCollisionTile(tempx - image.w2 , y) = 0
		x = tempx
	else
		x = (x-image.w2) / TILE_SIZE) * TILE_SIZE + image.w2
	endif
endif

taumel

(Posted 2011) [#9]

I really like 2d plattformers but never found the time/project to do one on my own. I already asked this before here on the forum. What is the best way to do all the collision tests with the surrounding? a) checking against a invisible collision bitmap (that's what i would think), b) testing against visible graphics (do you do this on a more tolerant level if a collision occur or just by intersecting rectangles, do you use two layers in the tileset then for collisions and where a character can be covered), c) testig against a level map first and then adjusting things according to the current tile or d) by physics?

I wouldn't mind if someone provides some explanations/thoughts on what's the most flexible and reliable solution from their experience/point of view, as well as some links or source.

Last edited 2011

therevills

(Posted 2011) [#10]

In the past, Ive used two layers, one for the tileset set and one for the collisions.

I've added a level editor... of course HTML5 cant save files, but it can output a string and load a text file :P

steve_ancell

(Posted 2011) [#11]

slenkar (Posted 1 day ago) #2
its a bit buggy laddie,
mario gets stuck in the landscape and falls through it

therevills (Posted 15 hours ago) #3
I saw that once, but couldnt reproduce it... can you?

I found one thing that triggers that to happen. Make the character jump repeatedly on the spot, it will happen every 3-4 jumps.

Hope that helps ;)

Last edited 2011

taumel

(Posted 2011) [#12]

How is you collision data then setup? Do you test against a collision tileset as well or do you bake the collision data it into a bitmap?

Last edited 2011

therevills

(Posted 2011) [#13]

Here is the code (without the graphics - replaced with Rects and Ovals)

Strict

import mojo

' Store the device width and height
Global SCREEN_WIDTH%
Global SCREEN_HEIGHT%

' Game Width and Height
Const WIDTH#=320
Const HEIGHT#=240

' Used for delta timing movement
Global dt:DeltaTimer

Global game:MyGame

Function Main:int()
	game = new MyGame()
	return 0
End Function

Class MyGame extends App
	Field player:Player
	Field level:Level
	Field FPS% = 60
	Field offsetX#, offsetY#
	Field scrollX#, scrollY#
	
	Method OnCreate:Int()
		' Create the delta timer
		dt = New DeltaTimer(FPS)
		SetUpdateRate FPS
		
		' Store the device width and height
		SCREEN_WIDTH = DeviceWidth()
		SCREEN_HEIGHT = DeviceHeight()
		
		level = new Level()
		level.load()
		
		player = new Player(level.playerX, level.playerY)
		
		return 0
	End Method
	
	Method OnUpdate:Int()
		dt.UpdateDelta()
		player.update()
		return 0
	End Method
	
	Method OnRender:Int()
		Cls 
		PushMatrix 
		Scale SCREEN_WIDTH/WIDTH, SCREEN_HEIGHT/HEIGHT
		level.draw()
		player.draw(game.scrollX, game.scrollY)
		PopMatrix
		return 0
	End Method	
end class

Class GameImage
	Field w%, h%
	Field w2%, h2%
End Class

Class Player
	Field x#, y#
	Field dx#, dy#
	Field speedX#, speedY#
	Field image:GameImage
	Field jumping:Bool
	
	Method New(x#, y#)
		self.x = x
		self.y = y
		image = new GameImage
		image.w = 16
		image.h = 16
		image.w2 = image.w / 2
		image.h2 = image.h / 2
		speedX = 2
		speedY = 5
	End Method
	
	Method draw:Void(offsetx# = 0, offsety# = 0)
		SetColor 0,255,0
		DrawOval x - image.w2 - offsetx, y - image.h2 - offsety, image.w, image.h
		SetColor 255, 255, 255
	End Method
	
	Method update:Void()
	
		if KeyDown(KEY_LEFT)
			Local tempx# = x - speedX * dt.delta
			if game.level.getCollisionTile(tempx - image.w2 , y + image.h2 - 1 ) = 0 and
				game.level.getCollisionTile(tempx - image.w2 , y - image.h2) = 0 and
				game.level.getCollisionTile(tempx - image.w2 , y) = 0 then
						
				x = tempx
			else
				x = round((x-image.w2)/Level.TILE_SIZE)*Level.TILE_SIZE + image.w2
			endif
		else if KeyDown(KEY_RIGHT)
			Local tempx# = x + speedX * dt.delta
			if game.level.getCollisionTile(tempx + image.w2 , y + image.h2 - 1 ) = 0 and
				game.level.getCollisionTile(tempx + image.w2 , y - image.h2) = 0 and
				game.level.getCollisionTile(tempx + image.w2 , y) = 0 then
				
				x = tempx
			else
				x = round((x+image.w2)/Level.TILE_SIZE)*Level.TILE_SIZE - image.w2
			endif
		End if
		
		If KeyDown(KEY_SPACE) And not jumping Then
			dy=-speedY
			jumping = true
		EndIf
		
		Local amount:Int = 1
		Local amountY:int = 1
		
		if not jumping
			if game.level.getCollisionTile(x - image.w2 + amount, y + image.h2) = 0 and 
				game.level.getCollisionTile(x + image.w2 - amount, y + image.h2) = 0 and 
				game.level.getCollisionTile(x, y + image.h2) = 0 then
				
				jumping = true
			endif
		endif
		
		if jumping
			dy +=Level.GRAVITY * dt.delta
			local tempY# = y + (dy * dt.delta)
			if dy <> 0
				if dy > 0
					if game.level.getCollisionTile(x - image.w2 + amount, tempY + image.h2 - amountY) > 0 or 
						game.level.getCollisionTile(x + image.w2 - amount, tempY + image.h2 -amountY) > 0 or
						game.level.getCollisionTile(x, tempY + image.h2 - amountY) > 0 then
						
						dy = 0
						jumping = false
						y = round( (tempY + image.h2) / Level.TILE_SIZE ) * Level.TILE_SIZE - image.h2
					else
						y = tempY
					endif
				else
					if game.level.getCollisionTile(x - image.w2 + amount, tempY - image.h2 ) > 0 or 
						game.level.getCollisionTile(x + image.w2 - amount, tempY - image.h2) > 0 or
						game.level.getCollisionTile(x, tempY - image.h2 ) > 0 then
						
						dy = 0
						y = round((tempY - image.h2) / Level.TILE_SIZE) * Level.TILE_SIZE + image.h2
						
					else
						y = tempY
					endif
				endif
			endif
		endif
		
		Local border% = 200
		If x-game.scrollX < border Then game.level.scrollHorizontal((x-game.scrollX)-border)
		If x-game.scrollX > WIDTH-border Then game.level.scrollHorizontal((x-game.scrollX)-(WIDTH-border))
	End Method
	
End Class

Function round%(f#)
	Return Floor(f+0.5)
End Function

Class Level
	Const TILE_SIZE% = 16
	Const GRAVITY# = 0.18
	
	Field map:Tile[][]
	Field width%, height%
	Field pixelWidth% = 0
	Field pixelHeight% = 0
	
	Field playerX%, playerY%
	
	' 32 across
	Global level1:=[
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,124,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,124,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,124,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,124,0,0,0,16,124,16,124,16,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,
		116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,116,
		115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,115,
		0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0]

	Method load:Void()
		width = 32
		height = 16
		
		pixelWidth = width * TILE_SIZE
		pixelHeight = height * TILE_SIZE
		
		map = tileArray(width, height)
		
		For Local x:Int = 0 To width - 1
			For Local y:Int = 0 To height - 1
				map[x][y] = New Tile((level1 [ x + y * width ] ))
			Next
		Next
		
		playerX = 10
		playerY = 200
		
	End Method
	
	Method draw:Void()
		For Local x% = 0 To width - 1
			For Local y% = 0 To height - 1
				If map[x][y].frame > 0
					SetColor map[x][y].red, map[x][y].green, map[x][y].blue
					DrawRect Int(x * TILE_SIZE - game.scrollX), Int(y * TILE_SIZE - game.scrollY), TILE_SIZE, TILE_SIZE
				endif
			Next
		Next
	End Method
	
	Method scrollHorizontal:Void(change#)
		game.scrollX+=change

		If game.scrollX <0 Then
			game.scrollX = 0
		Else
			Local maxX% = pixelWidth - WIDTH
			If game.scrollX > maxX Then game.scrollX = maxX
		EndIf
	End Method
	
	Method getCollisionTile:Int(x:Float, y:Float)
		If x < 0 Or x >= pixelWidth Or y < 0 Or y >= pixelHeight Then Return 0
		
		local xx% = (Floor(x / TILE_SIZE)) 
		local yy% = (Floor(y / TILE_SIZE))
		
		Return map[xx][yy].frame
	End Method
End Class

Function tileArray:Tile[][](x_size:Int, y_size:Int)
	Local map:Tile[x_size][]
	For Local x:Int=0 Until x_size
	   map[x]=New Tile[y_size]
	Next
	Return map
End Function

Class Tile
	Field frame:Int
	Field red%, green%, blue%	
	
	Method New(frame:Int=0)
		self.frame = frame
		red = 255 - frame
		green = 255 - frame
		blue = 255 - frame
	End
End

Class DeltaTimer
	Field targetfps:Float = 60
	Field currentticks:Float
	Field lastticks:Float
	Field frametime:Float
	Field delta:Float
	
	Method New (fps:Float)
		targetfps = fps
		lastticks = Millisecs()
	End
	
	Method UpdateDelta:Void()
		currentticks = Millisecs()
		frametime = currentticks - lastticks
		delta = frametime / (1000.0 / targetfps)
		lastticks = currentticks
	End
End

Can anyone see the error? Thanks!

Last edited 2011

therevills

(Posted 2011) [#14]

Uploaded a new version:

* Sound + Music
* You can now destory blocks
* 'Fixed' falling thru floor - Thanks to Matt at monkeycoder

Please test :)

Steve Elliott

(Posted 2011) [#15]

I got stuck in the grass - mario was lower than he should have been. Managed to jump out. Mario doesn't always fall too. Suspended in mid-air for a while.

[EDIT]
I suspect it's a problem with delta timing.

Last edited 2011

therevills

(Posted 2011) [#16]

How!?!?!? ARRRRGGHGGHGHHGHHHHH!!!!

taumel

(Posted 2011) [#17]

@therevills
Cool, thanks! I'll have a look at it later on when i find some time.

therevills

(Posted 2011) [#18]

Changed the updates to use a high Fixed Rate Logic ...

Does it work okay now?

http://www.therevillsgames.com/monkey/platformer/

D4NM4N

(Posted 2011) [#19]

Runs nice and smooth on crome on ubuntu.