Get the MAC address of a LAN client ?

Community Forums/General Help/Get the MAC address of a LAN client ?

Panno

(Posted 2010) [#1]

as the topic say :

how to "Get the MAC address of a LAN client" in bmax without tools such like arp -a

BlitzSupport

(Posted 2010) [#2]

I tried this a few days ago and failed, but finally got it working today:

Function GetMac:String (ip:String) 

	Local buffsize = 8
	Local MacAddr:Byte [buffsize] ' Got to pass at least two ints...
	Local addr = inet_addr (ip.ToCString ()) ' Convert IP to C string...
	Local mac$ = ""
	
	If addr <> -1
	
		error = SendARP (addr, 0, Varptr MacAddr [0], Varptr buffsize)

		If error = 0
			
			If buffsize
	
				' First 6 bytes contain MAC address (each byte padded out as 00
				' and separated by colons)...
				
				For i = 0 To 5
					mac$ = mac$ + RSet (Hex (MacAddr [i] & 255), 2) + ":"
				Next
				
				Return mac$ [.. Len (mac$) - 1] ' Strip last ":"
	
			Else
				Print "Error -- check if IP has an associated MAC! cmd -> ipconfig /all"
				Return "No MAC address found!"
			EndIf
		
		Else
			Print "SendARP failed!"
			Return "No MAC address found!"
		EndIf

	Else
		Print "inet_addr failed"
		Return "No MAC address found!"
	EndIf
	
End Function

' Functions needed...

Global SendARP (dest, src, mac:Byte Ptr, maclen:Byte Ptr)
Global inet_addr:Int (cp:Byte Ptr)
Global inet_ntoa:Byte Ptr (in)

' Load functions from libraries...

ws$ = "ws2_32.dll"
wslib = LoadLibraryA (ws)

iphelp$ = "iphlpapi.dll"
iphlplib = LoadLibraryA (iphelp)

If iphlplib
	SendArp = GetProcAddress (iphlplib, "SendARP")
Else
	RuntimeError "Can't open IP Help library!"
EndIf

If wslib
	inet_addr = GetProcAddress (wslib, "inet_addr")
	inet_ntoa = GetProcAddress (wslib, "inet_ntoa")
Else
	RuntimeError "Can't open WinSock 2 library!"
EndIf

' D E M O . . .

Print ""
Print "MAC addresses found..."
Print ""

' This just gets your public IP for the demo (MAY CAUSE FIREWALL TO PROMPT FOR ACCESS!)...

ip = ReadStream ("http::www.hi-toro.com/ip.php")
address$ = ReadLine (ip)
CloseStream ip

Print GetMac (address)
Print ""

' Some common default gateways (router IPs). Expect "SendARP failed!" messages if
' not valid for your network!

Print GetMac ("192.168.0.1")
Print ""
Print GetMac ("192.168.1.1")
Print ""
Print GetMac ("192.168.2.1")
Print ""
Print GetMac ("192.168.1.254")
Print ""

End ' IMPORTANT! This MUST be called if exiting right away on SendARP failing. For
	' some reason, if your program exits immediately without this here, it crashes!
	' Allowing a delay of a couple of seconds can also cure the problem. Weird...

This is Windows NT-specific, but the basic process is the same across OSes -- they all use sendarp, inet_addr, etc, as far as I know.

Please note that the demo obtains your public IP from my web site, so may pop up a firewall warning. Just comment those lines out of that's a problem, and specify the local IP you want to retrieve the MAC from. [EDIT: Actually, on XP my public IP has an associated MAC, but on '7 it doesn't, so don't be surprised if that test fails.]

Please note dire warning at bottom of code! Not sure what causes that...

Panno

(Posted 2010) [#3]

wow many thanks James.
sendarp with the iphlpapi.dll i dig this out from some vbforum but i get it never runing

thx again

AJ00200

(Posted 2010) [#4]

Yes, the ARP protocal is supported by all RFC compliant devices.