Clipboard - Text Copy & Paste

This code has been declared by its author to be Public Domain code.

Clipboard - Text Copy & Paste by EOF

2003

A couple of functions for reading and writing text to and from the clipboard.

a$=ReadClipboardText()
Opens the clipboard and passes any available text into a$.

WriteClipboardText "Hello World!"
Opens the clipboard and sends the message there clearing any previous text as it goes.

Credits to the following coders:
Ed from Mars - for clearing up a couple of userlib declarations.
Darkuni - for tracking down potentional collisons when accessing the clipboard.

NOTE:
=====
You need to save a 'user32.decls' file into the userlibs path. See the declarations in the code.

; Clipboard Text Read / Write
; ===========================
; Syntax Error & Ed from Mars


; userlib declarations - 'user32.decls'
; *********************************************
; .lib "user32.dll"
; OpenClipboard%(hwnd%):"OpenClipboard"
; CloseClipboard%():"CloseClipboard"
; ExamineClipboard%(format%):"IsClipboardFormatAvailable"
; EmptyClipboard%():"EmptyClipboard"
; GetClipboardData$(format%):"GetClipboardData"
; SetClipboardData%(format%,txt$):"SetClipboardData"
; *********************************************


Print "Clipboard Test." 
Print "~~~~~~~~~~~~~~~" 
Print "Enter a message for the clipboard." 
Print "Alternatively, leave BLANK to read clipboard." 
a$=Input$(">") 

If a$="" 
	a$=ReadClipboardText$() 
	Print a$
Else 
	WriteClipboardText a$ 
	Print "Text sent to clipboard. Open NotePad and paste!"
EndIf

Print Chr$(13)+"---------------------------------"

a$=Input$("Press RETURN to end ...") 

End

;-----------------------------------

Function WriteClipboardText(txt$)
	Local cb_TEXT=1
	If txt$="" Then Return 
	If OpenClipboard(0)
		EmptyClipboard
		SetClipboardText cb_TEXT,txt$
		CloseClipboard
	EndIf
End Function

;-----------------------------------

Function ReadClipboardText$()
	Local cb_TEXT=1
	Local txt$=""
	If OpenClipboard(0)
		If ExamineClipboard(cb_TEXT) 
			txt$=GetClipboardText$(cb_TEXT)
		EndIf
		CloseClipboard
	EndIf
	Return txt$
End Function

Comments

asdfasdf

2004

Does this work with Blitz3D?

EOF

2004

Yes.

DjBigWorm

2004

Hi,

I tried your Clipboard - Text Copy & Paste.

I found a problem

in the declaration you used
;GetClipboardData$(format%):"GetClipboardData"
But, in the function you called
SetClipboardText cb_TEXT,txt$

I just changed the SetClipboardText to SetClipboardData
as well as GetClipboardText$(cb_TEXT)
should use the word data instead of text.

That is all, thought to let you know so that you could change it. Great functions!!!

Wayne

2005

Junk! Doesn't work.

mongia2

2007

Print "Clipboard Test."
Print "~~~~~~~~~~~~~~~"
Print "Enter a message for the clipboard."
Print "Alternatively, leave BLANK to read clipboard."
a$=Input$(">")

If a$=""
a$=ReadClipboardText$()
Print a$
Else
WriteClipboardText a$
Print "Text sent to clipboard. Open NotePad and paste!"
EndIf

Print Chr$(13)+"---------------------------------"

a$=Input$("Press RETURN to end ...")

End

;-----------------------------------

Function WriteClipboardText(txt$)
Local cb_TEXT=1
If txt$="" Then Return
If OpenClipboard(0)
EmptyClipboard
SetClipboarddata cb_TEXT,txt$
CloseClipboard
EndIf
End Function

;-----------------------------------

Function ReadClipboardText$()
Local cb_TEXT=1
Local txt$=""
If OpenClipboard(0)
If ExamineClipboard(cb_TEXT)
txt$=GetClipboarddata$(cb_TEXT)
EndIf
CloseClipboard
EndIf
Return txt$
End Function

