Language Manager

BlitzMax Forums/BlitzMax Module Tweaks/Language Manager

Artemis

(Posted 2006) [#1]

Hi guys,

i'd like to present you my little, but useful (as I hope) module.

With this module you can easily write applications supporting multiple languages.

You just have to create a new instance of the LanguageManager, and add your files.

When you change the language then, all the values are reloaded, in the new language.

Here it is:
languagemanager.zip

If you find it useful, please give me a little note.

If there are much people thinking this ist useful I'll maybe implement encrypting of the language files.

Artemis

Edit:
For directly getting the code, look here:

SuperStrict

Rem
bbdoc: Language Manager Module
about: <p>This module provides a method to handle a multiple language appplication very easily.</p>
<table class="doc" cellspacing="3" width="100%">
<tbody>
<tr><td class="doctop" colspan="2">A little example</td></tr>
</tbody>
<tr><td class="docleft" width="1%">Content of <strong><a style="font-size:1em;" href="language.en.lng">language.en.lng</a></strong></td><td class="docright"><pre>Every line, not containing an equal-character is ignored.
Also it doesn't matter how you write the identifiers,
GOOdbYe equals goodByE.

welcome=Welcome to a little presentation!
content=This little content is also used to demonstrate the module
goOdbye=Oh, see you later!</pre></td></tr>
<tr><td class="docleft" width="1%">Content of <strong><a style="font-size:1em;" href="language.de.lng">language.de.lng</a></strong></td><td class="docright"><pre>Jede Zeile, die kein Gleichheitszeichen enth&auml;lt wird ignoriert
Ebensfalls ist es egal, wie Sie den Variablennamen schreiben,
GOOdbYe ist das gleiche wie goodByE.

welcome=Willkommen zu einer kleinen Demonstration!
content=Ein kleiner Inhalt, ebensfalls zu Demonstrationszwecken.
goodbye=Auf Wiedersehen!</pre></td></tr>
<tr><td class="docleft" width="1%">Content of <strong><a style="font-size:1em;" href="demonstration.bmx">demonstration.bmx</a></strong></td><td class="docright"><pre>SuperStrict

Framework BRL.StandardIO
Import ARTEMIS.LanguageManager

'Create a new language manager
Local LM:TLanguageManager = New TLanguageManager

'Add our language file (just the part before ".en/de.lng")
LM.AddFile("language")

'Set the language to German, it has to be the form we used in the filename
LM.SetLanguage("de")

'Print out our Messages
Print "This should be German"
Print "Welcome="+LM.Get("WELCOME")
Print "Content="+LM.Get("content")
Print "GoodBye="+LM.Get("goodBYE")
Print ""

'Now change the language to English
LM.SetLanguage("en")

'And print our messages again
Print "This should be English"
Print "Welcome="+LM.Get("WELCOME")
Print "Content="+LM.Get("content")
Print "GoodBye="+LM.Get("goodBYE")</pre></td></tr>
</table>
EndRem
Module ARTEMIS.LanguageManager

ModuleInfo "Version: 1.0"
ModuleInfo "Author: Jonas <em>Artemis</em> Cleve"
ModuleInfo "License: GNU General Public License"
ModuleInfo "Copyright: Jonas <em>Artemis</em> Cleve"

Import BRL.LinkedList
Import BRL.FileSystem

Rem
bbdoc: The class for the language manager
EndRem
Type TLanguageManager
	
	Field _Language:String = ""
	Field _Files:TList = New TList
	Field _Items:TList = New TList
	
	Rem
	bbdoc: Sets the language to the new value
	EndRem
	Method SetLanguage(Language:String)
		If Language <> Self._Language Then
			Self._Language = Language
			Self._Items.Clear()
			Self._ParseFiles()
		EndIf
	EndMethod
	
	Rem
	bbdoc: Adds a file to the file list
	EndRem
	Method AddFile(File:String)
		Self._Files.AddLast(File)
		If Self._Language <> "" Then Self._ParseFile(File)
	EndMethod
	
	Rem
	bbdoc: Removes a file from the file list
	EndRem
	Method RemoveFile(File:String)
		Self._Files.Remove(File)
		Self._Items.Clear()
		Self._ParseFiles()
	EndMethod
	
	Rem
	bbdoc: Gets the value of an item
	returns: The value, by it's identifier
	EndRem
	Method Get:String(Identifier:String)
		Local Link:TLink
		
		Link = Self._Items.FindLink(Identifier)
		If Not Link Then Return ""
		Return TLanguageManagerItem(Link.Value())._Content
	EndMethod
	
	Method _ParseFiles()
		Local File:String
		
		For File = EachIn Self._Files
			Self._ParseFile(File)
		Next
	EndMethod
	
	Method _ParseFile(File:String)
		Local Filename:String, Stream:TStream, Line:String, Position:Int
		
		Filename = File+"."+Self._Language+".lng"
		If FileType(Filename) <> FILETYPE_FILE Then
			Filename = File+".lng"
			If FileType(Filename) <> FILETYPE_FILE Then Return
		EndIf
		Stream = ReadFile(Filename)
		While Not Eof(Stream)
			Line = ReadLine(Stream)
			Position = Line.Find("=")
			If Position > 0 Then Self._Items.AddLast(TLanguageManagerItem.Create(Line[..Position], Line[Position+1..]))
		Wend
	EndMethod
	
EndType

Type TLanguageManagerItem
	
	Field _Identifier:String
	Field _Content:String
	
	Function Create:TLanguageManagerItem(Identifier:String, Content:String)
		Local Item:TLanguageManagerItem
		
		Item = New TLanguageManagerItem
		Item._Identifier = Identifier
		Item._Content = Content
		Return Item
	EndFunction
	
	Method Compare:Int(CompareObject:Object)
		If Not String(CompareObject) Then Super.Compare(CompareObject)
		If String(CompareObject).ToLower() = Self._Identifier.ToLower() Then Return 0
		Return Self._Identifier.Compare(CompareObject)
	EndMethod
	
EndType