Ignition X beta released!

Strict

Import demo

Import playniax.ignitionx.physics.box2dengine
Import playniax.ignitionx.physics.rube.importer
Import playniax.ignitionx.physics.rube.box2dworldcreator

Class Game Extends iBox2dEngine
 
Field rubeData:iRubeImporter
Field pwc:iBox2dWorldCreator

Field playfield:iPlayfield
Field gameLayer:iLayer
Field label:iGuiText

' Reference to physics objects we are interested in for this example
Field truckChassis:iRubeEntity
Field truckWheelRear:iRubeEntity
Field truckWheelfront:iRubeEntity

Method OnCreate:Int()
	
	Self.playfield = New iPlayfield
	Self.playfield.AttachLast()
	Self.playfield.Virtual(640, 480, True)
	Self.playfield.AutoCls(0, 0, 0)
	
	Self.gameLayer = New iLayer()
	Self.gameLayer.AttachLast(Self.playfield)
	Self.playfield.zoomX = 1
	Self.playfield.zoomY = 1
	
	' Switch debug draw on
	PhysicsDebug(True)
	
	'Set the physics draw scale
	PhysicsScale(30.0)
	
	' Create an instance of Rube read for setting up physics and importing data										
	Self.rubeData = New iRubeImporter()		
	Self.rubeData.ImportRubeData("truck.json")
	
	ResetScene()
	
	Return 0

End Method

Method OnUpdate:Int()

	'track the camera to the truck chassis:
	Self.playfield.cameraX = Self.truckChassis.x - deviceWidth / 3
	Self.playfield.cameraY = Self.truckChassis.y - deviceHeight / 2
	
	Local maxSpeed:Float = 20.0
	Local desiredSpeed:Float = 0.0
	
	If iKeyDown(KEY_LEFT)
		desiredSpeed = -maxSpeed
	End If

	If iKeyDown (KEY_RIGHT)
		desiredSpeed = maxSpeed
	End If
	
	'Apply angular velocity to truck wheels:
	iBox2dBodyMoveController(Self.truckWheelfront.MoveController).PhysicsBody().SetAngularVelocity(desiredSpeed)
	iBox2dBodyMoveController(Self.truckWheelRear.MoveController).PhysicsBody().SetAngularVelocity(desiredSpeed)
	
	If iKeyDown(KEY_R)
		
		ResetScene()
		
	Endif
	
	Return 0

End Method

' Reset the scene - you will probably need to use this a lot :)
Method ResetScene:Void()
	
	' Create the physics world
	Self.pwc = New iBox2dWorldCreator(Self, Self.rubeData, Self.gameLayer, Self.gameLayer)
	Self.pwc.CreatePhysicsWorld()

	' Loop through the entities created by the world creater to get a reference to the chassis and wheels
	For Local i:Int = 0 To Self.pwc.PhysicsEntities().Length() -1
			
			If Self.pwc.PhysicsEntities[i].RubeBody().name = "truckwheelfront"
				Self.truckWheelfront = Self.pwc.PhysicsEntities[i]
			Endif
			
			If Self.pwc.PhysicsEntities[i].RubeBody().name = "truckwheelrear"
				Self.truckWheelRear = Self.pwc.PhysicsEntities[i]
			Endif
			
			If Self.pwc.PhysicsEntities[i].RubeBody().name = "truckchassis"
				Self.truckChassis = Self.pwc.PhysicsEntities[i]
			Endif
			
	Next

End Method
	
End Class