BlackD

2008

The code above I've had trouble rolling out across multiple systems. There seem to be incompatiablities with Vista in some cases where users are not running as administrator and have separate user-space thingees turned on. :P (Even changing the DECLS and code to work off a bank instead.. it'd work on one system them not another).

For a quick and easy way out, I grabbed the clipboard access DLL from here: http://www.icynorth.com/development/clipboard_dll.html
(Public domain release: "You are free to use this DLL in any way that you wish without restrictions." from website, although I'd recommend attribution to Brett Kapilik.)

After renaming the dll to "clipboard.dll" purely for testing, I created this clipboard.decls file:

.lib "clipboard.dll"
IsTextOnClipboard%():"IsTextOnClipboard"
CopyTextToClipboard%(strText$):"CopyTextToClipboard"
GetTextFromClipboard$():"GetTextFromClipboard"

And some sample code:

If IsTextOnClipboard() Then 
	Print "Text already on the clipboard.."
	Print "but we're going To wipe it anyway..":Print
	End If

SeedRnd MilliSecs()
a$="**"+Str$(Rand(0,1000))+"**"
Print "Writing "+a$+" to the clipboard.."
CopyTextToClipboard a$

b$=GetTextFromClipboard$()
Print "Read "+b$+" from the clipboard.."

Print:If a$=b$ then print "SUCCESS!"

WaitKey()
End

Unfortunately the DLL doesn't come with source so I have no idea if it's closing the reads and writes cleanly, though tracing its behaviour and using it extensively it appears to do exactly what it says on the box.

+BlackD

D4NM4N

2008

THANK YOU BlackD!!!!!

You just saved my life!
http://www.blitzbasic.com/Community/posts.php?topic=78874

(I think, more testing is needed but seems to work fine :)

DjBigWorm

2011

Hi Everyone,

Ok here is something strange. I noticed that the good old
copy to clipboard broke function in windows vista and above.
I also tried BlackD Suggestion. Now when I ran the example it worked just fine. When I tried to use it in my app blitzplus would crash. I used it in another part of
my program and it mysteriouly worked. After a major hunt blaming everything but the dll. It turns out that if you call the command "CopyTextToClipboard" and it encounters a "Return" Command it crashes with no warning( Blitz3D bounced me a Memory Access Violation). A way around
this (For Me) is to put the Command in a Function instead, call it and when you use the "End Function" Command All Seems to work well. Now Can anyone explain why that is? Hope this can help someone with this nice dll. Happy Programming.

Mikorians

2014

Not broken for me - Here you go!

;All patched up and perfected by Mikorians (at least for Windows XP it is)
;Copy/Paste Image Clipboard functions by markcw and John Simmons
;Copy/Paste Text Clipboard functions Syntax Error & Ed from Mars

;Userlibs/kernel32.decls:
;.lib "kernel32.dll"
;apiRtlMoveMemory(Destination*,Source,Length) : "RtlMoveMemory"
;api_GlobalAlloc%(wFlags,dwBytes):"GlobalAlloc"
;api_GlobalLock%(hMem%):"GlobalLock"
;api_GlobalUnlock%(hMem%):"GlobalUnlock"
;api_RtlCopyMemory(Destination,Source*,Length):"RtlMoveMemory" ;AKA apiRtlMoveMemory2

;Userlibs/user32.decls:
;.lib "User32.dll"
;api_CloseClipboard%():"CloseClipboard"
;api_EmptyClipboard%():"EmptyClipboard"
;api_ExamineClipboard%(format%):"IsClipboardFormatAvailable" 
;api_GetClipboardData%(wFormat%):"GetClipboardData"
;api_IsClipboardFormatAvailable%(wFormat%):"IsClipboardFormatAvailable"
;api_OpenClipboard%(hwnd%):"OpenClipboard"
;api_SetClipboardData%(wFormat%,hMem%):"SetClipboardData"
;;This is CUSTOM for convenience (should be GetClipboardData, but pointers are no good to ME)
;api_GetClipboardText$ (wFormat%) : "GetClipboardData"

Graphics 640,480
CRLF$=Chr$(13)+Chr$(10)

;Send text to the clipboard
a$="Hello!"+CRLF$+"This is a test"+CRLF$+"of the text clipboard!"
CopyToClipboardText a$

;a$ is already in the clipboard by this point...

;Get it back again
b$="":b$=PasteTextFromClipboard$() 
PrintMultilineText b$
Print
Print "Now try pasting this into notepad!"
Print "Come back and hit a key."

WaitKey

Cls
Image=LoadImage("Test.jpg")				;Load image
ok=CopyImageToClipboard(Image)		;Copy image to clipboard
FreeImage Image										;Throw it out - Proof positive
Locate 0,150
Print "OK, paste the current clipboard data to whatever"
Print "program you use to see the results of the image copy."
Print "Here are the clipboard graphics contents..."
Image2=PasteImageFromClipboard()	;Paste image from clipboard
DrawImage Image2,50,50						;Draw the image

WaitKey
FreeImage Image2									;Tidy up  :)
End

