Blitz can't find while under wend. But I can.

Community Forums/General Help/Blitz can't find while under wend. But I can.

Elzic

(Posted 2014) [#1]

Does anybody know what's going on? here is the apparently offending code, i'm using it to easily draw a grid of squares:

Graphics 800,600
SetBuffer BackBuffer

Dim gridxy(19,19)

While vy < 600
A = A+1
B = B
If B = 0 Then
B = 1
EndIf
xs = xs + 1
vx = -800 + 40*A
vy = -600 + 30*B
gridxy(xs,ys) = (vx),(vy)
If vx > 800 Then
vx = -800
A = 0
B = B+1
ys = ys + 1
EndIf
Wend

I've tried using repeat-until unsuccessfully as well.
I've have been having trouble with If and Then and an error saying that there are too many parameters also.
I'm new to basic, so don't get mad at me if these are just a lot of stupid questions.

Elzic

(Posted 2014) [#2]

btw: the code is tabbed, just not on this post, although I have no idea if that makes a difference or not.

Floyd

(Posted 2014) [#3]

The cursor points to the real offender, despite the misleading error message.

It's not always easy to find the cursor. If you hold down the shift key and press up-arrow it should highlight at least part of the offending line. In this case it is

gridxy(xs,ys) = (vx),(vy)

RemiD

(Posted 2014) [#4]

An example of how to use a 2D dim array :

Graphics(800,600,32,2)

;Let's imagine that i have a grid with 10x10 cells and i want to store the state of a cell at X,Y

;Create the dim array
Dim CellState%(9,9) ;9,9 because the array entries go from 0 to 9

;Write a value in the dim array
For CX% = 0 To 9
 For CY% = 0 To 9
  TState% = Rand(0,10)
  DebugLog("TState at "+CX+","+CY+" = "+TState)
  CellState(CX,CY) = TState
 Next
Next

;Read a value in the dim array
For CX% = 0 To 9
 For CY% = 0 To 9
  DebugLog("CellState("+CX+","+CY+") = "+CellState(CX,CY))
 Next
Next

FlushKeys()
WaitKey()
End()

An example of how to use a While Wend loop :

Graphics(800,600,32,2)

TValue% = 0

While(TValue < 100)
 TValue = TValue + 1
 DebugLog("TValue = "+TValue)
Wend

FlushKeys()
WaitKey()

End()

An example of how to use a Repeat Until loop :

Graphics(800,600,32,2)

TValue% = 0

Repeat
 TValue = TValue + 1
 DebugLog("TValue = "+TValue)
Until(TValue = 100)

FlushKeys()
WaitKey()

End()

I think you should post in the BlitzPlus forums or in the Blitz3d forums, not in this forum.

dawlane

(Posted 2014) [#5]

@Elzic: When it comes to programming you need to follow what's know as the KISS principle.

IF/THEN/ELSE general structure
One line

IF x>800 THEN B=1 ELSE B=0

Multi-line

IF X>800
B=1
ELSE
B=0
ENDIF

The nested (loop within a loop) For/Next in RemiD's example is the simplest solution. Another solution would be to use a custom type to store the x,y coordinates and use a one dimensional array with a quick calculation to get the position. Using a type is more versatile as you can group related data like if the grid location was to hold a image for part of a level.

You should read the wiki for For/Next,While/Wend. The Repeat/Until loop is the same as the While/Wend loop with the only difference being is that the loop is performed at least once. You should also read up on how arrays work, especially their structure.

Drawing a grid using while/wend and Repeat/Until and using Not. You can remove Not and replace the equal sign (=) with a less-than (<)

Graphics 800,600
SetBuffer BackBuffer()

Dim gridxy(20,20) ; Array to hold grid coordinates

Local gy=0
Local gx=0

Local row=0
Local col=0

; Create top/left grid coordinate
While Not col = 20 ; if the column count is not equal to 20 then carry on
	While Not row = 20 ; if the row count is not equal to 20 then carry on
		gridxy(row,col) = gy ; Store the current grid position for y on current row and column
		gy=gy + 30	; 600 divide by 20 is 30
		row=row+1 ; Inrease the row count
	Wend
	
	; Reset both the row count and the grids y coordinate position
	row=0 
	gy=0
	
	; Add the x axis to the grid array
	gridxy(row,col) = gx ; Store the current grid position for x on current row and column
	gx=gx + 40 ; 800 divide by 20 is 40
	col=col + 1	; Increase the column count
	
Wend

; Reset the column and rows for drawing the grig
col=0
row=0

; Loop to draw grid
While Not KeyDown(1)
	
	While Not col = 20
		
		gx = gridxy(row,col) ; Get current x position from array
		Repeat
			row=row + 1
			gy = gridxy(row,col) ; Get current y position from array
			; Checker pattern
			If (col+row) Mod 2 = 0
				Color 0,0,255
			Else
				Color 255,0,0
			EndIf
			Rect gx,gy,40,30
			
			; Draw a box	
			Color 255,255,255
			Line gx, gy, gx+40, gy ; Top
			Line gx, gy, gx, gy + 30 ; Left
			Line gx + 39, gy, gx + 39,gy + 30 ; Right
			Line gx, gy + 29, gx + 39,gy + 29 ; Right
		Until row = 20
		row=0
		col=col+1
	Wend
	col=0
	row=0
	Flip
Wend

Same thing but using a custom type

Graphics 800,600
SetBuffer BackBuffer()

Type TColour
	Field red
	Field blue
	Field green
End Type

Type TGrid
	Field x
	Field y
	Field colour.TColour
End Type	

Dim gridxy.TGrid(400) ; Array to hold grid coordinates 20x20=400

Local gy=0
Local gx=0
Local index = 0

While gy < 600
	While gx < 800
		; Create a new instance of a grid
		gridxy(index) = New TGrid
		gridxy(index)\x = gx
		gridxy(index)\y = gy
		gridxy(index)\colour = New TColour
		
		; Set the checker pattern colour
		If Not (gx/40 + gy/30) Mod 2
			gridxy(index)\colour\blue = 255
			gridxy(index)\colour\green = 0
			gridxy(index)\colour\red = 0
		Else
			gridxy(index)\colour\blue = 0
			gridxy(index)\colour\green = 255
			gridxy(index)\colour\red = 255
		EndIf
		
		; Calculate the x position and move along to the next column
		gx = gx + 40
		index = index + 1
	Wend
	
	; reset column and do next row down
	gx = 0
	gy = gy + 30
Wend

While Not KeyDown(1)
	For i=0 To 399 ; 0-399 400 elements in total
		Color gridxy(i)\colour\red,gridxy(i)\colour\green,gridxy(i)\colour\blue ; Set colour from the custom array element 
		Rect gridxy(i)\x,gridxy(i)\y,40,30 ; Fill in a rectangle
		Color 255,0,0 ; Set the colour for drawing a box
		Line gridxy(i)\x,gridxy(i)\y,gridxy(i)\x+40,gridxy(i)\y ; Top
		Line gridxy(i)\x,gridxy(i)\y,gridxy(i)\x,gridxy(i)\y+30 ; Left
		Line gridxy(i)\x+39,gridxy(i)\y,gridxy(i)\x+39,gridxy(i)\y+30 ; Right
		Line gridxy(i)\x,gridxy(i)\y+29,gridxy(i)\x+39,gridxy(i)\y+29 ; Bottom
	Next
	; To access any element use gridxy(row*total columns in row + column)
Wend

End