Request : DX Fallback

BlitzMax Forums/BlitzMax Module Tweaks/Request : DX Fallback

TartanTangerine (was Indiepath)

(Posted 2006) [#1]

It would be nice if the offical modules could be tweaked to contain the following code - it would make implementation of my software renderer seamless.

d3d7max2d.bmx : enable surfaces to be created in system memory as a fallback.

	Function Create:TD3D7ImageFrame( driver:TD3D7Max2DDriver,width,height,flags )				
		Function Pow2Size( n )
			Local t=1
			While t<n
				t:*2
			Wend
			Return t
		End Function
		
		Local	swidth=Pow2Size(width)
		Local	sheight=Pow2Size(height)
		Local	desc:DDSURFACEDESC2=New DDSURFACEDESC2
		Local	res
						
		desc.dwSize=SizeOf(desc)
		desc.dwFlags=DDSD_WIDTH|DDSD_HEIGHT|DDSD_CAPS|DDSD_PIXELFORMAT
		desc.dwWidth=swidth
		desc.dwHeight=sheight		
		desc.ddsCaps=DDSCAPS_TEXTURE|DDSCAPS_LOCALVIDMEM|DDSCAPS_VIDEOMEMORY
		desc.ddsCaps2=DDSCAPS2_HINTDYNAMIC'DDSCAPS2_TEXTUREMANAGE
		desc.ddpf_dwSize=SizeOf(DDPIXELFORMAT)
		desc.ddpf_dwFlags=DDPF_RGB|DDPF_ALPHAPIXELS
		desc.ddpf_BitCount=32
		desc.ddpf_BitMask_0=$ff0000
		desc.ddpf_BitMask_1=$00ff00
		desc.ddpf_BitMask_2=$0000ff
		desc.ddpf_BitMask_3=$ff000000
		Local surf:IDirectDrawSurface7
		If flags & MIPMAPPEDIMAGE desc.ddsCaps:|DDSCAPS_MIPMAP|DDSCAPS_COMPLEX
		res=PrimaryDevice.DDraw.CreateSurface( desc,Varptr surf,Null )
		If res<>DD_OK 
			desc.ddsCaps=DDSCAPS_TEXTURE|DDSCAPS_SYSTEMMEMORY
			res=PrimaryDevice.DDraw.CreateSurface( desc,Varptr surf,Null )
			If res<>DD_OK RuntimeError "Create DX7 surface Failed"	
		EndIf
		
			
		Local frame:TD3D7ImageFrame=New TD3D7ImageFrame
		frame.driver=driver
		frame.surface=surf
		frame.sinfo=New DDSurfaceDesc2
		frame.sinfo.dwSize=SizeOf(frame.sinfo)
		frame.xyzuv=New Float[24]
		frame.width=width
		frame.height=height
		frame.flags=flags
		frame.SetUV 0.0,0.0,Float(width)/swidth,Float(height)/sheight
		Return frame
	End Function

d3d7graphics.bmx : To enable software emulation fallback

	Method Reset()
		Local		ddsc:DDSCAPS2
		Local		res
		Local		fullscreen
		
		ddsd=New DDSURFACEDESC2
		ddsd.dwSize=SizeOf(ddsd)
		fullscreen=state&DX7FULLSCREEN
		flipflags=DDFLIP_WAIT
		If fullscreen
			ddsd.dwFlags=DDSD_CAPS|DDSD_BACKBUFFERCOUNT
			ddsd.ddsCaps=DDSCAPS_PRIMARYSURFACE|DDSCAPS_FLIP|DDSCAPS_COMPLEX|DDSCAPS_3DDEVICE|DDSCAPS_VIDEOMEMORY
			ddsd.dwBackBufferCount=1
		Else
			ddsd.dwFlags=DDSD_CAPS
			ddsd.ddsCaps=DDSCAPS_PRIMARYSURFACE|DDSCAPS_3DDEVICE
		EndIf

		res=ddraw.CreateSurface( ddsd,Varptr primarysurface,Null )
		If res Throw "CreateSurface Failed result="+res
		
		res=d3d.CreateDevice(IID_IDirect3DTnLDevice,primarysurface,Varptr device)
		
		If res 
			res=d3d.CreateDevice(IID_IDirect3DHALDevice,primarysurface,Varptr device)
			Print "TnL Failed : Selecting HAL"
		EndIf
		
		If res 
			res=d3d.CreateDevice(IID_IDirect3DMMXDevice,primarysurface,Varptr device)
			Print "HAL Failed : Selecting MMX (software)"
		EndIf
		If res Throw "CreateDevice Failed result="+res		

		If fullscreen
			ddsc=New DDSCAPS2
			ddsc.dwCaps=DDSCAPS_BACKBUFFER
			res=primarysurface.GetAttachedSurface( ddsc,Varptr BackBuffer )
			If res Throw "GetAttachedSurface Failed result="+res
		Else
			ddsd.ddsCaps=DDSCAPS_OFFSCREENPLAIN|DDSCAPS_3DDEVICE
			ddsd.dwFlags=DDSD_WIDTH|DDSD_HEIGHT|DDSD_CAPS
			ddsd.dwWidth=width
			ddsd.dwHeight=height
			res=ddraw.CreateSurface( ddsd,Varptr BackBuffer,Null )
			If res Throw "CreateSurface Failed result="+res
			res=ddraw.CreateClipper( 0,Varptr Clipper,Null )
			If res Throw "CreateClipper Failed result="+res
			res=primarysurface.SetClipper(Clipper)
			If res Throw "SetClipper Failed result="+res
			res=clipper.SetHWnd( 0,hwnd )
			If res Throw "Clipper.SetHWND Failed result="+res			
		EndIf
		device.SetRenderTarget BackBuffer,0
		device.SetRenderState D3DRS_LIGHTING,False
	End Method

And add the following line to d3d7.bmx

Global IID_IDirect3DMMXDevice[]=[$881949a1,$11d0d6f3,$a000ab89,$294105c9]

TartanTangerine (was Indiepath)

(Posted 2006) [#2]

Do I assume that the answer to my request is no?

tonyg

(Posted 2006) [#3]

Can you turn off DDSCAPS2_TEXTUREMANAGE without adding a lot more code to manage textures?