Pause, Resume and Reset Timers

BlitzMax Forums/BlitzMax Module Tweaks/Pause, Resume and Reset Timers

Otus	(Posted 2009) [#1]

To enable pausing, resuming and resetting timers, add these to BRL.Timer, under Type TTimer, replacing the Stop method and the Create function:

	Method Stop()
		If Not _handle
			_cycle=Null
			Return
		End If
		bbTimerStop _handle
		_handle=0
		_event=Null
		_cycle=Null
	End Method
	
	Method Reset()
		_ticks=0
	End Method
	
	Method Pause()
		If Not _handle Return
		bbTimerStop _handle
		_handle=0
	End Method
	
	Method Resume()
		If _handle Or Not _cycle Return
		_handle=bbTimerStart( _hertz,Self )
	End Method
	
	Method IsPaused:Int()
		Return _handle=0 And _cycle<>Null
	End Method
	
	Function Create:TTimer( hertz#,event:TEvent=Null )
		Local t:TTimer=New TTimer
		Local handle=bbTimerStart( hertz,t )
		If Not handle Return
		t._cycle=t
		t._event=event
		t._handle=handle
		t._hertz=hertz
		Return t
	End Function
	
	Field _hertz#

For a procedural interface add these to the end of the document:

Rem
bbdoc: Reset a timer
about: Reset timer ticks to zero.
End Rem
Function ResetTimer( timer:TTimer )
	timer.Reset
End Function

Rem
bbdoc: Pause a timer
about: While paused, a timer does not tick.
End Rem
Function PauseTimer( timer:TTimer )
	timer.Pause
End Function

Rem
bbdoc: Resume a timer
about: Resume a paused timer.
End Rem
Function ResumeTimer( timer:TTimer )
	timer.Resume
End Function

Rem
bbdoc: Check if a timer is paused
returns: True if timer is paused, False if it is running or stopped.
End Rem
Function TimerIsPaused( timer:TTimer )
	Return timer.IsPaused()
End Function