Make the compiler build settings local to your project

This code has been declared by its author to be Public Domain code.

Make the compiler build settings local to your project by Zethrax

2014

This code is for BlizMax.

One pet peeve I have with many compilers is that they have the build options set in the IDE rather than having them local to the actual project being compiled. This is a massive nuisance requiring you to change the build settings for each individual project each time you swap between projects. This is particularly annoying when working on a client-server project where you may need a GUI build for the client project and a console build for the server, and need to work on both at once as you tweak them.

The two methods below modify the 'bmk.exe' file that controls the build options for the BlitzMax compiler in order to override the build options set in the IDE and make the build options local to the project being built. Pick whichever method suits you best. You can also use both methods at once.

-

Before making any changes first back up your 'C:\BlitzMax\src\bmk\bmk.bmx' and 'C:\BlitzMax\bin\bmk.exe' files in case you need to restore them to their original state.

-

Whichever one of the config option methods you choose to use below should go after the line:-

args=ParseConfigArgs( AppArgs[2..] )

and before the line:-

CreateDir BlitzMaxPath()+"/tmp"

in the 'bmk.bmx' file found in the 'C:\BlitzMax\src\bmk' folder (the exact folderpath may be different on different systems).

Compile the 'bmk.bmx' file as a unthreaded console release build and place the resulting 'bmk.exe' file in the 'C:\BlitzMax\bin' folder (the exact folderpath may be different on different systems).

-

If you want to test the resulting build settings then place this code below the added code:-

Print "opt_apptype = " + opt_apptype
Print "opt_threaded = " + opt_threaded
Print "opt_debug = " + opt_debug
Print "opt_release = " + opt_release
Print "opt_outfile = " + opt_outfile
Delay( 10000 )

=============================================================

Method 1 - Config options stored in the first line of a project's main source code file.

' -- Parse the first line of the main source code file for config options.
' These option strings should go on the very first line of your main source code file. That line should be a comment line to stop it from being compiled.
'	eg. ' [GUI] [THREADED] [DEBUG] [OUTPUTFILE:C:\BlitzMax\bin\bmk.exe]
' The config option strings are:-
'	[CONSOLE] - Do a console build rather than a GUI build.
'	[GUI] - Do a GUI build rather than a console build.
'	[THREADED] - Do a threaded (multi-threaded) build.
'	[UNTHREADED] - Do an unthreaded (single-threaded) build.
'	[DEBUG] - Do a debug (non-release) build.
'	[RELEASE] - Do a release (non-debug) build.
'	[OUTPUTFILE:<filepath>] - Set the filepath and filename for the compiled output file. You can also specify the filename without the filepath if the file is to be placed in the source code folder.
'		eg. [OUTPUTFILE:C:\BlitzMax\Bin\bmk.exe] would place the compiled file in the 'C:\BlitzMax\bin' folder with the name 'bmk.exe'.
'		eg. [OUTPUTFILE:bmk.exe] would place the compiled file in the folder the source code is being compiled from with the name 'bmk.exe'.
' Note that config option strings are case insensitive.

