brl.hook tweak

BlitzMax Forums/BlitzMax Module Tweaks/brl.hook tweak

fredborg

(Posted 2006) [#1]

Hi,

Here's a tweak for BRL.Hook, which enables you to remove individual hooks even when they use the same function as other hooks.

Use it like this:

Local myhook:Object = AddHook(blabla...)
RemoveHookObject(myhook)

And here's the tweaked code:

Strict

Rem
bbdoc: Hook functions
end rem
Module BRL.Hook

ModuleInfo "Version: 1.00"
ModuleInfo "Author: Mark Sibly"
ModuleInfo "License: Blitz Shared Source Code"
ModuleInfo "Copyright: Blitz Research Ltd"
ModuleInfo "Modserver: BRL"

Private

Type THook
	Field succ:THook
	Field priority
	Field func:Object( id,data:Object,context:Object )
	Field context:Object
End Type

Global hooks:THook[256]

Public

Rem
bbdoc: Allocate a hook id
returns: An integer hook id
about:
The returned hook id can be used with #AddHook, #RunHooks and #RemoveHook.
end rem
Function AllocHookId()
	Global id=-1
	id:+1
	If id>255 Throw "Too many hook ids"
	Return id
End Function

Rem
bbdoc: Add a hook function
returns: An Object containing the hook reference, which may be used with #RemoveHookObject to destroy the hook.
about:
Add a hook function to be executed when #RunHooks is called with the specified hook @id.
End Rem
Function AddHook:Object( id,func:Object( id,data:Object,context:Object ),context:Object=Null,priority=0 )

	Local t:THook=New THook
	t.priority=priority
	t.func=func
	t.context=context
	
	Local pred:THook
	Local hook:THook=hooks[id]
	
	While hook
		If priority>hook.priority Exit
		pred=hook
		hook=hook.succ
	Wend
	
	If pred
		t.succ=pred.succ
		pred.succ=t
	Else
		t.succ=hooks[id]
		hooks[id]=t
	EndIf

	Return t

End Function

Rem
bbdoc: Run hook functions
returns: The data produced by the last hook function
about:
#RunHooks runs all hook functions that have been added for the specified hook @id.<br>
<br>
The first hook function is called with the provided @data object. The object returned by
this function is then passed as the @data parameter to the next hook function and so on. 
Therefore, hook functions should generally return the @data parameter when finished.
end rem
Function RunHooks:Object( id,data:Object )

	Local hook:THook=hooks[id]
	While hook
		data=hook.Func( id,data,hook.context )
		hook=hook.succ
	Wend
	Return data

End Function

Rem
bbdoc:Remove a hook function
about:
Removes the hook function specified by @id and @func.
end rem
Function RemoveHook( id,func:Object( id,data:Object,context:Object ) )

	Local pred:THook
	Local hook:THook=hooks[id]
	
	While hook And hook.func<>func
		pred=hook
		hook=hook.succ
	Wend
	
	If Not hook Return
	
	If pred
		pred.succ=hook.succ
	Else
		hooks[id]=hook.succ
	EndIf

End Function

Rem
bbdoc:Remove a hook function
about:
Removes the hook function specified by @hook.
End Rem
Function RemoveHookObject( hook:Object )

	If THook(hook) = Null Return

	For Local id:Int = 0 Until hooks.length
		Local pred:THook
		Local this:THook=hooks[id]
	
		While this And this<>hook
			pred=this
			this=this.succ
		Wend
	
		If Not this Continue
	
		If pred
			pred.succ=this.succ
		Else
			hooks[id]=this.succ
		EndIf
		
		Return
	Next

End Function