Function PrintMultilineText(Txt$)
Local CRLF$=Chr$(13)+Chr$(10)
Local a,b,t
t=1:a=1:b=1
While a<Len(Txt$)-1
b=Instr(Txt$,CRLF$,a)
If b=0 Then Print Mid$(Txt$,a,Len(Txt$)-a+1):Exit
Print Mid$(Txt$,a,b-a)
a=b+2 ;(Usually CR-LF, not just CR)
Wend
End Function

Function CopyToClipboardText(Txt$)		;Only the HARD WAY worked!
Local CF_TEXT=1
If Txt$="" Then Return False
l=Len(Txt$)+1													;Plus 1 for the trailing 0 byte
buf=CreateBank(l+1)										;Plus 1 because we start with 0
For t=0 To l-1:PokeByte buf,t,Asc(Mid$(txt$,t+1,1)):Next
PokeByte buf,l,0											;Trailing 0 byte (C format)
hnd%=api_GlobalAlloc%(66,l)						;GHND=66, MOVEABLE=2|ZEROINIT=64
If Not hnd%														;Bummer if we couldn't get memory block
	FreeBank hnd%
	Return False												;Return Fail code
EndIf
pntr=api_GlobalLock%(hnd%)						;Window Lock Memory! Give us the pointer to it
api_RtlCopyMemory(pntr,buf,l)					;Copy our bank to Windows Memory
api_GlobalUnlock%(hnd%)								;Windows Unlock Memory!
If api_OpenClipboard%(0)							;Failsafe- Did we gain access to clipboard?
	api_EmptyClipboard%()								;Free last clipboard data to make room
	api_SetClipboardData%(CF_TEXT,hnd%)	;Point windows to take the memory to the cliboard
	api_CloseClipboard%()								;Close clipboard back up
EndIf
Return True														;Return Good code
End Function

Function PasteTextFromClipboard$()
Local CF_TEXT=1
Local Txt$=""
If api_OpenClipboard%(0)							;Did we access the clipboard sucessfully?
	If api_ExamineClipboard%(CF_Text)		;Does the clipboard contain TEXT
	Txt$=api_GetClipboardText$(CF_TEXT) ;This duplicate function makes like easier!
	EndIf
	api_CloseClipboard%()								;Close it back up
EndIf
Return Txt$														;Here's what we got
End Function