Local configsourcepath$ = RealPath( args[0] )
Local configstream:TStream = ReadStream:TStream( configsourcepath$ )
If configstream
	Local configline$ = configstream.ReadLine()
	CloseStream( configstream )

	Local configline2$ = configline.ToUpper() ' Use a copied string to make the config option strings case insensitive without affecting the outputfile filepath.

	If configline2.Contains( "[CONSOLE]" ) Then opt_apptype = "console" ' Do a console build.
	If configline2.Contains( "[GUI]" ) Then opt_apptype = "gui" ' Do a GUI build.

	If configline2.Contains( "[THREADED]" ) Then opt_threaded = True ' Do a threaded build.
	If configline2.Contains( "[UNTHREADED]" ) Then opt_threaded = False ' Do an unthreaded build.

	If configline2.Contains( "[DEBUG]" ) Then opt_debug = True ; opt_release = False ' Do a debug (non-release) build.
	If configline2.Contains( "[RELEASE]" ) Then opt_debug = False ; opt_release = True ' Do a release (non-debug) build.

	' Config option to set the filepath and filename for the compiled output file.
	' eg. [OUTPUTFILE:C:\BlitzMax\bin\bmk.exe] would place the compiled file in the 'C:\BlitzMax\bin' folder with the name 'bmk.exe'.
	Local config_start:Int = configline2.Find( "[OUTPUTFILE:" )
	If config_start <> -1 ' If the 'outputfile' config option was found...
		config_start = config_start + 12 ' Move past the "[OUTPUTFILE:" config option string.
		If config_start < configline.length ' Make sure there are enough chars left in the string to search.
			Local config_end:Int = configline.Find( "]", config_start )
			If config_end <> -1
				opt_outfile = configline[ config_start .. config_end ].Trim()
				If ExtractDir$( opt_outfile ) = ""
					opt_outfile = ExtractDir$( configsourcepath$ ) + "/" + opt_outfile
				EndIf
				opt_outfile = RealPath( opt_outfile )
			EndIf
		EndIf
	EndIf

EndIf
'---

==========

Method 2 - Config options are stored inside square brackets in the filename of a project's main source code file.
Note that the 'OUTPUTFILE' option is not supported for this method.

' -- Parse the filename for config options.
' This code allows you to set build options that are local to your project and which override those set in the IDE.
' Config options are:
'	C - Do a console build rather than a GUI build.
'	G - Do a GUI build rather than a console build.
'	T - Do a threaded (multi-threaded) build.
'	U - Do an unthreaded (single-threaded) build.
'	D - Do a debug (non-release) build.
'	R - Do a release (non-debug) build.
' Note that config characters are case insensitive.
' The config options should go in the filename of the project's main file and should be surrounded by square brackets (eg. start[TC].bmx - compiles a threaded console app).

Local nameapp$, nameapp_cmd$, nameappargs_start:Int, nameappargs_end:Int
nameapp$ = StripAll( args[0] ) ' Strip the folderpath and file extension from the filepath of the file to be compiled, leaving only the bare filename.
nameappargs_start = nameapp.Find( "[" ) ' Find the location of the opening bracket that delimits the config options.
If nameappargs_start <> -1 ' If the opening bracket is not found then the config settings are not present.
	If nameappargs_start < ( nameapp.length - 2 ) ' Discontiue parsing config options if there are not at least 2 chars following the opening bracket (a config char and the closing bracket).
		nameappargs_start = nameappargs_start + 1 ' Move the start pointer past the opening bracket.
		nameappargs_end = nameapp.Find( "]", nameappargs_start )
		If nameappargs_end <> -1 ' If the closing bracket is not found then the config settings will be ignored (the endpoint can't be established).
			nameapp_cmd = nameapp[ nameappargs_start .. nameappargs_end ].ToUpper() ' Extract the command chars (note that the slice terminator needs to be 1 higher than the last index included in the sliced chars (exclusive)).
			If nameapp_cmd.Contains( "C" ) Then opt_apptype = "console" ' Create a console app.
			If nameapp_cmd.Contains( "G" ) Then opt_apptype = "gui" ' Create a GUI app.
			If nameapp_cmd.Contains( "T" ) Then opt_threaded = True ' Create a threaded app.
			If nameapp_cmd.Contains( "U" ) Then opt_threaded = False ' Create an unthreaded app.
			If nameapp_cmd.Contains( "D" ) Then opt_debug = True ; opt_release = False ' Do a debug (non-release) build.
			If nameapp_cmd.Contains( "R" ) Then opt_debug = False ; opt_release = True ' Do a release (non-debug) build.
			' Add more config otions here if you want to expand on this.
		EndIf
	EndIf
EndIf
'---

You can find the code at: http://www.blitzbasic.com/codearcs/codearcs.php?code=3137

Comments

None.

Code Archives Forum