MaxGUI overview docs

BlitzMax Forums/BlitzMax Module Tweaks/MaxGUI overview docs

markcw

(Posted 2010) [#1]

This is an update to MaxGUI overview.bbdoc (from v 1.41).

I basically just added links, reformatted the code a little and created and linked to the example files. Also, as with BlitzMax overview docs I added   to empty lines in <pre> tags.

The files are zipped here and posted below along with the patch.
maxgui-overview-doc.zip (expired)

Last edit: 18 Aug 2010

MaxGUI overview.diff

--- MaxGUI overview-old.bbdoc	2010-07-13 03:54:58.000000000 +0100
+++ MaxGUI overview.bbdoc	2010-08-18 02:59:38.537322019 +0100
@@ -4,56 +4,50 @@
 <link rel="styleSheet" href="../bmxstyle.css" type="text/css">
 </head>
 <body>
-<h1>MaxGUI Overview</h1>
-
-<ul>
-<li>Introduction
-<li>Getting Started
-<li>Gadget Layout
-<li>Crossplatform Issues
-<li>Using an EventHook
-<li>Using a Canvas
-<li>Event Hook based Rendering 
-<li>Porting from BlitzPlus
-<li>The New Modules
-<li>Under the Hood
-<li>Extending MaxGui
-</ul>
-
-<hr>
-
-<h3>Introduction</h3>
+<h1>MaxGUI overview</h1>
 
 The MaxGui module provides commands to build user interfaces
 for applications programmed in BlitzMax.
 <p>
-The command set originates from the original BlitzPlus "Gadget"
+The command set originates from the original BlitzPlus 'Gadget'
 based names providing a healthy amount of backward
 compatability for users wishing to port code developed in 
 BlitzPlus.
 
-
-<h3>Getting Started</h3>
+<ul>
+<li><a href=#started>Getting Started</a><br><br>
+<li><a href=#layout>Gadget Layout</a><br><br>
+<li><a href=#crossplatform>Cross Platform Issues</a><br><br>
+<li><a href=#hooks>Using Event Hooks</a><br><br>
+<li><a href=#canvas>Using a Canvas</a><br><br>
+<li><a href=#rendering>Event Hook based Rendering</a><br><br>
+<li><a href=#blitzplus>Porting from BlitzPlus</a><br><br>
+<li><a href=#modules>The New Modules</a><br><br>
+<li><a href=#hood>Under the Hood</a><br><br>
+<li><a href=#extending>Extending MaxGui</a>
+</ul>
+<hr>
+<div id=started>
+<h2>Getting Started</h2>
 
 
 The following program opens a small window on the desktop
 that ends when the window is closed.
+The source for this example is <a href="../gettingstarted.bmx">here</a>.
 <p>
 The code beginning at "While True" is the main event loop
-of the program, it repeats forever waiting for an Event
+of the program, it repeats forever waiting for an event
 to happen, printing the event's details to the output window
 and ending if the event has the ID of EVENT_WINDOWCLOSE.
 <pre class=code>
-' createwindow.bmx
-
-Strict 
-
+' gettingstarted.bmx
+&nbsp;
+Strict
+&nbsp;
 Import MaxGUI.Drivers
-
-Local window:TGadget
-
-window=CreateWindow("My Window",40,40,320,240)
-
+&nbsp;
+Local window:TGadget=CreateWindow("My Window",40,40,320,240)
+&nbsp;
 While True
 	WaitEvent 
 	Print CurrentEvent.ToString()
@@ -61,67 +55,80 @@
 		Case EVENT_WINDOWCLOSE
 			End
 	End Select
-Wend
-</pre>
+Wend</pre>
 Try moving and sizing the window while the program is running
 and you will see the details of the events that occur printed
 in the debug window of BlitzMax.
 <p>
 Try also modifying the "window=" line in the program with:
 <pre class=code>
-window=CreateWindow("My Window",40,40,320,240,Null,WINDOW_TITLEBAR)
-</pre>
-which will create a Window with only a title bar and no status or
-menu bars. See the documentation for CreateWindow for more details
+Local window:TGadget=CreateWindow("My Window",40,40,320,240,Null,WINDOW_TITLEBAR)</pre>
+This will create a window with only a title bar and no status or
+menu bars. See #CreateWindow for more details
 of the Window styles supported by MaxGui.
 <p>
 The MaxGui documentation contains working examples for each of 
-commands that create gadgets including CreateButton, CreateCanvas,
-CreateComboBox, CreateHTMLView, CreateLabel, CreateListBox,
-CreateMenu, CreatePanel, CreateProgBar, CreateSlider, CreateTabber,
-CreateTextField, CreateToolBar and CreateTreeView.
-<p>
-
-<h3>Gadget Layout</h3>
-<p>
-A Gadget in MaxGui is given pixel coordinates when it is created
-that positions it in it's parent's client area. The client area of
-a Window gadget is inside the window's borders not including the
+the commands that create gadgets including:
+<ul>
+<li>#CreateButton
+<li>#CreateCanvas
+<li>#CreateComboBox
+<li>#CreateHTMLView
+<li>#CreateLabel
+<li>#CreateListBox
+<li>#CreateMenu
+<li>#CreatePanel
+<li>#CreateProgBar
+<li>#CreateSlider
+<li>#CreateTabber
+<li>#CreateTextField
+<li>#CreateToolBar
+<li>#CreateTreeView
+</ul>
+</div>
+<br>
+<div id=layout>
+<h2>Gadget Layout</h2>
+<p>
+A gadget in MaxGui is given pixel coordinates when it is created
+which positions it in its parent's client area. The client area of
+a window gadget is inside the window's borders, not including the
 space used by any Status or Menu bars.
 <p>
-If a Window is resized MaxGui uses any children's layout settings
-to reposition them within the new size of it's client area.
+If a window is resized MaxGui uses any children's layout settings
+to reposition them within the new size of its client area.
 <p>
-The SetGadgetLayout is used to control how the Gadget is repositioned
-when it's parent is resized.
+#SetGadgetLayout is used to control how the gadget is repositioned
+when its parent is resized.
 <p>
-By considering each edge of the Gadget independently, the MaxGui
+By considering each edge of the gadget independently, the MaxGui
 layout engine repositions each gadget according to each edge's
-rule where the rule is 
-<p>
-EDGE_CENTERED - The edge remains a fixed distance from the center of the parent<br>
-EDGE_ALIGNED - The edge is a locked distance away from it's parent's corresponding edge<br>
-EDGE_RELATIVE - The edge remains a proportional distance from the parent's 2 edges<br>
-<p>
+rule where the rules are: 
+<ul>
+<li>EDGE_CENTERED - The edge remains a fixed distance from the center of the parent<br>
+<li>EDGE_ALIGNED - The edge is a locked distance away from its parent's corresponding edge<br>
+<li>EDGE_RELATIVE - The edge remains a proportional distance from the parent's 2 edges<br>
+</ul>
 The following code demonstrates a common case of creating a panel
 in a window the size of the window's client area and locking the
 distance of each edge to the correspong edge of the parent window
 (EDGE_ALIGNED rule). The result is that the panel is automatically sized by 
 MaxGui when the window is resized filling the entire client area.
+<p>
+The source for this example is <a href="../gadgetlayout.bmx">here</a>.
 <pre class=code>
+' gadgetlayout.bmx
+&nbsp;
 Strict 
-
+&nbsp;
 Import MaxGUI.Drivers
-
-Local window:TGadget
-Local panel:TGadget
-
-window=CreateWindow("My Window",40,40,320,240)
-
-panel=CreatePanel(0,0,ClientWidth(window),ClientHeight(window),window)
+&nbsp;
+Local window:TGadget=CreateWindow("My Window",40,40,320,240)
+&nbsp;
+Local panel:TGadget=CreatePanel(0,0,ClientWidth(window),ClientHeight(window),window)
 SetGadgetColor panel,200,100,100
 SetGadgetLayout panel,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED
-
+&nbsp;
 While True
 	WaitEvent 
 	Print CurrentEvent.ToString()
@@ -129,32 +136,31 @@
 		Case EVENT_WINDOWCLOSE
 			End
 	End Select
-Wend
-</pre>
-By removing the line of code with the SetGadetLayout command you can view the default 
-EDGE_CENTERED rule in effect on all edges with the panel retaining it's size 
-due to all it's edges being kept a fixed distance from the center 
+Wend</pre>
+By removing the line of code with the "SetGadgetLayout" command you can view the default 
+EDGE_CENTERED rule in effect on all edges. This will make the panel retain its size 
+due to all its edges being kept a fixed distance from the center 
 of the window.
 <p>
-To view rule EDGE_RELATIVE in effect modify the SetGadgetLayout command to read
-"SetGadgetLayout panel,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE".
-<p>
+To view rule EDGE_RELATIVE in effect modify the "SetGadgetLayout" command to read:
+<pre class=code>
+SetGadgetLayout panel,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE</pre>
 But wait, there is no discernable change in the resizing behavior between
 rule EDGE_ALIGNED and rule EDGE_RELATIVE???
 <p>
-Unless the panel is created inset from the window client such as 
+This will happen unless the panel is created inset from the window client such as 
 the result of the following modification:
 <pre class=code>
-panel=CreatePanel(10,10,ClientWidth(window)-20,ClientHeight(window)-20,window)
-</pre>
-you will note the edges are infact being kept a proportional distance
+Local panel:TGadget=CreatePanel(10,10,ClientWidth(window)-20,ClientHeight(window)-20,window)</pre>
+Now you will notice the edges are in fact being kept a proportional distance
 from the parent's 2 edges when the window is resized.
 <p>
-The fact is that EDGE_ALIGNED and EDGE_RELATIVE have the same effect on Gadget 
+The fact is that EDGE_ALIGNED and EDGE_RELATIVE have the same effect on gadget 
 edges when the edges are created on the borders of their parent's client area.
-<p>
-
-<h3>Crossplatform Issues</h3>
+</div>
+<br>
+<div id=crossplatform>
+<h2>Cross Platform Issues</h2>
 <p>
 In general the MaxGUI module should perform identically on Windows,
 Apple and Linux machines. However some care and attention is required
@@ -165,16 +171,16 @@
 enable you to publish programs that look and function well on a wide 
 variety of systems.
 <p>
-Recomended gadget dimensions.
+Use the recommended gadget dimensions:
 <p>
 <ul>
 <li>Buttons and ComboBoxes should be 24 pixels high.
 <p>
 Shorter buttons are possible in Windows but they will become cropped
-on Apple systems so it is recomended that when using the default font
-buttons should be created with a height of 24 pixels.
+on Apple systems so it is recommended that the default font
+buttons are created with a height of 24 pixels.
 <p>
-<li>TextFields should be 20 pixels high and accompanying labels lowered 4 pixels.
+<li>TextFields should be 20 pixels high and accompanying labels lowered by 4 pixels.
 <p>
 Again, using the default font settings, the above rule should produce
 good results on all platforms. Often labels will be placed to the left
@@ -187,81 +193,85 @@
 row 30 pixels below the y position of the previous gadget's positions.
 </ul>
 <p>
-Use the WINDOW_CLIENTCOORDS flag when dependent on client size.
-<p>
-If you are using a fixed size window specify it's size based on the
+Use the WINDOW_CLIENTCOORDS flag when dependent on client size:
+<ul>
+<li>If you are using a fixed size window specify its size based on the
 required client area using the WINDOW_CLIENTCOORDS style.
 <p>
 Specifying a window's size in the default frame coordinates will 
 result in a client area that may be different on different machines
 due to a number of factors including both the version of the computer's
-operating system and certain user preference outside your control.
-<p>
-<p>
-<h3>Using an EventHook</h3>
+operating system and certain user preferences outside your control.
+</ul>
+</div>
+<br>
+<div id=hooks>
+<h2>Using Event Hooks</h2>
 <p>
 As an alternative to developing applications that have a single
-main loop that waits then processes events from an eventqueue
-the AddHook command allows a callback function to be used
+main loop that waits then processes events from an eventqueue,
+the #AddHook command allows a callback function to be used
 to process events as they happen.
 <p>
-This is important for two type of events.
-<p>
-EVENT_GADGETACTION events produced by Slider gadgets with the 
-original SLIDER_SCROLLBAR style and EVENT_WINDOWRESIZE events
-that occur when the user is resizing a Window both require
+This is important for two type of events:
+<ul>
+<li>EVENT_GADGETACTION events produced by slider gadgets with the 
+original SLIDER_SCROLLBAR style and also EVENT_WINDOWRESIZE events
+that occur when the user is resizing a window. Both of these require
 a hooked type of event processing for best results.
-In both these situations most OS's go into a "modal"
-loop that means a WaitEvent command will only return once
-the user releases the mouse button but with Event hooks 
+In these situations most OS's will go into a 'modal'
+loop which means a #WaitEvent command will only return once
+the user releases the mouse button but with event hooks 
 the code can be called directly from within the OS's own 
 modal loop.
 <p>
-The other type of event is EVENT_GADGETPAINT which is generated 
-whenever the operating system needs to redraw a Canvas gadget.
+<li>The other type of event is EVENT_GADGETPAINT which is generated 
+whenever the operating system needs to redraw a canvas gadget.
 When hooked, drawing code can be executed at the time of the 
 event rather than later when the OS returns control to the
 main program, at which time it may have already drawn other
-content above the Canvas.
-<p>
-
-<h3>Using a Canvas</h3>
+content above the canvas.
+</ul>
+</div>
+<br>
+<div id=canvas>
+<h2>Using a Canvas</h2>
 <p>
 The following code is a simple example of using Max2D to 
-render dynamically into a Canvas Gadget...
+render dynamically into a canvas gadget. 
+The source for this example is <a href="../createcanvas.bmx">here</a>.
 <pre class=code>
 ' createcanvas.bmx
-
+&nbsp;
 Strict 
-
+&nbsp;
 Import MaxGUI.Drivers
-
+&nbsp;
 Global GAME_WIDTH=320
 Global GAME_HEIGHT=240
-
-' create a centered window with client size GAME_WIDTH,GAME_HEIGHT
-
+&nbsp;
+' create a centered window with client size GAME_WIDTH, GAME_HEIGHT
+&nbsp;
 Local wx=(GadgetWidth(Desktop())-GAME_WIDTH)/2
 Local wy=(GadgetHeight(Desktop())-GAME_HEIGHT)/2
-
+&nbsp;
 Local window:TGadget=CreateWindow("My Canvas",wx,wy,GAME_WIDTH,GAME_HEIGHT,Null,WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS)
-
+&nbsp;
 ' create a canvas for our game
-
+&nbsp;
 Local canvas:TGadget=CreateCanvas(0,0,320,240,window)
-
+&nbsp;
 ' create an update timer
-
+&nbsp;
 CreateTimer 60
-
+&nbsp;
 While WaitEvent()
 	Select EventID()
 		Case EVENT_TIMERTICK
 			RedrawGadget canvas
-
+&nbsp;
 		Case EVENT_GADGETPAINT
-			Local g=CanvasGraphics(canvas)
-			SetGraphics g
+			SetGraphics CanvasGraphics(canvas)
 			SetOrigin 160,120
 			SetLineWidth 5
 			Cls
@@ -269,65 +279,65 @@
 			DrawLine 0,0,120*Cos(t),120*Sin(t)
 			DrawLine 0,0,80*Cos(t/60),80*Sin(t/60)
 			Flip
-
+&nbsp;
 		Case EVENT_WINDOWCLOSE
 			FreeGadget canvas
 			End
-
+&nbsp;
 		Case EVENT_APPTERMINATE
 			End
 	End Select
-Wend
-</pre>
-The above code creates a timer that causes an event to occur
-at 60hz (ticks per second). 
+Wend</pre>
+This example creates a timer that causes an event to occur
+at 60 Hz (ticks per second). 
 <p>
 Each time an EVENT_TIMERTICK is received by the program's main 
-event loop it calls RedrawGadget which tells the system to redraw
+event loop it calls #RedrawGadget which tells the system to redraw
 our canvas gadget.
 <p>
-The code following the Case EVENT_GADGETPAINT above is where
+The code following the "Case EVENT_GADGETPAINT" line is where
 the actual drawing takes place.
 <p>
-- of interest -
+You may be interested to find that if you remove the lines 
+"RedrawGadget canvas" and "Case EVENT_GADGETPAINT" from the program 
+that it still appears to function normally. "Why is this so?" you might ask.
+<p>
+This is because MaxGUI in fact allows you to draw to a canvas
+whenever you want. Drawing in response to an EVENT_GADGETPAINT
+however, is better behavior as no drawing code will be executed if
+the canvas is obscured or the application has a low refresh rate. 
+In this case, an obscured canvas will still be asked to redraw itself 
+when revealed by window movement from above.
+</div>
+<br>
+<div id=rendering>
+<h2>Event Hook based Rendering</h2>
 <p>
-If you remove two lines of the above code that contain the
-"RedrawGadget canvas" and "Case EVENT_GADGETPAINT" the program
-still appears to function normally.
-<p>
-This is because MaxGUI infact allows you to draw to a canvas
-when ever you want. Drawing in response to an EVENT_GADGETPAINT
-however is better behavior as no drawing code is executed if
-the canvas is obscured or the application has a low refresh rate 
-in which case it will be still asked to redraw itself on the
-event an obscured canvas is revealed by window movement from
-above.
+As previously mentioned, the best way to manage redrawing a canvas
+gadget is with an event hook.
 <p>
-
-<h3>Event Hook based Rendering</h3>
-<p>
-As mentioned above the best way to manage redrawing a Canvas
-gadget is with an EventHook.
-<p>
-The following example uses an EventHook to handle events
-at the time of occurance rather than from the WaitEvent()
+The following example uses an event hook to handle events
+at the time of occurence rather than from the #WaitEvent
 queue. You will notice at the bottom of the program that 
-infact the main loop does nothing but WaitEvent and all 
-the event handling is done inside the TApplet Type.
+in fact the main loop does nothing but WaitEvent and all 
+the event handling is done inside the TApplet type.
 <p>
+The source for this example is <a href="../eventhookrendering.bmx">here</a>.
 <pre class=code>
-' rendering a canvas using an EventHook based Applet Type
-
+' eventhookrendering.bmx
+&nbsp;
+' rendering a canvas using an event hook based applet type
+&nbsp;
 Strict
-
+&nbsp;
 Import MaxGUI.Drivers
-
+&nbsp;
 Type TApplet
-	
+&nbsp;
 	Field	window:TGadget
 	Field	canvas:TGadget
 	Field	timer:TTimer
-	
+&nbsp;
 	Method Render()
 		Local x,y,width,height,t,i
 		width=GraphicsWidth()
@@ -343,7 +353,7 @@
 			DrawLine 0,0,x,y
 		Next
 	End Method
-	
+&nbsp;
 	Method OnEvent(event:TEvent)
 		Select event.id
 		Case EVENT_WINDOWCLOSE
@@ -356,7 +366,7 @@
 			Flip
 		End Select
 	End Method
-
+&nbsp;
 	Function eventhook:Object(id,data:Object,context:Object)
 		Local	event:TEvent
 		Local	app:TApplet
@@ -364,7 +374,7 @@
 		app=TApplet(context)
 		app.OnEvent event	
 	End Function
-	
+&nbsp;
 	Method Create:TApplet(name$)
 		Local	a:TApplet
 		Local	w,h
@@ -377,38 +387,39 @@
 		AddHook EmitEventHook,eventhook,Self
 		Return Self		
 	End Method
-	
+&nbsp;
 End Type
-
+&nbsp;
 AutoMidHandle True
-
+&nbsp;
 Local	applet:TApplet
-
+&nbsp;
 applet=New TApplet.Create("Render Applet")
-
+&nbsp;
 While True
 	WaitEvent
-Wend
-</pre>
+Wend</pre>
 <p>
 Unfortunately I have obfiscated (made obscure) the 
 function of the event hook by wrapping it in an 
-Applet object and I have started using big words in
-my sentences.
+Applet object (and I have started using big words in
+my sentences).
 <p>
-To be as concise as possible, the TApplet Type declares
-a Class that features an OnEvent Method that with some 
-magic in it's constructor (the Create() Method) provides
+To be as concise as possible, the TApplet type declares
+a class that features an OnEvent method that, with some 
+magic in its constructor (the Create method), provides
 an object oriented way for our program to collect events.
 <p>
 Our TApplet implements the rendering sequence
-as featured in the previous example but because
-it does so based on a Hook responds in a more
+as featured in the previous example, but because
+it does so based on a hook, it responds in a more
 well behaved manner when the OS wishes to redraw the
 desktop when it is made visible by some user action
-or told to refresh with the RedrawGadget command.
-
-<h3>Porting from BlitzPlus</h3>
+or told to refresh with the #RedrawGadget command.
+</div>
+<br>
+<div id=blitzplus>
+<h2>Porting from BlitzPlus</h2>
 <p>
 The following are a few issues that you may encounter when
 porting code from BlitzPlus.
@@ -416,36 +427,30 @@
 
 <h4>Event Codes</h4>
 <p>
-The codes returned by the WaitEvent and EventID commands
-are not the same as BlitzPlus. See the Event Objects docs
+The codes returned by the #WaitEvent and #EventID commands
+are not the same as BlitzPlus. See the 
+<a href="../../Modules/Events/Events/index.html">Event Objects</a> docs
 for a list of the constants used in MaxGUI. Numerical
 values have not been documented in order to encourage
 users to use the correct EVENT_NAMES.
 <p>
-New events in MaxGUI include
-<p>
-EVENT_HOTKEYHIT - see SetHotKeyEvent 
-<p>
-EVENT_WINDOWACCEPT - a file has been dragged onto the window
-<p>
-EVENT_GADGETPAINT - a canvas gadget needs redrawing
-<p>
-EVENT_GADGETSELECT - the selected state of a TextArea has changed
-<p>
-EVENT_GADGETMENU - the user has clicked the right button on this gadget
-<p>
-EVENT_GADGETOPEN - a node in a TreeViewNode has been expanded
-<p>
-EVENT_GADGETCLOSE - a node in a TreeViewNode has been collapsed
-<p>
-EVENT_GADGETDONE - an HTMLView has finished loading a page
-<p>
+New events in MaxGUI include:
+<ul>
+<li>EVENT_HOTKEYHIT - see #SetHotKeyEvent 
+<li>EVENT_WINDOWACCEPT - a file has been dragged onto the window
+<li>EVENT_GADGETPAINT - a canvas gadget needs redrawing
+<li>EVENT_GADGETSELECT - the selected state of a TextArea has changed
+<li>EVENT_GADGETMENU - the user has clicked the right button on this gadget
+<li>EVENT_GADGETOPEN - a node in a TreeViewNode has been expanded
+<li>EVENT_GADGETCLOSE - a node in a TreeViewNode has been collapsed
+<li>EVENT_GADGETDONE - an HTMLView has finished loading a page
+</ul>
 
 <h4>TextArea filters</h4>
 <p>
 TextAreas no longer generate Key Up, Key Down or Key Stroke events.
 <p>
-Instead the new SetGadgetFilter command can be used to install
+Instead, the new #SetGadgetFilter command can be used to install
 a callback routine that is called each time the user presses
 a key with the callback able to accept or reject each key
 by returning either True or False respectively.
@@ -453,55 +458,58 @@
 
 <h4>Popup Menus</h4>
 
-There is a new PopupWindowMenu command that can be used
+There is a new #PopupWindowMenu command that can be used
 for implementing context menus commonly activated by the
 right mouse button (reported as an EVENT_GADGETMENU for most
 gadgets).
-
-
-<h3>The New Modules</h3>
+</div>
+<br>
+<div id=modules>
+<h2>The New Modules</h2>
 <p>
 The three platform specific modules that ship with MaxGui are 
 Win32MaxGui.mod, CocoaMaxGui.mod and FLTKMaxGui.mod which provide 
 native implementations of MaxGui for Windows, Apple MacOS and 
 Linux platforms respectively.
 <p>
-The new Event.mod and EventQueue.mod modules are extensions
+The new <a href="../../Modules/Events/Events/index.html">Event</a> and 
+<a href="../../Modules/Events/Event queue/index.html">EventQueue</a> modules are extensions 
 to the BlitzMax system. BlitzMax events provide the necessary 
 mechanics of communicating with a MaxGui based application as well
 as providing all BlitzMax applications with events such as
 EVENT_APPSUSPEND, EVENT_APPRESUME and EVENT_APPTERMINATE.
 <p>
-The commands WaitEvent, PeekEvent and PollEvent are the primary
-commands for receiving Events in BlitzMax programs and PostEvent
-can be used for generating Events.
-<p>
-
-<h3>Under the Hood</h3>
+The commands #WaitEvent, #PeekEvent and #PollEvent are the primary
+commands for receiving events in BlitzMax programs and #PostEvent
+can be used for generating events.
+</div>
+<br>
+<div id=hood>
+<h2>Under the Hood</h2>
 <p>
-The Type TGadget is used in MaxGui to represent all 18 Gadget
+The type TGadget is used in MaxGui to represent all 18 Gadget
 types including:
-<p>
-GADGET_DESKTOP
-GADGET_WINDOW
-GADGET_BUTTON
-GADGET_PANEL
-GADGET_TEXTFIELD
-GADGET_TEXTAREA
-GADGET_COMBOBOX
-GADGET_LISTBOX
-GADGET_TOOLBAR
-GADGET_TABBER
-GADGET_TREEVIEW
-GADGET_HTMLVIEW
-GADGET_LABEL
-GADGET_SLIDER
-GADGET_PROGBAR
-GADGET_MENUITEM
-GADGET_NODE
-GADGET_CANVAS
-<p>
-The TMaxGUIDriver Type defined in maxgui.driver represents the 
+<ul>
+<li>GADGET_DESKTOP
+<li>GADGET_WINDOW
+<li>GADGET_BUTTON
+<li>GADGET_PANEL
+<li>GADGET_TEXTFIELD
+<li>GADGET_TEXTAREA
+<li>GADGET_COMBOBOX
+<li>GADGET_LISTBOX
+<li>GADGET_TOOLBAR
+<li>GADGET_TABBER
+<li>GADGET_TREEVIEW
+<li>GADGET_HTMLVIEW
+<li>GADGET_LABEL
+<li>GADGET_SLIDER
+<li>GADGET_PROGBAR
+<li>GADGET_MENUITEM
+<li>GADGET_NODE
+<li>GADGET_CANVAS
+</ul>
+The TMaxGUIDriver type defined in #MaxGui.Drivers represents the 
 gadget factory which is created at startup to produce platform 
 specific versions of TGadget on demand.
 <p>
@@ -513,15 +521,14 @@
 an abstract interface to the platform specific implementations
 meaning that like TGadget itself, they are not intended to be 
 extended by the user.
-<p>
-<p>
-
-
-<h3>Crossplatform vs Flexibility</h3>
+</div>
+<br>
+<div id=extending>
+<h2>Extending MaxGui</h2>
 <p>
 It is expected that most users wanting to create custom
 gadgets that work well across all platforms will find 
-the Panel and Canvas gadgets provide adequate Event reporting
+the panel and canvas gadgets provide adequate event reporting
 and rendering functionality from which to produce their
 own uber-gadgets.
 <p>
@@ -537,10 +544,10 @@
 <p>
 This of course does not mean the the current specification 
 of MaxGUI is set in stone, rather, that those wanting to 
-interface at a lower level with the Operating System of
+interface at a lower level with the operating system of
 their choice do so in the privacy of their own modules
 rather than becoming muddied in the source of the lowlevel
 platform specific BRL modules.
-
+</div>
 </body>
 </html>

MaxGUI overview.bbdoc

<html>
<head>
<title></title>
<link rel="styleSheet" href="../bmxstyle.css" type="text/css">
</head>
<body>
<h1>MaxGUI overview</h1>

The MaxGui module provides commands to build user interfaces
for applications programmed in BlitzMax.
<p>
The command set originates from the original BlitzPlus 'Gadget'
based names providing a healthy amount of backward
compatability for users wishing to port code developed in 
BlitzPlus.

<ul>
<li><a href=#started>Getting Started</a><br><br>
<li><a href=#layout>Gadget Layout</a><br><br>
<li><a href=#crossplatform>Cross Platform Issues</a><br><br>
<li><a href=#hooks>Using Event Hooks</a><br><br>
<li><a href=#canvas>Using a Canvas</a><br><br>
<li><a href=#rendering>Event Hook based Rendering</a><br><br>
<li><a href=#blitzplus>Porting from BlitzPlus</a><br><br>
<li><a href=#modules>The New Modules</a><br><br>
<li><a href=#hood>Under the Hood</a><br><br>
<li><a href=#extending>Extending MaxGui</a>
</ul>
<hr>
<div id=started>
<h2>Getting Started</h2>


The following program opens a small window on the desktop
that ends when the window is closed.
The source for this example is <a href="../gettingstarted.bmx">here</a>.
<p>
The code beginning at "While True" is the main event loop
of the program, it repeats forever waiting for an event
to happen, printing the event's details to the output window
and ending if the event has the ID of EVENT_WINDOWCLOSE.
<pre class=code>
' gettingstarted.bmx
&nbsp;
Strict
&nbsp;
Import MaxGUI.Drivers
&nbsp;
Local window:TGadget=CreateWindow("My Window",40,40,320,240)
&nbsp;
While True
	WaitEvent 
	Print CurrentEvent.ToString()
	Select EventID()
		Case EVENT_WINDOWCLOSE
			End
	End Select
Wend</pre>
Try moving and sizing the window while the program is running
and you will see the details of the events that occur printed
in the debug window of BlitzMax.
<p>
Try also modifying the "window=" line in the program with:
<pre class=code>
Local window:TGadget=CreateWindow("My Window",40,40,320,240,Null,WINDOW_TITLEBAR)</pre>
This will create a window with only a title bar and no status or
menu bars. See #CreateWindow for more details
of the Window styles supported by MaxGui.
<p>
The MaxGui documentation contains working examples for each of 
the commands that create gadgets including:
<ul>
<li>#CreateButton
<li>#CreateCanvas
<li>#CreateComboBox
<li>#CreateHTMLView
<li>#CreateLabel
<li>#CreateListBox
<li>#CreateMenu
<li>#CreatePanel
<li>#CreateProgBar
<li>#CreateSlider
<li>#CreateTabber
<li>#CreateTextField
<li>#CreateToolBar
<li>#CreateTreeView
</ul>
</div>
<br>
<div id=layout>
<h2>Gadget Layout</h2>
<p>
A gadget in MaxGui is given pixel coordinates when it is created
which positions it in its parent's client area. The client area of
a window gadget is inside the window's borders, not including the
space used by any Status or Menu bars.
<p>
If a window is resized MaxGui uses any children's layout settings
to reposition them within the new size of its client area.
<p>
#SetGadgetLayout is used to control how the gadget is repositioned
when its parent is resized.
<p>
By considering each edge of the gadget independently, the MaxGui
layout engine repositions each gadget according to each edge's
rule where the rules are: 
<ul>
<li>EDGE_CENTERED - The edge remains a fixed distance from the center of the parent<br>
<li>EDGE_ALIGNED - The edge is a locked distance away from its parent's corresponding edge<br>
<li>EDGE_RELATIVE - The edge remains a proportional distance from the parent's 2 edges<br>
</ul>
The following code demonstrates a common case of creating a panel
in a window the size of the window's client area and locking the
distance of each edge to the correspong edge of the parent window
(EDGE_ALIGNED rule). The result is that the panel is automatically sized by 
MaxGui when the window is resized filling the entire client area.
<p>
The source for this example is <a href="../gadgetlayout.bmx">here</a>.
<pre class=code>
' gadgetlayout.bmx
&nbsp;
Strict 
&nbsp;
Import MaxGUI.Drivers
&nbsp;
Local window:TGadget=CreateWindow("My Window",40,40,320,240)
&nbsp;
Local panel:TGadget=CreatePanel(0,0,ClientWidth(window),ClientHeight(window),window)
SetGadgetColor panel,200,100,100
SetGadgetLayout panel,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED
&nbsp;
While True
	WaitEvent 
	Print CurrentEvent.ToString()
	Select EventID()
		Case EVENT_WINDOWCLOSE
			End
	End Select
Wend</pre>
By removing the line of code with the "SetGadgetLayout" command you can view the default 
EDGE_CENTERED rule in effect on all edges. This will make the panel retain its size 
due to all its edges being kept a fixed distance from the center 
of the window.
<p>
To view rule EDGE_RELATIVE in effect modify the "SetGadgetLayout" command to read:
<pre class=code>
SetGadgetLayout panel,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE,EDGE_RELATIVE</pre>
But wait, there is no discernable change in the resizing behavior between
rule EDGE_ALIGNED and rule EDGE_RELATIVE???
<p>
This will happen unless the panel is created inset from the window client such as 
the result of the following modification:
<pre class=code>
Local panel:TGadget=CreatePanel(10,10,ClientWidth(window)-20,ClientHeight(window)-20,window)</pre>
Now you will notice the edges are in fact being kept a proportional distance
from the parent's 2 edges when the window is resized.
<p>
The fact is that EDGE_ALIGNED and EDGE_RELATIVE have the same effect on gadget 
edges when the edges are created on the borders of their parent's client area.
</div>
<br>
<div id=crossplatform>
<h2>Cross Platform Issues</h2>
<p>
In general the MaxGUI module should perform identically on Windows,
Apple and Linux machines. However some care and attention is required
when testing in regards to how your application will look on each 
platform.
<p>
The following are a few issues that if considered should hopefully
enable you to publish programs that look and function well on a wide 
variety of systems.
<p>
Use the recommended gadget dimensions:
<p>
<ul>
<li>Buttons and ComboBoxes should be 24 pixels high.
<p>
Shorter buttons are possible in Windows but they will become cropped
on Apple systems so it is recommended that the default font
buttons are created with a height of 24 pixels.
<p>
<li>TextFields should be 20 pixels high and accompanying labels lowered by 4 pixels.
<p>
Again, using the default font settings, the above rule should produce
good results on all platforms. Often labels will be placed to the left
or right of TextFields, in which case they should be set 4 pixels lower
down the screen in order to correctly align with TextFields.
<p>
<li>Separate fields in a form by 30 pixels.
<p>
When creating a form with multiple TextField gadgets start each
row 30 pixels below the y position of the previous gadget's positions.
</ul>
<p>
Use the WINDOW_CLIENTCOORDS flag when dependent on client size:
<ul>
<li>If you are using a fixed size window specify its size based on the
required client area using the WINDOW_CLIENTCOORDS style.
<p>
Specifying a window's size in the default frame coordinates will 
result in a client area that may be different on different machines
due to a number of factors including both the version of the computer's
operating system and certain user preferences outside your control.
</ul>
</div>
<br>
<div id=hooks>
<h2>Using Event Hooks</h2>
<p>
As an alternative to developing applications that have a single
main loop that waits then processes events from an eventqueue,
the #AddHook command allows a callback function to be used
to process events as they happen.
<p>
This is important for two type of events:
<ul>
<li>EVENT_GADGETACTION events produced by slider gadgets with the 
original SLIDER_SCROLLBAR style and also EVENT_WINDOWRESIZE events
that occur when the user is resizing a window. Both of these require
a hooked type of event processing for best results.
In these situations most OS's will go into a 'modal'
loop which means a #WaitEvent command will only return once
the user releases the mouse button but with event hooks 
the code can be called directly from within the OS's own 
modal loop.
<p>
<li>The other type of event is EVENT_GADGETPAINT which is generated 
whenever the operating system needs to redraw a canvas gadget.
When hooked, drawing code can be executed at the time of the 
event rather than later when the OS returns control to the
main program, at which time it may have already drawn other
content above the canvas.
</ul>
</div>
<br>
<div id=canvas>
<h2>Using a Canvas</h2>
<p>
The following code is a simple example of using Max2D to 
render dynamically into a canvas gadget. 
The source for this example is <a href="../createcanvas.bmx">here</a>.
<pre class=code>
' createcanvas.bmx
&nbsp;
Strict 
&nbsp;
Import MaxGUI.Drivers
&nbsp;
Global GAME_WIDTH=320
Global GAME_HEIGHT=240
&nbsp;
' create a centered window with client size GAME_WIDTH, GAME_HEIGHT
&nbsp;
Local wx=(GadgetWidth(Desktop())-GAME_WIDTH)/2
Local wy=(GadgetHeight(Desktop())-GAME_HEIGHT)/2
&nbsp;
Local window:TGadget=CreateWindow("My Canvas",wx,wy,GAME_WIDTH,GAME_HEIGHT,Null,WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS)
&nbsp;
' create a canvas for our game
&nbsp;
Local canvas:TGadget=CreateCanvas(0,0,320,240,window)
&nbsp;
' create an update timer
&nbsp;
CreateTimer 60
&nbsp;
While WaitEvent()
	Select EventID()
		Case EVENT_TIMERTICK
			RedrawGadget canvas
&nbsp;
		Case EVENT_GADGETPAINT
			SetGraphics CanvasGraphics(canvas)
			SetOrigin 160,120
			SetLineWidth 5
			Cls
			Local t=MilliSecs()
			DrawLine 0,0,120*Cos(t),120*Sin(t)
			DrawLine 0,0,80*Cos(t/60),80*Sin(t/60)
			Flip
&nbsp;
		Case EVENT_WINDOWCLOSE
			FreeGadget canvas
			End
&nbsp;
		Case EVENT_APPTERMINATE
			End
	End Select
Wend</pre>
This example creates a timer that causes an event to occur
at 60 Hz (ticks per second). 
<p>
Each time an EVENT_TIMERTICK is received by the program's main 
event loop it calls #RedrawGadget which tells the system to redraw
our canvas gadget.
<p>
The code following the "Case EVENT_GADGETPAINT" line is where
the actual drawing takes place.
<p>
You may be interested to find that if you remove the lines 
"RedrawGadget canvas" and "Case EVENT_GADGETPAINT" from the program 
that it still appears to function normally. "Why is this so?" you might ask.
<p>
This is because MaxGUI in fact allows you to draw to a canvas
whenever you want. Drawing in response to an EVENT_GADGETPAINT
however, is better behavior as no drawing code will be executed if
the canvas is obscured or the application has a low refresh rate. 
In this case, an obscured canvas will still be asked to redraw itself 
when revealed by window movement from above.
</div>
<br>
<div id=rendering>
<h2>Event Hook based Rendering</h2>
<p>
As previously mentioned, the best way to manage redrawing a canvas
gadget is with an event hook.
<p>
The following example uses an event hook to handle events
at the time of occurence rather than from the #WaitEvent
queue. You will notice at the bottom of the program that 
in fact the main loop does nothing but WaitEvent and all 
the event handling is done inside the TApplet type.
<p>
The source for this example is <a href="../eventhookrendering.bmx">here</a>.
<pre class=code>
' eventhookrendering.bmx
&nbsp;
' rendering a canvas using an event hook based applet type
&nbsp;
Strict
&nbsp;
Import MaxGUI.Drivers
&nbsp;
Type TApplet
&nbsp;
	Field	window:TGadget
	Field	canvas:TGadget
	Field	timer:TTimer
&nbsp;
	Method Render()
		Local x,y,width,height,t,i
		width=GraphicsWidth()
		height=GraphicsHeight()
		t=MilliSecs()
		SetBlend ALPHABLEND
		SetViewport 0,0,width,height
		SetClsColor 0,0,0
		SetOrigin width/2,height/2
		Cls
		For x=-width/2 To width/2 Step 2
			y=Sin(t*0.3+x)*height/2
			DrawLine 0,0,x,y
		Next
	End Method
&nbsp;
	Method OnEvent(event:TEvent)
		Select event.id
		Case EVENT_WINDOWCLOSE
			End
		Case EVENT_TIMERTICK
			RedrawGadget canvas
		Case EVENT_GADGETPAINT
			SetGraphics CanvasGraphics(canvas)
			Render
			Flip
		End Select
	End Method
&nbsp;
	Function eventhook:Object(id,data:Object,context:Object)
		Local	event:TEvent
		Local	app:TApplet
		event=TEvent(data)
		app=TApplet(context)
		app.OnEvent event	
	End Function
&nbsp;
	Method Create:TApplet(name$)
		Local	a:TApplet
		Local	w,h
		window=CreateWindow(name,20,20,512,512)
		w=ClientWidth(window)
		h=ClientHeight(window)
		canvas=CreateCanvas(0,0,w,h,window)
		canvas.SetLayout 1,1,1,1
		timer=CreateTimer(100)
		AddHook EmitEventHook,eventhook,Self
		Return Self		
	End Method
&nbsp;
End Type
&nbsp;
AutoMidHandle True
&nbsp;
Local	applet:TApplet
&nbsp;
applet=New TApplet.Create("Render Applet")
&nbsp;
While True
	WaitEvent
Wend</pre>
<p>
Unfortunately I have obfiscated (made obscure) the 
function of the event hook by wrapping it in an 
Applet object (and I have started using big words in
my sentences).
<p>
To be as concise as possible, the TApplet type declares
a class that features an OnEvent method that, with some 
magic in its constructor (the Create method), provides
an object oriented way for our program to collect events.
<p>
Our TApplet implements the rendering sequence
as featured in the previous example, but because
it does so based on a hook, it responds in a more
well behaved manner when the OS wishes to redraw the
desktop when it is made visible by some user action
or told to refresh with the #RedrawGadget command.
</div>
<br>
<div id=blitzplus>
<h2>Porting from BlitzPlus</h2>
<p>
The following are a few issues that you may encounter when
porting code from BlitzPlus.
<p>

<h4>Event Codes</h4>
<p>
The codes returned by the #WaitEvent and #EventID commands
are not the same as BlitzPlus. See the 
<a href="../../Modules/Events/Events/index.html">Event Objects</a> docs
for a list of the constants used in MaxGUI. Numerical
values have not been documented in order to encourage
users to use the correct EVENT_NAMES.
<p>
New events in MaxGUI include:
<ul>
<li>EVENT_HOTKEYHIT - see #SetHotKeyEvent 
<li>EVENT_WINDOWACCEPT - a file has been dragged onto the window
<li>EVENT_GADGETPAINT - a canvas gadget needs redrawing
<li>EVENT_GADGETSELECT - the selected state of a TextArea has changed
<li>EVENT_GADGETMENU - the user has clicked the right button on this gadget
<li>EVENT_GADGETOPEN - a node in a TreeViewNode has been expanded
<li>EVENT_GADGETCLOSE - a node in a TreeViewNode has been collapsed
<li>EVENT_GADGETDONE - an HTMLView has finished loading a page
</ul>

<h4>TextArea filters</h4>
<p>
TextAreas no longer generate Key Up, Key Down or Key Stroke events.
<p>
Instead, the new #SetGadgetFilter command can be used to install
a callback routine that is called each time the user presses
a key with the callback able to accept or reject each key
by returning either True or False respectively.
<p>

<h4>Popup Menus</h4>

There is a new #PopupWindowMenu command that can be used
for implementing context menus commonly activated by the
right mouse button (reported as an EVENT_GADGETMENU for most
gadgets).
</div>
<br>
<div id=modules>
<h2>The New Modules</h2>
<p>
The three platform specific modules that ship with MaxGui are 
Win32MaxGui.mod, CocoaMaxGui.mod and FLTKMaxGui.mod which provide 
native implementations of MaxGui for Windows, Apple MacOS and 
Linux platforms respectively.
<p>
The new <a href="../../Modules/Events/Events/index.html">Event</a> and 
<a href="../../Modules/Events/Event queue/index.html">EventQueue</a> modules are extensions 
to the BlitzMax system. BlitzMax events provide the necessary 
mechanics of communicating with a MaxGui based application as well
as providing all BlitzMax applications with events such as
EVENT_APPSUSPEND, EVENT_APPRESUME and EVENT_APPTERMINATE.
<p>
The commands #WaitEvent, #PeekEvent and #PollEvent are the primary
commands for receiving events in BlitzMax programs and #PostEvent
can be used for generating events.
</div>
<br>
<div id=hood>
<h2>Under the Hood</h2>
<p>
The type TGadget is used in MaxGui to represent all 18 Gadget
types including:
<ul>
<li>GADGET_DESKTOP
<li>GADGET_WINDOW
<li>GADGET_BUTTON
<li>GADGET_PANEL
<li>GADGET_TEXTFIELD
<li>GADGET_TEXTAREA
<li>GADGET_COMBOBOX
<li>GADGET_LISTBOX
<li>GADGET_TOOLBAR
<li>GADGET_TABBER
<li>GADGET_TREEVIEW
<li>GADGET_HTMLVIEW
<li>GADGET_LABEL
<li>GADGET_SLIDER
<li>GADGET_PROGBAR
<li>GADGET_MENUITEM
<li>GADGET_NODE
<li>GADGET_CANVAS
</ul>
The TMaxGUIDriver type defined in #MaxGui.Drivers represents the 
gadget factory which is created at startup to produce platform 
specific versions of TGadget on demand.
<p>
The type TGadget is actually an abstract class with TWin32Gadget,
TCocoaGadget and TFLTKGadget being the actual types produced
depending on the current TMaxGUIDriver.
<p>
The types TIconStrip, TGUIFont and TGadgetItem also provide
an abstract interface to the platform specific implementations
meaning that like TGadget itself, they are not intended to be 
extended by the user.
</div>
<br>
<div id=extending>
<h2>Extending MaxGui</h2>
<p>
It is expected that most users wanting to create custom
gadgets that work well across all platforms will find 
the panel and canvas gadgets provide adequate event reporting
and rendering functionality from which to produce their
own uber-gadgets.
<p>
The cross platform nature of MaxGUI means there are
implications for those wishing to extend functionality by
taking advantage of platform specific features that have
no logical equivalent on other platforms.
<p>
Those wishing to do so are encouraged to implement such 
features in separate modules rather than making modifications
to the BRL modules which are intended only to support the
core cross platform MaxGUI functionality.
<p>
This of course does not mean the the current specification 
of MaxGUI is set in stone, rather, that those wanting to 
interface at a lower level with the operating system of
their choice do so in the privacy of their own modules
rather than becoming muddied in the source of the lowlevel
platform specific BRL modules.
</div>
</body>
</html>

createcanvas.bmx

' createcanvas.bmx

Strict 

Import MaxGUI.Drivers

Global GAME_WIDTH=320
Global GAME_HEIGHT=240

' create a centered window with client size GAME_WIDTH, GAME_HEIGHT

Local wx=(GadgetWidth(Desktop())-GAME_WIDTH)/2
Local wy=(GadgetHeight(Desktop())-GAME_HEIGHT)/2

Local window:TGadget=CreateWindow("My Canvas",wx,wy,GAME_WIDTH,GAME_HEIGHT,Null,WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS)

' create a canvas for our game

Local canvas:TGadget=CreateCanvas(0,0,320,240,window)

' create an update timer

CreateTimer 60

While WaitEvent()
	Select EventID()
		Case EVENT_TIMERTICK
			RedrawGadget canvas

		Case EVENT_GADGETPAINT
			SetGraphics CanvasGraphics(canvas)
			SetOrigin 160,120
			SetLineWidth 5
			Cls
			Local t=MilliSecs()
			DrawLine 0,0,120*Cos(t),120*Sin(t)
			DrawLine 0,0,80*Cos(t/60),80*Sin(t/60)
			Flip

		Case EVENT_WINDOWCLOSE
			FreeGadget canvas
			End

		Case EVENT_APPTERMINATE
			End
	End Select
Wend

eventhookrendering.bmx

' eventhookrendering.bmx

' rendering a canvas using an event hook based applet type

Strict

Import MaxGUI.Drivers

Type TApplet
	
	Field	window:TGadget
	Field	canvas:TGadget
	Field	timer:TTimer
	
	Method Render()
		Local x,y,width,height,t,i
		width=GraphicsWidth()
		height=GraphicsHeight()
		t=MilliSecs()
		SetBlend ALPHABLEND
		SetViewport 0,0,width,height
		SetClsColor 0,0,0
		SetOrigin width/2,height/2
		Cls
		For x=-width/2 To width/2 Step 2
			y=Sin(t*0.3+x)*height/2
			DrawLine 0,0,x,y
		Next
	End Method
	
	Method OnEvent(event:TEvent)
		Select event.id
		Case EVENT_WINDOWCLOSE
			End
		Case EVENT_TIMERTICK
			RedrawGadget canvas
		Case EVENT_GADGETPAINT
			SetGraphics CanvasGraphics(canvas)
			Render
			Flip
		End Select
	End Method

	Function eventhook:Object(id,data:Object,context:Object)
		Local	event:TEvent
		Local	app:TApplet
		event=TEvent(data)
		app=TApplet(context)
		app.OnEvent event	
	End Function
	
	Method Create:TApplet(name$)
		Local	a:TApplet
		Local	w,h
		window=CreateWindow(name,20,20,512,512)
		w=ClientWidth(window)
		h=ClientHeight(window)
		canvas=CreateCanvas(0,0,w,h,window)
		canvas.SetLayout 1,1,1,1
		timer=CreateTimer(100)
		AddHook EmitEventHook,eventhook,Self
		Return Self
	End Method
	
End Type

AutoMidHandle True

Local	applet:TApplet

applet=New TApplet.Create("Render Applet")

While True
	WaitEvent
Wend

gadgetlayout.bmx

' gadgetlayout.bmx

Strict 

Import MaxGUI.Drivers

Local window:TGadget=CreateWindow("My Window",40,40,320,240)

Local panel:TGadget=CreatePanel(0,0,ClientWidth(window),ClientHeight(window),window)
SetGadgetColor panel,200,100,100
SetGadgetLayout panel,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED,EDGE_ALIGNED

While True
	WaitEvent 
	Print CurrentEvent.ToString()
	Select EventID()
		Case EVENT_WINDOWCLOSE
			End
	End Select
Wend

gettingstarted.bmx

' gettingstarted.bmx

Strict

Import MaxGUI.Drivers

Local window:TGadget=CreateWindow("My Window",40,40,320,240)

While True
	WaitEvent
	Print CurrentEvent.ToString()
	Select EventID()
		Case EVENT_WINDOWCLOSE
			End
	End Select
Wend