Message-based networking

This code has been declared by its author to be Public Domain code.

Message-based networking by plash

2010

This is a simplified form of the model used in the network module from duct.
I recommend using types for each message, but I've to keep it out of this example for the sake of simplicity.

See the comments below for example code (multiple source files).

' common.bmx

Const MSGID_PING:Int = 10
Const MSGID_PONG:Int = 11

Type TBaseClient Extends TStream Abstract
	
	Field m_socket:TSocket, m_sip:Int
	
	Method Init(socket:TSocket)
		m_socket = socket
		If m_socket
			m_sip = m_socket.RemoteIP()
		End If
	End Method
	
	Method Read:Int(buf:Byte Ptr, count:Int)
		Return m_socket.Recv(buf, count)
	End Method
	
	Method Write:Int(buf:Byte Ptr, count:Int)
		Return m_socket.Send(buf, count)
	End Method
	
	Method ReadAvail:Int()
		Return m_socket.ReadAvail()
	End Method
	
	Method Eof:Int()
		If m_socket
			If m_socket.Connected() = True
				Return False
			End If
		End If
		Close()
		Return True
	End Method
	
	Method Close()
		If m_socket
			m_socket.Close()
			m_socket = Null
		End If
	End Method
	
	Method Connect:Int(remoteip:Int, remoteport:Int)
		m_sip = remoteip
		Return m_socket.Connect(remoteip, remoteport)
	End Method
	
	Method Connected:Int()
		If m_socket
			Return m_socket.Connected()
		End If
		Return False
	End Method
	
	Method Update()
		If Not Eof()
			If ReadAvail() > 0
				HandleMessage(ReadInt())
			End If
		End If
	End Method
	
	Method GetIPAddressAsInt:Int()
		Return m_sip
	End Method
	
	Method GetIPAddressAsString:String(separator:String = ".")
		Return (m_sip Shr 24) + separator + (m_sip Shr 16 & 255) + separator + (m_sip Shr 8 & 255) + separator + (m_sip & 255)
	End Method
	
	Method HandleMessage(id:Int) Abstract
	
End Type

Comments

plash

2010

Example code.

server.bmx

SuperStrict

Framework brl.blitz
Import brl.standardio
Import brl.stream
Import brl.socket
Import brl.linkedlist
Import brl.glmax2d

Include "common.bmx"

AppTitle = "Server"
Graphics(320, 240, 0)

Local server:TServer = New TServer.Create(TSocket.CreateTCP(), 35111)
If server.Start()
	Print("Server started")
	While Not AppTerminate() And Not KeyHit(KEY_ESCAPE)
		server.Update()
		Delay(10)
	End While
Else
	Print("Failed to start server")
End If

Type TServer
	
	Field m_port:Int
	Field m_socket:TSocket
	Field m_clients:TList
	
	Method New()
		m_clients = New TList
	End Method
	
	Method Create:TServer(socket:TSocket, port:int)
		m_port = port
		m_socket = socket
		Return Self
	End Method
	
	Method Start:Int()
		If m_socket <> Null
			If m_socket.Bind(m_port) = True
				m_socket.Listen(0)
				Return True
			End If
		End If
		Return False
	End Method
	
	Method Update()
		For Local client:TServerClient = EachIn m_clients
			client.Update()
		Next
		Local socket:TSocket = m_socket.Accept(0)
		If socket
			AddClient(New TServerClient.Create(socket))
		End If
	End Method
	
	Method AddClient(client:TServerClient)
		client.SetLink(m_clients.AddLast(client))
		client.SendPing()
	End Method
	
	Method Disconnect()
		For Local client:TServerClient = EachIn m_clients
			client.Close()
		Next
		If m_socket
			m_socket.Close()
		End If
	End Method
	
End Type

Type TServerClient Extends TBaseClient
	
	Field m_link:TLink
	
	Method Create:TServerClient(socket:TSocket)
		Init(socket)
		Return Self
	End Method
	
	Method SetLink(link:TLink)
		m_link = link
	End Method
	
	Method RemoveLink()
		If m_link
			m_link.Remove()
			m_link = Null
		End If
	End Method
	
	Method Close()
		Super.Close()
		RemoveLink()
		Print(GetIPAddressAsString() + " disconnected")
	End Method
	
	Method SendPing()
		WriteInt(MSGID_PING)
	End Method
	
	Method HandleMessage(id:Int)
		Select id
			Case MSGID_PONG
				Print("Pong from " + GetIPAddressAsString())
				SendPing()
			Default
				Print("Unknown message id: " + id)
		End Select
	End Method
	
End Type

client.bmx

SuperStrict

Framework brl.blitz
Import brl.standardio
Import brl.stream
Import brl.socket
Import brl.glmax2d

Include "common.bmx"

AppTitle = "Client"
Graphics(320, 240, 0)

Local client:TMasterClient = New TMasterClient.Create(TSocket.CreateTCP())
If client.Connect(HostIP("localhost"), 35111)
	While Not AppTerminate() And Not KeyHit(KEY_ESCAPE)
		client.Update()
		If Not client.Connected()
			Print("Lost connection to server")
			Exit
		End If
	End While
	client.Close()
Else
	Print("Failed to connect to localhost")
End If

Type TMasterClient Extends TBaseClient
	
	Method Create:TMasterClient(socket:TSocket)
		Init(socket)
		Return Self
	End Method
	
	Method SendPong()
		WriteInt(MSGID_PONG)
	End Method
	
	Method HandleMessage(id:Int)
		Select id
			Case MSGID_PING
				Print("Ping from " + GetIPAddressAsString())
				SendPong()
			Default
				Print("Unknown message id: " + id)
		End Select
	End Method
	
End Type

Czar Flavius

2010

"Ping from " + GetIPAddressAsString()

Won't this just print the local IP and not the IP address of the sender?

plash

2010

Won't this just print the local IP and not the IP address of the sender?

No. GetIPAddressAsString is a method of TBaseClient which returns the socket's RemoteIP.

Drackbolt

2010

First, thanks for this!
I have what is probably a newbie question about this and/or Sockets in general. Is each Int sent in a separate packet or is it packed/optimized ? Can this code be quickly modified to transfer string lines instead of integers, or is this code far underneath that layer of control?
I've read up on Stream Sockets where I could but I apologize if I'm asking confused questions.

Code Archives Forum