How to know if a vertex need to be duplicated or n

Community Forums/General Help/How to know if a vertex need to be duplicated or n

RemiD

(Posted 2013) [#1]

Hello,

When i create a cube in Blitz3d, some vertices are duplicated so that some triangles can have their own vertices (not shared with others triangles), and this allows to have another lighting, a bit like flat shaded lighting but only on some faces.

Now let's say that i have a mesh with all its vertices being shared by several triangles and that i want to have some triangles have their own vertices (not shared with others triangles) so that the lighting is more realistic. How do i know which vertices to duplicate or not ?

I have thought to do this :
->calculate the normal of each triangle
->choose a triangle
->choose a vertex of this triangle
->if this vertex is shared with another triangle
->calculate if the angle between the normal of this triangle and the normal of the other triangle allows to receive lighting from the same direction or not (0 to 180 or -180 to 0)
->if yes
keep only one vertex for the 2 triangles
->if no
create a vertex for each triangle

If you have some experience with this, can you please explain how i can manage to do this ?

The goal is to be able to have a better lighting on mesh which has been welded, that is a mesh where each triangle share its vertices with others triangles.

To illustrate what i mean :

I want a mesh like the one at left to be recreated so that it will be lighted like the one at right.

But with more complex meshes.

Any suggestions will be appreciated.

Thanks,

Yasha

(Posted 2013) [#2]

There's a code archive entry that will do pretty much what you need, already written courtesy of BIG BUG: UpdateNormalsAngle

You can specify the threshold angle below which faces will share vertices, and it will take care of the details. Handy stuff.

RemiD

(Posted 2013) [#3]

Yasha>>i have already seen this code but i thought that it only calculated new vertices normals, not create new vertices.

I will study it. Thanks.

Yasha

(Posted 2013) [#4]

I could be misremembering what it does, but in any case if necessary you can always supplement it with two other steps:

1) Do a full unweld of the mesh
2) UpdateNormalsAngle
3) Do a weld only of those vertices that have identical normals as well as position

It's a bit roundabout, but you'll get the same end result eventually.

Kryzon

(Posted 2013) [#5]

I coded a system like this for my B3D exporter for 3DS Max.
In my case, I was using the SMOOTHING GROUPS as reference to know which vertices to BREAK or to WELD, but in your case you're using as reference the triangles that are COPLANAR.

The logic steps you described are somewhat similar, but I preferred to work in a vertex-level instead of triangle. That is, I went through all vertices, identified which triangles it belonged to, THEN checked the normal of these triangles and for any triangles with a different normal, I duplicated the vertex and assigned this duplicate to the triangle.

It's imperative that you leave the original mesh alone, and instead work on an ABSTRACT mesh.
That is, recreate an exact copy of the original mesh but store the geometry information in user-types:

Type TempVertex
	Field index	

	Field x#, y#, z#
	Field #u, #v
	field #nx, #ny, #nz
End Type

Type TempTriangle
	Field index1, index2, index3

	Field vertex1.TempVertex
	Field vertex2.TempVertex
	Field vertex3.TempVertex	
End Type

Because this allows you to break or weld vertices more easily than if you kept using Blitz3D surface commands all the time. This way, to "weld" vertices you simply have to assign the same vertex instance to several triangles.

Only at the end is that you use this processed abstract mesh to create an actual Blitz3D mesh with surface and everything.

RemiD

(Posted 2013) [#6]

Ok after some tests, it seems that the code by BigBug doesn't produce what i want achieve, i will try to code my own routine.

Thanks for the advices,

Stevie G

(Posted 2013) [#7]

In my opinion, the best way to do this is ...

1. Weld the mesh to remove any unwelded triangles.
2. Unweld the mesh to ensure all triangles are unwelded
3. Calculate and set all the normals based on the vertices of each triangle.

Example code and functions below ...

Note that I welded entity TEST1 and used updatenormals on it to show the dodgy lighting on a welded version.

Graphics3D 1024,768,32,1

Global LIGHT = CreateLight() : RotateEntity LIGHT, 45,0,0;-135,0
Global CAMERA = CreateCamera()

PositionEntity CAMERA, 0,0,-5

Global TEST1 = CreateCube()
MESHweld( TEST1 )
UpdateNormals TEST1

Global TEST2 = CreateCube()
MESHweld( TEST2 )
MESHunweld( TEST2 )
MESHnormals( TEST2 )

PositionEntity TEST1, -2,0,0
PositionEntity TEST2, 2,0,0

While Not KeyHit(1)

	TurnEntity TEST1 ,1,0,1
	TurnEntity TEST2, 1,0,1

	RenderWorld()
	Flip

Wend

;============================================================
;============================================================
;============================================================

Function MESHweld( Mesh )

	Local S, T, v0,v1,v2,nv0,nv1,nv2, Copy, CS, C
	Local SU

	Copy = CopyMesh( Mesh )

	For S = 1 To CountSurfaces( Mesh )
		ClearSurface GetSurface( Mesh, S ), True, True
	Next

	For SU = 1 To CountSurfaces( Copy )
		CS = GetSurface( Copy, SU )
		S = CreateSurface( Mesh )
		For T = 0 To CountTriangles(CS) - 1
			v0 = TriangleVertex( CS, T, 0 )
			v1 = TriangleVertex( CS, T, 1 )
			v2 = TriangleVertex( CS, T, 2 )
			nv0 = MESHfindvertex( S, VertexX( CS, v0 ) , VertexY( CS, v0 ) , VertexZ( CS, v0 ) )
			If nv0 = -1 nv0 = AddVertex( S, VertexX( CS, v0 ) , VertexY( CS, v0 ) , VertexZ( CS, v0 ) )
			nv1 = MESHfindvertex( S, VertexX( CS, v1 ) , VertexY( CS, v1 ) , VertexZ( CS, v1 ) )
			If nv1 = -1 nv1 = AddVertex( S, VertexX( CS, v1 ) , VertexY( CS, v1 ) , VertexZ( CS, v1 ) )
			nv2 = MESHfindvertex( S, VertexX( CS, v2 ) , VertexY( CS, v2 ) , VertexZ( CS, v2 ) )
			If nv2 = -1 nv2 = AddVertex( S, VertexX( CS, v2 ) , VertexY( CS, v2 ) , VertexZ( CS, v2 ) )
			AddTriangle S, nv0, nv1, nv2
		Next	
	Next
		
	FreeEntity Copy
	
End Function

;============================================================
;============================================================
;============================================================

Function MESHfindvertex( su , x#, y#, z#, tolerance# = .1 )

	Local V

	For V = 0 To CountVertices(su) - 1
	
		If Abs( VertexX( su, V ) - x ) < tolerance  
			If Abs( VertexY( su, V ) - y ) < tolerance 
				If Abs( VertexZ( su, V ) - z ) < tolerance
					Return V
				EndIf
			EndIf
		EndIf
		
	Next
	
	Return -1
	
End Function

;============================================================
;============================================================
;============================================================

Function MESHunweld( Mesh )

	Local S, T, NS, SU, Copy, v0,v1,v2,nv0,nv1,nv2, L

	Copy = CopyMesh( Mesh )

	For S = 1 To CountSurfaces( Mesh )
		ClearSurface GetSurface( Mesh, S ), True, True
	Next
	
	For SU = 1 To CountSurfaces( Copy )
		NS = CreateSurface( Mesh )
		S = GetSurface( Copy , SU )
		For T = 0 To CountTriangles( S ) - 1
			v0 = TriangleVertex( S, T, 0 )
			v1 = TriangleVertex( S, T, 1 )
			v2 = TriangleVertex( S, T, 2 )
			nv0 = AddVertex( NS , VertexX( S , v0 ) , VertexY( S, v0 ) , VertexZ( S, v0 ) )
			nv1 = AddVertex( NS , VertexX( S , v1 ) , VertexY( S, v1 ) , VertexZ( S, v1 ) )
			nv2 = AddVertex( NS , VertexX( S , v2 ) , VertexY( S, v2 ) , VertexZ( S, v2 ) )
			VertexColor NS, nv0 , VertexRed( S, v0 ) , VertexGreen( S, v0 ) , VertexBlue( S, v0 )
			VertexColor NS, nv1 , VertexRed( S, v1 ) , VertexGreen( S, v1 ) , VertexBlue( S, v1 )
			VertexColor NS, nv2 , VertexRed( S, v2 ) , VertexGreen( S, v2 ) , VertexBlue( S, v2 )
			AddTriangle NS , nv0 , nv1 , nv2
		Next
	Next
	FreeEntity Copy

End Function	

;============================================================
;============================================================
;============================================================

Function MESHnormals( mesh )

	Local SU, S, T, V, v0,v1,v2
	Local ax#,ay#,az#,bx#,by#,bz#
	Local Nx#, Ny#, Nz#, Ns#

	For SU = 1 To CountSurfaces(mesh )
		S = GetSurface( mesh , SU )
		For T = 0 To CountTriangles( S )-1
			v0 = TriangleVertex( S, T, 0 )
			v1 = TriangleVertex( S, T, 1 )
			v2 = TriangleVertex( S, T, 2 )
			ax# = VertexX( S, v1 ) - VertexX( S, v0 )
			ay# = VertexY( S, v1 ) - VertexY( S, v0 )	
			az# = VertexZ( S, v1 ) - VertexZ( S, v0 )	
			bx# = VertexX( S, v2 ) - VertexX( S, v1 )
			by# = VertexY( S, v2 ) - VertexY( S, v1 )	
			bz# = VertexZ( S, v2 ) - VertexZ( S, v1 )	
			Nx# = ( ay * bz ) - ( az * by )
			Ny# = ( az * bx ) - ( ax * bz )
			Nz# = ( ax * by ) - ( ay * bx )
			Ns# = Sqr( Nx * Nx + Ny*Ny + Nz*Nz )
			Nx = Nx / Ns
			Ny = Ny / Ns
			Nz = Nz / Ns
			For V = v0 To v2
				VertexNormal S, V, Nx, Ny, Nz 
			Next
		Next
	Next
	
End Function

RemiD

(Posted 2013) [#8]

Stevie G>>Thanks, your example shows what i call a flat shaded mesh, where each triangle has its own vertices, what i want is a mix between this and a progressive shaded, where some triangles share some vertices.

I have already coded a routine similar to yours, i like the render, i may use this afterall.

Let's say that i want to recreate a rigged, skinned, animated mesh, (.b3d), the only way is to write the .b3d file or is there any other way ?

Thanks,

BIG BUG

(Posted 2013) [#9]

You're right, there is no API for bone access, so writing a .b3d file is your only option.

Yasha

(Posted 2013) [#10]

You can dynamically add bones to a mesh at runtime with this: http://www.blitzbasic.com/codearcs/codearcs.php?code=2485

However, the method is very B3D-version-dependent, hasn't been properly tested, etc. etc. I make no guarantee that it actually works. Writing a B3D file is slower but guaranteed to work.

RemiD

(Posted 2013) [#11]

Ok, thanks for the infos. :)