[MAXGUI] "About" window module?

BlitzMax Forums/BlitzMax Module Tweaks/[MAXGUI] "About" window module?

Grisu

(Posted 2006) [#1]

Hi!

Has anyone written a proper "about" window module yet?
Such as the ones used in Firefox or Thunderbird:

Version, homepage link ect on the one "side".
Scrolling credits on the other "side".

Anything that is better than this when I click "About" in the BMX GUI:

klepto2

(Posted 2006) [#2]

Do you mean something like this?

Strict

Type TAboutBox
	Field Window:Tgadget
	Field Buttons:TAboutButton[2]
	Field RealButtons:TGadget[2]
	Field ActiveButton:TAboutButton
	Field ExitButton:TGadget
	Field Canvas:TGadget
	Field Timer:TTimer
	
	Field Name:String
	Field PosX:Int
	Field PosY:Int 
	Field Width:Int
	Field Height:Int
	
	Field AlwaysOnTop:Byte = False
	
	Function eventhook:Object(id:Int,data:Object,context:Object)
		If TAboutBox(context) TAboutBox(context).ev TEvent(data);Return data	
	EndFunction
	
	Method New()
		AddHook EmitEventHook,eventhook,Self
	End Method
	
	Function Create:TAboutBox(Name:String , X:Int , Y:Int , Width:Int , Height:Int)
		Local A:TAboutBox = New TAboutBox
		A.Name = Name
		A.PosX = X
		A.PosY = Y
		A.Width = Width
		A.Height = Height
		
		A.Window = CreateWindow(Name , X , Y , Width , Height,,WINDOW_TITLEBAR)
		A.Canvas = CreateCanvas(0 , 0 , ClientWidth(A.Window) , ClientHeight(A.Window) - 50 , A.Window)
		A.ExitButton = CreateButton("Exit",ClientWidth(A.Window)-120 , ClientHeight(A.Window) - 40 , 80 , 30 , A.Window)
		
		A.Timer = CreateTimer(60)
		HideGadget(A.Window)
		
		Return A
	End Function
	
	Method AddButton(Name:String,Style:TTextStyle , Index:Int)
		If Index > 2 And Index < 1 Then 
			Throw "Index must be in 1 or 2"
		Else
			Local B:TAboutButton = TaboutButton.Create(Name,Style)
			B.Canvas = Canvas
			B.Index = Index
			Style.Parent = B
			Buttons[Index-1] = B
			RealButtons[Index - 1] = CreateButton(B.Name , 40 , ClientHeight(Window) - 40 , 80 , 30 , Window) 
			Select Index
				Case 1
					ShowGadget(RealButtons[Index - 1])
					ActiveButton = Buttons[Index-1]
				Default
					HideGadget(RealButtons[Index - 1])
			End Select
			
		EndIf
	End Method
	
	Method ev(event:TEvent)
			If event.id = EVENT_GADGETPAINT Then 
				If ActiveButton Then
					ActiveButton.Style.Update()
				EndIf
			EndIf
			
			If event.id = EVENT_TimerTick And Event.source = Timer Then
				If Canvas.parent <> Null Then RedrawGadget canvas
			EndIf
			
			If event.id = EVENT_WINDOWCLOSE And event.Source = Window
					Kill()
			End If			
			If event.id = EVENT_GADGETACTION
				If event.source = ExitButton Then 
					Kill()
				EndIf
				If Event.Source = RealButtons[0] Then
					ActiveButton = Buttons[1]
					HideGadget(RealButtons[0])
					ShowGadget(RealButtons[1])
				ElseIf Event.Source = RealButtons[1] Then
					ActiveButton = Buttons[0]
					HideGadget(RealButtons[1])
					ShowGadget(RealButtons[0])
				EndIf
			EndIf

	End Method
	
	Method Kill()
		HideGadget(Window)
		ShowGadget(RealButtons[0])
		ActiveButton = Buttons[0]
		HideGadget(RealButtons[1])

	End Method
	
	Method Show()
		ShowGadget(Window)
	End Method

End Type

Type TTextStyle
	Field Index
	Field Text:Tlist = New TList
	Field Background:Timage
	Field isBAckground:Byte = False
	Field CenterAllign:Byte = True
	Field LeftAllign:Byte = False
	Field RightAllign:Byte = False
	Field Parent:TAboutButton
	
	Method AddText(Text:String) 
		self.Text.Addlast(Text)
	End Method
	
	Method SetBackGround(Path:String)
		Background = LoadImage(Path)
		If Background Then isBackground = True
	End Method
	
	Method SetAllign(Center:Byte = True , _Left:Byte = False , _Right:Byte = False)
			If Center = True Then 
				CenterAllign = True
				LeftAllign = False
				RightAllign = False
				Return
			EndIf
			If _Left = True Then 
				CenterAllign = False
				LeftAllign = True
				RightAllign = False
				Return
			EndIf	
			If _Right = True Then 
				CenterAllign = False
				LeftAllign = False
				RightAllign = True
				Return
			EndIf
	End Method
	
	Method Update()
	End Method
End Type

Type TStaticText Extends TTextStyle
	
	Function Create:TStaticText()
		Local S:TStaticText = New TStaticText
		Return S
	End Function
	
	Method Update()
		SetGraphics CanvasGraphics(parent.canvas)
		Cls
		If CenterAllign = True Then
			If isBackground = True Then
				DrawImageRect BAckGround , 0 , 0 , ClientWidth(Parent.Canvas) , ClientHeight(Parent.Canvas)
			EndIf
			
			Local Row:Int = 0
			Local Width:Int = ClientWidth(Parent.Canvas) 
			
			For Local T:String = EachIn Text
				DrawText T , (Float(Width)/2.0)-(TextWidth(T)/2) , 20 * Row
				Row:+ 1
			Next
			
		EndIf
		
		If LeftAllign = True Then
			If isBackground = True Then
				DrawImageRect BackGround , 0 , 0 , ClientWidth(Parent.Canvas) , ClientHeight(Parent.Canvas)
			EndIf
			
			Local Row:Int = 0
			Local Width:Int = ClientWidth(Parent.Canvas) 
			
			For Local T:String = EachIn Text
				DrawText T ,0 , 20 * Row
				Row:+ 1
			Next
			
		EndIf
		
		If RightAllign = True Then
			If isBackground = True Then
				DrawImageRect BAckGround , 0 , 0 , ClientWidth(Parent.Canvas) , ClientHeight(Parent.Canvas)
			EndIf
			
			Local Row:Int = 0
			Local Width:Int = ClientWidth(Parent.Canvas) 
			
			For Local T:String = EachIn Text
				DrawText T , Width-TextWidth(T) , 20 * Row
				Row:+ 1
			Next
			
		EndIf


		
		'Print "Test"
		
		Flip
	End Method
	
End Type

Type TAboutButton
	Field Canvas:TGadget
	Field Name:String
	Field Style:TTextStyle
	Field Index:Int
	
	Function Create:TAboutButton(Name:String , Style:TTextStyle )
		
		Local B:TAboutButton = New TAboutButton
		B.Name = Name
		B.Style = Style
		  
		
		Return B
	End Function
	
End Type



' createmenu.bmx
' Creating the About Box

Local About:TAboutBox = TAboutBox.Create("About" , 20 , 20 , 400 , 400)

Local TS:TStaticText = TStaticText.Create()
TS.AddText("Test1")
TS.AddText("Test1")
TS.SetAllign(False,False,True)

About.AddButton("<< Test2" , TS , 1)

Local TS2:TStaticText = TStaticText.Create()
TS2.SetBackGround("D:\Back.JPG")
TS2.AddText("Test2")
TS2.AddText("Test2")
TS2.SetAllign(True , False , False)

About.AddButton(">> Test1" , TS2 , 2)

					


Local window:TGadget
Local filemenu:TGadget
Local editmenu:TGadget
Local helpmenu:TGadget

Const MENU_NEW=101
Const MENU_OPEN=102
Const MENU_SAVE=103
Const MENU_CLOSE=104
Const MENU_EXIT=105

Const MENU_CUT=106
Const MENU_COPY=107
Const MENU_PASTE=108

Const MENU_ABOUT=109

window=CreateWindow("My Window",40,40,320,240)

filemenu=CreateMenu("&File",0,WindowMenu(window))
CreateMenu"&New",MENU_NEW,filemenu,KEY_N,MODIFIER_COMMAND
CreateMenu"&Open",MENU_OPEN,filemenu,KEY_O,MODIFIER_COMMAND
CreateMenu"&Close",MENU_CLOSE,filemenu,KEY_W,MODIFIER_COMMAND
CreateMenu"",0,filemenu
CreateMenu"&Save",MENU_SAVE,filemenu,KEY_S,MODIFIER_COMMAND
CreateMenu"",0,filemenu
CreateMenu"E&xit",MENU_EXIT,filemenu,KEY_F4,MODIFIER_COMMAND

editmenu=CreateMenu("&Edit",0,WindowMenu(window))
CreateMenu "Cu&t",MENU_CUT,editmenu,KEY_X,MODIFIER_COMMAND
CreateMenu "&Copy",MENU_COPY,editmenu,KEY_C,MODIFIER_COMMAND
CreateMenu "&Paste",MENU_PASTE,editmenu,KEY_V,MODIFIER_COMMAND

helpmenu=CreateMenu("&Help",0,WindowMenu(window))
CreateMenu "&About",MENU_ABOUT,helpmenu

UpdateWindowMenu window

While True
	WaitEvent 
	Select EventID()
		Case EVENT_WINDOWCLOSE
			End
		Case EVENT_MENUACTION
			Select EventData()
				Case MENU_EXIT
					End
				Case MENU_ABOUT
					About.Show()
					
			End Select
	End Select
Wend

The TTextStyle is extendable as you see by the TStaticText
So it should be easy to add different Effects like scrolling, fading etc.
It is a short write and bug maybe included. but it should give you a hint how to do it. Also things like textColor etc. are not implemented yet.

Enjoy ;)

Grisu

(Posted 2006) [#3]

Thanks Klepto.

Will have a look.

P.S.: Is this EmitEventHook stuff portable to MAC+Linux?

Dreamora

(Posted 2006) [#4]

Yepp thats BMs own event code stuff from brl.event etc

Grisu

(Posted 2006) [#5]

Another problem with the example.
When I click the close button, not only the about window shuts down, but also the WHOLE application.
How can I prevent that?

Also, can I set a window to ALWAYSONTOP with MAXGUI commands?
So the about window stays over the apps window...

SebHoll

(Posted 2006) [#6]

Change the

		Case EVENT_WINDOWCLOSE
			End

to this:

		Case EVENT_WINDOWCLOSE
			If EventSource() = About.Window Then About.Kill() Else End

*EDIT: Just to explain: this will check to see if the event was triggered by the About Box window, if it was then the about box is "Killed", otherwise (i.e. it was triggered by the main window) it ends the program.

Also I think there was an "AlwaysOnTop" flag in the Type declaration but I don't think it works. :(

Seb

Grisu

(Posted 2006) [#7]

Thanks Seb!