[BRL.FileSystem] fixed CreateDir network recursion

BlitzMax Forums/BlitzMax Module Tweaks/[BRL.FileSystem] fixed CreateDir network recursion

plash

(Posted 2009) [#1]

The CreateDir function did not handle network directories correctly under windows (where paths start with "//" - it tried to create "/", then "/", then the server name/IP, which is impossible).

Here is a corrected (and SuperStricted) version, which makes the beginning of the loop start at the network base path:

Function CreateDir:Int(path:String, recurse:Int = False)
	
	FixPath(path, True)
	
	If recurse = False
		mkdir_(path, 1023)
		Return FileType(path) = FILETYPE_DIR
	Else If recurse = True
		
		Local t:String, i:Int
		path = RealPath(path) + "/"
		
		If path.StartsWith("//") = True
			i = path.Find("/", path.Find("/", 2)) + 1
			t:+path[..i]
			path = path[i..]
		End If
		
		While path <> Null
			i = path.Find("/") + 1
			
			t:+path[..i]
			path = path[i..]
			
			Select FileType(t)
				Case FILETYPE_DIR
					' Avoid Default (dir already exists)
				Case FILETYPE_NONE
					Local s:String = StripSlash(t)
					mkdir_(StripSlash(s), 1023)
					If FileType(s) <> FILETYPE_DIR
						Return False
					End If
					
				Default
					Return False
					
			End Select
			
		Wend
		
		Return True
		
	End If
	
End Function