Doubt about ragdoll

Community Forums/General Help/Doubt about ragdoll

Yue	(Posted 2014) [#1]

Anyone have a theoretical knowledge of how the ragdoll is performed, some information material explaining something.

RemiD

(Posted 2014) [#2]

https://www.google.fr/?gws_rd=ssl#q=ragdoll+site:blitzbasic.com
http://en.wikipedia.org/wiki/Ragdoll_physics

From what i understand, you have to set primitive colliders/bodies as childs of the joints of your character, and set constraints for each joint (how much it can turn/move on each axis), then the physics engine will calculate how the skeleton behaves and how the primitive colliders/bodies collide and react with the environment.

also :
http://www.blitzbasic.com/codearcs/codearcs.php?code=2105

Matty

(Posted 2014) [#3]

Usually a physics engine, even a simple one, can handle this.

There are some things in the code archives but my experience with physics engines is limited since I generally made arcade games where this sort of behaviour could be approximated.

As RemiD says, you create "bones" by using different types of primitive shaped that your physics engine uses such as cylinders, spheres and so on.

Now, the ragdoll doesn't actually need to be built until the character is about to perform its ragdoll animation, such as a death or something. At this point you would assign the ragdoll and allow the physics engine to take over. However you still have to then align the bones of the 3d model such that they follow the positions of the ragdoll's bones.

So in blitz3d you would have two models. Your ragdoll model and your character model. The ragdoll model is purely a reference that you use to determine rotations etc for your character model when it falls over etc.

Now, an alternative which is much simpler is to create a host of animations for your character in your 3d software which includes physics and simply play back pre recorded animations, often chosen from a variety of animations provided.

Hope that helps.

Yue	(Posted 2014) [#4]

Bullet is an example of a ragdoll, but failed to use that as a reference for incrustrarlo mesh.

In this case in rigid body should occupy the same position of the articulation of the head, but I have no idea how to do that.


;*******************************************************************
;*******************************************************************
;***                                        
;***	Example of use BlitzBullet 
;***	(Physics Bullet Library wrapper for Blitz3D) 
;***   
;***	(c) 2010-2011 Mirage-lab Team 
;***	www.tools.mirage-lab.com                       
;***                                                  
;*******************************************************************
;*******************************************************************

Include "..\include\BlitzBullet.bb"

Graphics3D 800, 600,32,2
AppTitle "BlitzBullet: Ragdoll"
SetBuffer(BackBuffer())
SetFont LoadFont("Blitz")
SeedRnd MilliSecs ()

btCreateWorld(0,"license_key")
btCreateDebugDraw()
btDebugDrawSetMode(0)
btWorldSetFixedTimeStep(1.0/60)
btContactSetSolverMode(SOLVER_USE_2_FRICTION_DIRECTIONS+SOLVER_SIMD+SOLVER_RANDMIZE_ORDER)

camera=CreateCamera()
AmbientLight 180,180,180
PositionEntity camera,0,90,-75
RotateEntity camera,20,0,0
CameraClsColor camera,70,70,70

AmbientLight 140,140,140
light=CreateLight()
RotateEntity light,25,0,20

Global meshPlane=CreatePlane()
Global tex=LoadTexture("..\media\cell.png")
Global tex_mesh=LoadTexture("..\media\cell.png")
ScaleTexture tex,10,10
EntityTexture meshPlane,tex,0,1 

btBodyCreatePlane(0,1,0)

mass#=12
bodyTrunk=phCreateCapsule(5,3,mass)
btBodySetPosition(bodyTrunk,0,83,0)

bodyPelvis=phCreateCapsule(5,2,mass)
btBodySetPosition(bodyPelvis,0,70,0)

bodyLegLeft1=phCreateCapsule(2.4,9,mass) 
btBodySetPosition(bodyLegLeft1,-5,58,0)
btBodySetRotation(bodyLegLeft1,0,0,-10)

bodyLegLeft2=phCreateCapsule(2,7,mass) 
btBodySetPosition(bodyLegLeft2,-7,45,0)
btBodySetRotation(bodyLegLeft2,0,0,-6)

bodyLegRight1=phCreateCapsule(2.4,9,mass) 
btBodySetPosition(bodyLegRight1,5,58,0)
btBodySetRotation(bodyLegRight1,0,0,7)

bodyLegRight2=phCreateCapsule(2,7,mass) 
btBodySetPosition(bodyLegRight2,7,45,0)
btBodySetRotation(bodyLegRight2,0,0,7)

bodyArmLeft1=phCreateCapsule(2,7,mass) 
btBodySetPosition(bodyArmLeft1,-11,85,0)
btBodySetRotation(bodyArmLeft1,0,0,-80)

bodyArmLeft2=phCreateCapsule(2,5,mass) 
btBodySetPosition(bodyArmLeft2,-21,83,0)
btBodySetRotation(bodyArmLeft2,0,0,-80)

bodyArmRight1=phCreateCapsule(2,7,mass) 
btBodySetPosition(bodyArmRight1,11,85,0)
btBodySetRotation(bodyArmRight1,0,0,80)

bodyArmRight2=phCreateCapsule(2,5,mass) 
btBodySetPosition(bodyArmRight2,21,83,0)
btBodySetRotation(bodyArmRight2,0,0,80)

bodyHead=phCreateSphere(3.5)
btBodySetMass(bodyHead,0)
btBodySetPosition(bodyHead,0,90,0)
btBodySetRotation(bodyHead,0,0,0)
EntityColor phSphereGetEntity(),150,150,90
	
Const M_ANG=160
Const M_ANG_2=120
Const M_ANG_4=70
Const M_ANG_5=70

jointHead=btJointCreateConeTwist(bodyTrunk,bodyHead, 0,7,0,0, 0,-3,0,0, 1)
btJointConeTwistSetLimit(jointHead, M_ANG_5, M_ANG_5, M_ANG_5)

;--- left arm
jointArmL1=btJointCreateConeTwist(bodyTrunk,bodyArmLeft1, -6,87,0,1, -5,87,0,1, 1)
btJointConeTwistSetLimit(jointArmL1, M_ANG_5, M_ANG_5, M_ANG_5)

jointArmL2=btJointCreateHinge(bodyArmLeft1,bodyArmLeft2, -17,84,0,1, -17,84,0,1, 1)
btJointHingeSetLimit(jointArmL2,-120,0)
btJointSetRotationA(jointArmL2,0,90,0)
btJointSetRotationB(jointArmL2,0,90,0)

;--- right arm
jointArmR1=btJointCreateConeTwist(bodyTrunk,bodyArmRight1, 6,87,0,1, 5,87,0,1, 1)
btJointConeTwistSetLimit(jointArmR1, M_ANG_5, M_ANG_5, M_ANG_5)

jointArmR2=btJointCreateHinge(bodyArmRight1,bodyArmRight2, 17,84,0,1, 17,84,0,1, 1)
btJointHingeSetLimit(jointArmR2,-120,0)
btJointSetRotationA(jointArmR2,0,90,0)
btJointSetRotationB(jointArmR2,0,90,0)

;--- pelvis
jointPelvis=btJointCreateHinge(bodyTrunk,bodyPelvis, 0,76,0,1, 0,76,0,1, 1)
btJointHingeSetLimit(jointPelvis,-90,90)
btJointSetRotationA(jointPelvis,0,90,0)
btJointSetRotationB(jointPelvis,0,90,0)

;--- left leg
jointLegL1=btJointCreateConeTwist(bodyPelvis,bodyLegLeft1, -4,65,0,1, -4,65,0,1, 1)
btJointConeTwistSetLimit(jointLegL1,M_ANG_2, M_ANG_2, 90)
btJointSetRotationA(jointLegL1,0,0,90)
btJointSetRotationB(jointLegL1,0,0,90)

jointLegL2=btJointCreateHinge(bodyLegLeft1,bodyLegLeft2, -6,51,0,1, -6,51,0,1, 1)
btJointHingeSetLimit(jointLegL2,0,120)
btJointSetRotationA(jointLegL2,-10,90,90,1)
btJointSetRotationB(jointLegL2,-10,90,90,1)

;--- right leg
jointLegR1=btJointCreateConeTwist(bodyPelvis,bodyLegRight1, 4,65,0,1, 4,65,0,1, 1)
btJointConeTwistSetLimit(jointLegR1,M_ANG_2, M_ANG_2, 90)
btJointSetRotationA(jointLegR1,0,0,90)
btJointSetRotationB(jointLegR1,0,0,90)

jointLegR2=btJointCreateHinge(bodyLegRight1,bodyLegRight2, 6,51,0,1, 6,51,0,1, 1)
btJointHingeSetLimit(jointLegR2,0,120)
btJointSetRotationA(jointLegR2,10,90,90,1)
btJointSetRotationB(jointLegR2,10,90,90,1)


Global mx#,my#,msx#,msy#
Global hide=0
MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
HidePointer 

Repeat	
	
	If KeyHit(2) btDebugDrawSetMode(0)
	If KeyHit(3) btDebugDrawSetMode(1)
	If KeyHit(4) btDebugDrawSetMode(1+DBG_JOINTLIMITS+DBG_JOINTS)
	If KeyHit(5) btDebugDrawSetMode(DBG_JOINTLIMITS+DBG_JOINTS)

	msx#=MouseXSpeed()
	msy#=MouseYSpeed()
	Camera_Look(camera)

	If KeyHit(35)
		HideShowMeshes()
	EndIf

	If MouseHit(1)
		sphere=phCreateSphere()
		TFormVector (0,0,1,camera,0)
		btBodySetPosition sphere,EntityX(camera)+TFormedX()*10,EntityY(camera)+TFormedY()*10,EntityZ(camera)+TFormedZ()*10
		btBodyApplyImpulse(sphere,TFormedX()*1000, TFormedY()*1000, TFormedZ()*1000)
	EndIf

	btSimulation(.1,6)
	
	UpdateWorld()
	RenderWorld()
	btDebugDrawWorld(camera)
	
	frames=frames+1
   	If MilliSecs()-render_time=>1000  fps1=frames : frames=0 : render_time=MilliSecs()  
 	Text 10,10,"FPS: "+fps1
	Text 10,30,"1,2,3,4 - debug draw mode"
	Text 10,50,"H - hide/show meshes"
	Text 10,70,"W,A,S,D - move camera"
	Text 10,90,"Left mouse - to throw sphere"
	
	Flip 1
	
Until KeyHit(1)

btDestroyWorld()
End

Type phEntity
	Field mesh
	Field body
End Type

Function HideShowMeshes()

	If hide=0 Then
		For phEnt.phEntity = Each phEntity
			HideEntity phEnt\mesh
		Next
		hide=1
	Else
		For phEnt.phEntity = Each phEntity
			ShowEntity phEnt\mesh
		Next
		hide=0
	EndIf
	
End Function

Function phSphereGetEntity%()
	
	phEnt.phEntity = Last phEntity
	Return phEnt\mesh
	
End Function

Function phCreateSphere%(radius#=0)
	
	phEnt.phEntity = New phEntity
	If radius<=0 Then
		radius#=Rnd(2,4)
	EndIf
	phEnt\mesh=CreateSphere()
	EntityShininess phEnt\mesh,0.5
	ScaleEntity phEnt\mesh,radius,radius,radius
	phEnt\body=btBodyCreateSphere(radius,Rnd(4,6))
			
	If hide=1
		HideEntity phEnt\mesh
	EndIf

	EntityColor phEnt\mesh,Rand(100,200),Rand(100,200),Rand(100,200)
	
	btBodySetPosition(phEnt\body,Rnd(-50,150),Rnd(50,100),Rnd(-50,50))
	btBodySetRotation(phEnt\body,Rnd(-180,180),Rnd(-180,180),Rnd(-180,180))
	btBodyAttachEntity(phEnt\body,phEnt\mesh)
	
	btBodySetAngularSleepingThreshold(phEnt\body,1)
	btBodySetLinearSleepingThreshold(phEnt\body,1)

	Return phEnt\body
End Function

Function phCreateCapsule%(radius#, height#, mass#)
	
	phEnt.phEntity = New phEntity
	phEnt\mesh=CreateCapsule(radius, height)
	EntityShininess phEnt\mesh,0.2
	phEnt\body=btBodyCreateCapsule(radius, height, mass)
			
	If hide=1
		HideEntity phEnt\mesh
	EndIf

	EntityColor phEnt\mesh,150,150,70
	btBodyAttachEntity(phEnt\body,phEnt\mesh)
	
	btBodySetAngularSleepingThreshold(phEnt\body,0.1)
	btBodySetLinearSleepingThreshold(phEnt\body,0.1)

	Return phEnt\body
End Function

Function CreateCapsule(radius#,height#)

	capsule= CreateCylinder()
	ScaleMesh capsule, radius, height/2, radius
	PositionMesh capsule,0,0,0
	EntityPickMode capsule,2
	EntityColor capsule,150,150,90
	
	sphere1 = CreateSphere() 
	ScaleMesh sphere1,radius,radius,radius
	PositionMesh sphere1,0, height/2,0
	AddMesh sphere1,capsule
	
	sphere2 = CreateSphere() 
	ScaleMesh sphere2,radius,radius,radius
	PositionMesh sphere2,0, -height/2,0
	AddMesh sphere2,capsule
	
	FreeEntity sphere1
	FreeEntity sphere2
	;HideEntity capsule
	;EntityAlpha capsule,0.1
	
	Return capsule
End Function

Function Camera_Look(cam,speedx#=.5,speedy#=.5,dang=-89,upang=89)

	If KeyDown(17) Then
		MoveEntity cam,0,0,1
	Else
		If KeyDown(31) Then MoveEntity cam,0,0,-1
	EndIf
	If KeyDown(30) Then 
		MoveEntity cam,-1,0,0	
	Else
		If KeyDown(32) Then MoveEntity cam,1,0,0
	EndIf	
	
	xrot#=EntityPitch(cam)
	yrot#=EntityYaw(cam)
	If(xrot#<upang)And(msy>0)Then xrot#=xrot#+speedx#*msy/10  
	If(xrot#>upang)And(msy>0)Then xrot#=upang	
	If(xrot#>dang)And(msy<0)Then xrot#=xrot#+speedx#*msy/10 
	If(xrot#<dang)And(msy<0)Then xrot#=dang		
	yrot=yrot-speedy#*msx/10 
	MoveMouse GraphicsWidth()/2,GraphicsHeight()/2
	RotateEntity cam,xrot,yrot,0
End Function

Who was John Galt?

(Posted 2014) [#5]

http://en.wikipedia.org/wiki/Verlet_integration