Function CopyImageToClipboard(himage)
Local CF_DIB=8
 ;Copy a given Blitz3D image to the clipboard
 ;From "Copying a DIB to the clipboard", by John Simmons
 ;(http://www.codeproject.com)
 Local width,height,sizeBits,sizeInfo,sizeDIB,btmp,x,y,offset,hDIB%,pbmi
 width=ImageWidth(himage)
 height=ImageHeight(himage)
 ;calculate bits, DWORD-aligned scanline (Width * BitCount) * Height
 sizeBits=((width*24+31)/32*4)*height
 sizeInfo=40 ;sizeof(BITMAPINFOHEADER)
 sizeDIB=sizeInfo+sizeBits ;total size
 btmp=CreateBank(sizeDIB) ;bank to store DIB
 ;calculate DWORD-aligned offset of bits for proper alignment
 ;we'll use biSize to store each pixel, we can fill it in after
 LockBuffer(ImageBuffer(himage))
 For y=0 To height-1
  offset=((width*24+31)/32*4)*y+sizeInfo ;start of next scanline
  For x=0 To width-1
   PokeInt btmp,0,ReadPixelFast(x,height-1-y,ImageBuffer(himage)) ;biSize
   PokeByte btmp,offset+(x*3),PeekByte(btmp,0) ;blue
   PokeByte btmp,offset+(x*3)+1,PeekByte(btmp,1) ;green
   PokeByte btmp,offset+(x*3)+2,PeekByte(btmp,2) ;red
  Next
 Next
 UnlockBuffer(ImageBuffer(himage))
 ;fill in the info header for our 24-bit DIB
 PokeInt btmp,0,sizeInfo ;biSize
 PokeInt btmp,4,width ;biWidth
 PokeInt btmp,8,height ;biHeight
 PokeShort btmp,12,1 ;biPlanes, must be 1
 PokeShort btmp,14,24 ;biBitCount
 PokeInt btmp,16,0 ;biCompression, RGB=0/RLE8=1/RLE4=2/BITFIELDS=3
 PokeInt btmp,20,sizeBits ;biSizeImage, zeros here mean "default"
 PokeInt btmp,24,0 ;biXPelsPerMeter
 PokeInt btmp,28,0 ;biYPelsPerMeter
 PokeInt btmp,32,0 ;biClrUsed
 PokeInt btmp,36,0 ;biClrImportant
 ;alloc memory block to store our DIB
 hDIB%=api_GlobalAlloc%(66,sizeDIB) ;GHND=66, MOVEABLE=2|ZEROINIT=64
 If Not hDIB% ;major bummer if we couldn't get memory block
  FreeBank btmp
  Return False ;fail code
 EndIf
 pbmi=api_GlobalLock%(hDIB%) ;lock memory and get pointer to it
 api_RtlCopyMemory(pbmi,btmp,sizeDIB) ;copy DIB to memory
 api_GlobalUnlock%(hDIB%) ;unlock the DIB
 ;send the DIB to the clipboard
 If api_OpenClipboard%(0) ;hwnd
  api_EmptyClipboard%() ;free last data
  api_SetClipboardData%(CF_DIB,hDIB%)
  api_CloseClipboard%()
 EndIf
 FreeBank btmp
 Return True ;success code
End Function

Function PasteImageFromClipboard()
Local CF_DIB=8
 ;Paste the clipboard to a new Blitz3D image
 ;From "Copying a DIB to the clipboard", by John Simmons
 ;(http://www.codeproject.com)
 Local hDIB%,himage,pbmi,btmp,sizeInfo,sizePal,width,height,bpp
 Local sizeBits,sizeDIB,x,y,offset,index,bytespp
 ;receive the bitmap from the clipboard as a DIB
 If api_OpenClipboard%(0) ;hwnd
  hDIB%=api_GetClipboardData%(CF_DIB)
  api_CloseClipboard%()
 EndIf
 If Not hDIB% ;if we didn't get a DIB, return a dummy image
  himage=CreateImage(1,1)
  Return himage
 EndIf
 pbmi=api_GlobalLock%(hDIB%) ;lock memory and get pointer to it
 btmp=CreateBank(40) ;initialize bank, we will resize it later
 apiRtlMoveMemory(btmp,pbmi,40) ;move info header to bank
 sizeInfo=PeekInt(btmp,0) ;biSize
 ;calculate palette, Clipboard DIBs use the BITMAPINFO struct
 sizePal=PeekInt(btmp,32) ;biClrUsed
 If Not sizePal
  If PeekShort(btmp,14)<16 ;no color table for 16/24/32
   sizePal=1 Shl PeekShort(btmp,14) ;biBitCount, colors=2/16/256
  Else
   sizePal=PeekInt(btmp,16) ;biCompression, 16/32 use BI_BITFIELDS=3
  EndIf
 EndIf
 sizePal=sizePal*4 ;sizeof(RGBQUAD)
 width=PeekInt(btmp,4) ;biWidth
 height=PeekInt(btmp,8) ;biHeight
 bpp=PeekShort(btmp,14) ;biBitCount
 bytespp=bpp/8 ;bytes per pixel
 ;calculate bits, DWORD-aligned scanline (Width * BitCount) * Height
 sizeBits=((width*bpp+31)/32*4)*height
 sizeDIB=sizeInfo+sizePal+sizeBits ;total size
 ResizeBank btmp,sizeDIB ;resize bank to store DIB
 apiRtlMoveMemory(btmp,pbmi,sizeDIB) ;move DIB to bank
 api_GlobalUnlock%(hDIB%) ;unlock the DIB
 himage=CreateImage(width,height) ;new image to write
 ;calculate DWORD-aligned offset of bits for proper alignment
 ;we'll use biSize to store each pixel, we don't need it any more
 LockBuffer(ImageBuffer(himage))
 For y=0 To height-1
  offset=((width*bpp+31)/32*4)*y+sizeInfo+sizePal ;start of next scanline
  For x=0 To width-1
   If bpp=1
    index=PeekByte(btmp,offset+(x/8)) ;1-bit, looks nasty but it works
    ;work out the bit, invert it, bitmask the byte and convert to 0/1
    index=(index And (1 Shl (7-(x Mod 8)))) Shr (7-(x Mod 8))
   EndIf
   If bpp=4
    index=PeekByte(btmp,offset+(x/2)) ;4-bit, work out the nibble
    If x Mod 2 Then index=index And 15 ;get bits 0-3
    If Not x Mod 2 Then index=index Shr 4 ;get bits 4-7
   EndIf
   If bpp=8
    index=PeekByte(btmp,offset+x) ;8-bit, we have our index
   EndIf
   If bpp=24 Or bpp=32 ;get rgb offset
    PokeByte btmp,0,PeekByte(btmp,offset+(x*bytespp)) ;blue
    PokeByte btmp,1,PeekByte(btmp,offset+(x*bytespp)+1) ;green
    PokeByte btmp,2,PeekByte(btmp,offset+(x*bytespp)+2) ;red
   ElseIf bpp=16 ;rgb=565
    PokeByte btmp,0,(PeekShort(btmp,offset+(x*bytespp)) And 31) Shl 3 ;blue
    PokeByte btmp,1,((PeekShort(btmp,offset+(x*bytespp)) And 2016) Shr 5) Shl 2 ;green
    PokeByte btmp,2,((PeekShort(btmp,offset+(x*bytespp)) And 63488) Shr 11) Shl 3 ;red
   Else ;get palette index, 1/4/8-bit
    PokeByte btmp,0,PeekInt(btmp,sizeInfo+(index*4))
    PokeByte btmp,1,PeekInt(btmp,sizeInfo+(index*4)+1)
    PokeByte btmp,2,PeekInt(btmp,sizeInfo+(index*4)+2)
   EndIf
   WritePixelFast x,height-1-y,PeekInt(btmp,0),ImageBuffer(himage) ;biSize
  Next
 Next
 UnlockBuffer(ImageBuffer(himage))
 FreeBank btmp
 Return himage ;image handle
End Function

Rick Nasher

2014

Great stuff, works marvelously!(tested on Win7 Ultimate x64)

Only I'd throw in an extra waitkey so people can see the text before the image covers it(or put text in after displaying the image):
.
.
Print "Here are the clipboard graphics contents..."
WaitKey ;<<< Add waitkey here..
Image2=PasteImageFromClipboard() ;Paste image from clipboard
.
.

Code Archives Forum