please help Glow question

Community Forums/General Help/please help Glow question

NotAGamer

(Posted 2016) [#1]

i've been very serious to make a game and i want to use blitz3d for fast prototyping my game..

i read this code and its amazing .. but if you changed the alpha of the sprite to 0.8

you can see that the sprite is not in the middle.. has any body know how to make this work and make the sprite centerd?

http://www.blitzbasic.com/codearcs/codearcs.php?code=1351

Kryzon

(Posted 2016) [#2]

Use this code archive entry:
http://www.blitzbasic.com/codearcs/codearcs.php?code=2862

You can modify it like this:

AppTitle "Motion Blur"
Graphics3D 640,480,0,2
SetBuffer BackBuffer()

Global buffer_size% = 256

blurtex = CreateTexture(buffer_size,buffer_size)

Global objecttex = CreateTexture(128,128)
SetBuffer TextureBuffer(objecttex)
Color 255,255,0
Rect 0,0,128,128
Color 0,127,255
Rect 0,0,64,64,True
Rect 64,64,64,64,True
SetBuffer BackBuffer()

Global camera% = CreateCamera()
CameraRange camera,0.1,1000

Global cube% = CreateCube()
PositionEntity cube,0,0,3
EntityTexture cube,objecttex

blurquad = CreateMesh()
surf = CreateSurface(blurquad)

Local texOffset# = 0.5 / buffer_size ;Prevents texture sliding.

AddVertex(surf,-1,1,0,0+texOffset,0+texOffset)
AddVertex(surf,1,1,0,1+texOffset,0+texOffset)
AddVertex(surf,1,-1,0,1+texOffset,1+texOffset)
AddVertex(surf,-1,-1,0,0+texOffset,1+texOffset)
AddTriangle(surf,0,1,2)
AddTriangle(surf,0,2,3)
EntityTexture blurquad,blurtex
PositionEntity blurquad,0,0,1
EntityFX blurquad,1
EntityAlpha blurquad,0.8 ;Never 1.0 so there's some decay, else it saturates.
EntityOrder blurquad,-1
Const BLEND_ADD = 3
EntityBlend blurquad, BLEND_ADD

Local timer = CreateTimer( 30 )

While Not KeyHit(1)
	WaitTimer( timer )
	Cls
	
	TurnEntity cube,1,2,3
	UpdateWorld()

	CameraViewport camera,0,0,buffer_size,buffer_size
	RenderWorld()
	CopyRect 0,0,buffer_size,buffer_size,0,0,BackBuffer(),TextureBuffer(blurtex)

	CameraViewport camera,0,0,GraphicsWidth(),GraphicsHeight()

	RenderWorld()
	
	Flip True
Wend

End

NotAGamer

(Posted 2016) [#3]

@kyrzon

thank you very much!!!!!

Yue	(Posted 2016) [#4]

Graphics3D 640,480,32,2
SetBuffer BackBuffer()

; Create camera
Global camera=CreateCamera()
MoveEntity camera,3,3,0
RotateEntity camera,30,30,0

light=CreateLight()

Global cube=CreateCube()
PositionEntity cube,0,0,5
tex0=CreateTexture(300,300)
SetBuffer TextureBuffer(tex0)
ClsColor 255,0,0
Cls
SeedRnd(MilliSecs())
For k=1 To 50
	Color Rand(256),Rand(256),Rand(256)
	Rect Rand(600),Rand(600),Rand(600),Rand(600)
Next
EntityTexture cube,tex0
SetBuffer BackBuffer()

;glow setup
s=1
Global sizex=640/s
Global sizey=480/s
Global glowtexture=CreateTexture (384,384,256)
Global sp=CreateSprite(camera)
MoveEntity sp,-.25,-0.06,1.18
EntityAlpha sp,.32
ScaleTexture glowtexture,GraphicsWidth()/sizex,GraphicsHeight()/sizey
EntityTexture sp,glowtexture
TextureBlend glowtexture, 5
While Not KeyDown( 1 )
	TurnEntity cube,0.5,0.5,0.5
	CameraViewport camera,0,0,sizex,sizey
	RenderWorld
	CopyRect 0,0,sizex,sizey,0,0,BackBuffer(),TextureBuffer(glowtexture)
	CameraViewport camera,0,0,GraphicsWidth(),GraphicsHeight()
	
	RenderWorld
	Flip
Wend

End

Graphics3D 640,480,32,2
SetBuffer BackBuffer()

; Create camera
Global camera=CreateCamera()
MoveEntity camera,3,3,0
RotateEntity camera,30,30,0

light=CreateLight()

Global cube=CreateCube()
PositionEntity cube,0,0,5

;Global cube2=CreateCube() 
;PositionEntity cube2,-5,0,5

tex0=CreateTexture(300,300)
SetBuffer TextureBuffer(tex0)
ClsColor 255,255,255
Cls
SeedRnd(MilliSecs())
For k=1 To 50
	Color Rand(256),Rand(256),Rand(256)
	Rect Rand(600),Rand(600),Rand(600),Rand(600)
Next
EntityTexture cube,tex0
SetBuffer BackBuffer()

;glow setup
s=1
Global sizex=640/s
Global sizey=480/s
Global glowtexture=CreateTexture (384,384,256)
Global sp=CreateSprite(camera)
MoveEntity sp,-.25,-0.06,1.21
ScaleTexture glowtexture,GraphicsWidth()/sizex,GraphicsHeight()/sizey
EntityTexture sp,glowtexture

TextureBlend glowtexture, 5    ;Also try mode 2 ...and increase the Alpha from 0.44 to about 0.80
EntityAlpha sp, 0.44

While Not KeyDown( 1 )
	TurnEntity cube,0.5,0.5,0.5
	CameraViewport camera,0,0,sizex,sizey
;	RenderWorld
	CopyRect 0,0,sizex,sizey,0,0,BackBuffer(),TextureBuffer(glowtexture)
	CameraViewport camera,0,0,GraphicsWidth(),GraphicsHeight()
	
	RenderWorld
	Flip
Wend

End

Type entlist
	Field ent
End Type


Graphics3D 1024,768,32,2
AmbientLight(10,10,20)
light=CreateLight()
PositionEntity light,-500,5000,2000
LightColor light,200,200,200
RotateEntity light,45,45,0
	
camera = CreateCamera()

ob1 = CreateCylinder()
PositionEntity ob1,0,1,7
EntityColor ob1,0,0,255
EntityFX ob1,1 
AddEnt(ob1)
		
ob2 = CreateCone()
PositionEntity ob2,-4,1,7
EntityColor ob2,0,255,0
EntityFX ob2,1
AddEnt(ob2)
	
ob3 = CreateSphere()
PositionEntity ob3,4,1,7
EntityColor ob3,255,255,255
AddEnt(ob3)
	
column = CreateCylinder()
ScaleEntity column,2,100,2
PositionEntity column,50,0,100
EntityColor column,255,0,0
EntityFX column,1
AddEnt(column)
	
	
While Not KeyHit(1)
	TurnEntity ob1,1,1,1
	TurnEntity ob2,1,1,1
	TurnEntity ob3,1,1,1
	TurnEntity column,1,1,1
	UpdateWorld
	RenderWorld 

	EntityGlow(camera,ob1,4,.2,50,50,255)
	EntityGlow(camera,ob2,3,.05,50,255,50)
	EntityGlow(camera,ob3,2,.05,255,255,0)

	
	Flip
Wend
End	
	
	
Function EntityGlow(eg_cam,eg_ent,eg_glowsteps=1,eg_glowsize#=.1,eg_r=-1,eg_g=-1,eg_b=-1)
	HideWorld()
	eg_pivot=CreatePivot()
	For eg_i=eg_glowsteps To 1 Step -1
		eg_glowent=CopyMesh(eg_ent)
		ShowEntity eg_glowent
		PositionEntity eg_glowent,EntityX(eg_ent),EntityY(eg_ent),EntityZ(eg_ent)
		RotateEntity eg_glowent,EntityPitch(eg_ent),EntityYaw(eg_ent),EntityRoll(eg_ent)
		EntityFX eg_glowent,1
		EntityBlend eg_glowent,3 ;optional
		ScaleMesh eg_glowent,1+eg_glowsize*eg_i,1+eg_glowsize*eg_i,1+eg_glowsize*eg_i
		EntityAlpha eg_glowent,0.1
		EntityParent eg_glowent,eg_pivot
		If (eg_r+eg_g+eg_b)>0 EntityColor eg_glowent,eg_r,eg_g,eg_b
	Next
	CameraClsMode eg_cam,0,0:RenderWorld:CameraClsMode eg_cam,1,1
	For i=1 To CountChildren(eg_pivot):FreeEntity GetChild(eg_pivot,i):Next
	FreeEntity eg_pivot
	ShowWorld()
End Function
	

;HOUSEKEEPING FUNCTIONS

Function AddEnt(ent)
	e.entlist=New entlist
	e\ent=ent
End Function
Function HideWorld()
	For e.entlist=Each entlist
		HideEntity e\ent
	Next
End Function
Function ShowWorld()
	For e.entlist=Each entlist
		ShowEntity e\ent
	Next
End Function
Function DeleteEnt(ent)
	For e.entlist=Each entlist
		If e\ent=ent
			Delete e
			Exit
		EndIf
	Next
End Function
Function ClearEntList()
		Delete Each entlist
End Function

RemiD

(Posted 2016) [#5]

Worth a mention is the method demonstrated by sswift (small render of the glowing surfaces in fullbright, then blur of the texture by using several textured quads with an offset at up, down, left, right, upleft, upright, downleft, downright, then display the resulting texture on a quadmesh over the whole screen) not precise but good enough for some cases...
Here : http://www.blitzbasic.com/codearcs/codearcs.php?code=754