SendTo() RecvFrom()

BlitzMax Forums/BlitzMax Module Tweaks/SendTo() RecvFrom()

Tom	(Posted 2005) [#1]

Not yet implemented as of v1.10, these 2 Methods extend the send & recieve capability of sockets.

SendTo() works similar to .Send(), except with .Send() you're supposed to connect to a socket before using it. With .SendTo() you do not have to connect a socket first, you simply specify the destination IP & Port.

RecvFrom() works just as .Recv() does, but you also pass the method two Integer variables (srcIP & srcPort). After the call to RecvFrom() (if there was data in the socket), the srcIP & srcPort variables will be filled with the IP & Port of the sender.

Add this code in '\mod\brl.mod\socket.mod\socket.bmx' somewhere after 'Type TSocket', compile with command line 'bmk makemods brl.socket'

Tested & working in Win32, they *should* work in Linux/Mac

Cya!
Tom

  Method SendTo( buf:Byte Ptr,count,destIP,destPort,flags=0 )
    Local n=sendto_( _socket,buf,count,flags,destIP,destPort )
    If n<0 Return 0
    Return n
  End Method

  Method RecvFrom( buf:Byte Ptr,count,srcIP Var,srcPort Var,flags=0 )
    Local n=recvfrom_( _socket,buf,count,flags,srcIP,srcPort )
    If n<0 Return 0
    Return n
  End Method

Vertex

(Posted 2005) [#2]

Hi!
Problem if you use recv or recvfrom with an udp socket is that you must read the complete size of the data buffer. If you don't do this, then the message is cut to specific size and the rest where trashed.

Here the example for the UDPStream:

Strict

Import Brl.Stream
Import Pub.StdC

Private

Type TSockAddr
	Field SinFamily : Short
	Field SinPort   : Short
	Field SinAddr   : Int
	Field SinZero   : Long
End Type

Extern "OS"
	Const INVALID_SOCKET_ = -1

	?Win32
		Const FIONREAD = $4004667F
		Function ioctl_:Int(Socket:Int, Command:Int, Arguments:Byte Ptr) = "ioctlsocket@12"
		Function inet_addr_:Int(Address$z) = "inet_addr@4"
		Function inet_ntoa_:Byte Ptr(Adress:Int) = "inet_ntoa@4"
		Function getsockname_:Int(Socket:Int, Name:Byte Ptr, NameLen:Int Ptr) = "getsockname@12"
		Function err:Int() = "WSAGetLastError@0"

	?MacOS
		Const FIONREAD = $4004667F
		Function ioctl_(Socket:Int, Command:Int, Arguments:Byte Ptr) = "ioctl"
		Function inet_addr_:Int(Address$z) = "inet_addr"
		Function inet_ntoa_:Byte Ptr(Adress:Int) = "inet_ntoa"
		Function getsockname_:Int(Socket:Int, Name:Byte Ptr, NameLen:Int Ptr) = "getsockname"

	?Linux
		Const FIONREAD = $0000541B
		Function ioctl_(Socket:Int, Command:Int, Arguments:Byte Ptr) = "ioctl"
		Function inet_addr_:Int(Address$z) = "inet_addr"
		Function inet_ntoa_:Byte Ptr(Adress:Int) = "inet_ntoa"
		Function getsockname_:Int(Socket:Int, Name:Byte Ptr, NameLen:Int Ptr) = "getsockname"
	?
End Extern

Public

Type TNetwork
	Function DottedIP:String(IP:Int)
		Return String.FromCString(inet_ntoa_(htonl_(IP)))
	End Function
	
	Function IntIP:Int(IP:String)
		Return htonl_(inet_addr_(IP))
	End Function
End Type

Type TUDPStream Extends TStream
	Field Socket      : Int
	Field LocalPort   : Short
	Field RemotePort  : Short
	Field RemoteIP    : Int
	Field MessageIP   : Int
	Field MessagePort : Short
	Field ReadTimeout : Int

	Method New()
		Self.Socket      = socket_(AF_INET_, SOCK_DGRAM_, 0)
		Self.LocalPort   = 0
		Self.RemotePort  = 0
		Self.RemoteIP    = 0
		Self.ReadTimeout = 0
	End Method

	Method Delete()
		Self.Close()
	End Method

	Method SetLocalPort:Int(Port:Short=0)
		Local Address:TSockAddr, NameLen:Int

		If Self.Socket = INVALID_SOCKET_ Then Return False

		If bind_(Self.Socket, AF_INET_, Port) = SOCKET_ERROR_ Then
			Return False
		Else
			Address = New TSockAddr
			NameLen = 16
			If getsockname_(Self.Socket, Address, Varptr(NameLen)) = SOCKET_ERROR_ Then
				Return False
			Else
				Self.LocalPort = ntohs_(Address.SinPort)
				Return True
			EndIf
		EndIf
	End Method
	
	Method GetLocalPort:Short()
		Return Self.LocalPort
	End Method
	
	Method SetRemotePort(Port:Short)
		Self.RemotePort = Port
	End Method
	
	Method GetRemotePort:Short()
		Return Self.RemotePort
	End Method
	
	Method SetRemoteIP(IP:Int)
		Self.RemoteIP = IP
	End Method
	
	Method GetRemoteIP:Int()
		Return Self.RemoteIP
	End Method

	Method GetMessagePort:Short()
		Return Self.MessagePort
	End Method

	Method GetMessageIP:Int()
		Return Self.MessageIP
	End Method

	Method SetReadTimeout(ReadMillisecs:Int)
		Self.ReadTimeout = ReadMillisecs
	End Method

	Method GetReadTimeout:Int()
		Return Self.ReadTimeout
	End Method

	Method Read:Int(Buffer:Byte Ptr, Size:Int)
		Local Result:Int, MessagePort:Int

		' If Socket does not exist
		If Self.Socket = INVALID_SOCKET_ Then Return 0

		' Try to receive
		Result = recvfrom_(Self.Socket, Buffer, Size, 0, Self.MessageIP, ..
		                   MessagePort)
		
		' Mark, Port is Short not Int!!!!
		Self.MessagePort = Short(MessagePort)

		If Result = SOCKET_ERROR_ Then
			Return Size
		Else
			Return Result
		EndIf
	End Method

	Method Write:Int(Buffer:Byte Ptr, Size:Int)
		Local Result:Int

		' If Socket does not exist
		If Self.Socket = INVALID_SOCKET_ Then Return 0
		
		' Try to send
		Result = sendto_(Self.Socket, Buffer, Size, 0, Self.RemoteIP, Self.RemotePort)
		If Result = SOCKET_ERROR_ Then
			Return 0
		Else
			Return Result
		EndIf
	End Method

	Method Eof:Int()
		Local Read:Int

		' If socket does not exist
		If Self.Socket = INVALID_SOCKET_ Then
			Return True
		Else
			' Data can read?
			Read = Self.Socket
			If (select_(1, Varptr(Read), 0, Null, 0, Null, Self.ReadTimeout) ..
			   = SOCKET_ERROR_) Or (Self.ReadAvail() = 0) Then

				Return True
			Else
				Return False
			EndIf
		EndIf
	End Method

	Method Size:Int()
		Return Self.ReadAvail()
	End Method
	
	Method Close()
		If Self.Socket <> INVALID_SOCKET_ Then
			shutdown_(Self.Socket, 2)
			closesocket_(Self.Socket)
			
			Self.Socket = INVALID_SOCKET_
		EndIf
	End Method

	Method ReadAvail:Int()
		Local Size:Int
		
		If Self.Socket = INVALID_SOCKET_ Then Return 0

		If ioctl_(Self.Socket, FIONREAD, Varptr(Size)) = SOCKET_ERROR_ Then
			Return 0
		Else
			Return Size
		EndIf
	End Method
End Type

you would for example send a simple message to a specific ip, you can do this with:

Global Stream:TUDPStream

Stream = New TUDPStream
Stream.SetLocalPort(4321)

Stream.SetRemotePort(1234)
Stream.SetRemoteIP(TNetwork.IntIP("127.0.0.1"))

Stream.WriteLine("Hello World")

Stream.Close()
End

But if you would receive a message like:

Global Stream:TUDPStream

Stream = New TUDPStream
Stream.SetLocalPort(1234)

While Not KeyDown(KEY_ESCAPE)
   If Stream.ReadAvail() Then
      While Not Stream.Eof()
         Print ">"+Stream.ReadLine()
      Wend

      Stream.SetRemoteIP(Stream.GetMessageIP())
      Stream.SetRemotePort(Stream.GetMessagePort())
      Stream.WriteLine("OK")
   EndIf
Wend

Stream.Close()
End

It is not work, becouse ReadLine reads byte by byte and not the full databuffer. GetMessageIP/Port does work, but only one byte are analysted complete.

Any idea how do solve this?

cu olli

Gehhilfe

(Posted 2005) [#3]

Hi Vertex,
i have a idea using banks to buffer the data
and the sending the bank with a extra Method.

See you Tim

Vertex

(Posted 2005) [#4]

Gehilfe: Hmm, yes, that was what Blitz3D do with RecvUDPMsg. RecvUDPMsg reads all I think in a internal Blitz buffer and ReadLine and so on reads out of this buffer. But it must can do with recvfrom only. A TCP Socket can do this. I must test setsockop with a peek parameter, but I think, this does only work with windows.

cu olli

Tibit

(Posted 2005) [#5]

I'm sorry but I don't get the problem. As far as I know, RecvFrom works for me? And I don't buffer. With UDP you get a message or not?

I think I've missed something but why would you ever, want to not read the whole UDP message?

Please explain more, I can probably help you then.

Vertex

(Posted 2005) [#6]

"Hello World" consist of 13(String+Chr(13)+Chr(10) ) Bytes.

From brl.mod\stream.mod\stream.bmx:

	Method ReadLine$()
		Local str$,buf:Byte[1024],p
		Repeat
			Local n:Byte
			If Read( Varptr n,1 )<>1 Exit
			If n=0 Exit
			If n=10 Exit
			If n=13 Continue
			buf[p]=n ; p:+1
			If p<>buf.length Continue
			str:+String.FromBytes(buf,p)
			p=0
		Forever
		If p str:+String.FromBytes(buf,p)
		Return str
	End Method

You see, ReadLine want to read on this example 13 Bytes individually. One Byte need 1 call of recvfrom.

The networkbuffer consist of the 13 bytes. If you call recvfrom with 1 Byte size, than recvfrom returns SOCKET_ERROR and WSAGetlastError returns 10040 -> WSAEMSGSIZE.

http://msdn.microsoft.com/library/default.asp?url=/library/en-us/winsock/winsock/recvfrom_2.asp

WSAEMSGSIZE:

The message was too large to fit into the specified buffer and was truncated.

A message sent on a datagram socket was larger than the internal message buffer or some other network limit, or the buffer used to receive a datagram was smaller than the datagram itself.

Datagram Socket = UDP Socket

So 1 Byte is read, and the other 12 Bytes are deleted from the networkbuffer. A second call of recvfrom will fall.

cu olli

Gehhilfe

(Posted 2005) [#7]

Vertex my Version with Buffering is running well.

Private

Type TSockAddr
   Field SinFamily : Short
   Field SinPort   : Short
   Field SinAddr   : Int
   Field SinZero   : Long
End Type

Extern "OS"
   Const INVALID_SOCKET_ = -1

   ?Win32
      Const FIONREAD = $4004667F
      Function ioctl_:Int(Socket:Int, Command:Int, Arguments:Byte Ptr) = "ioctlsocket@12"
      Function inet_addr_:Int(Address$z) = "inet_addr@4"
      Function inet_ntoa_:Byte Ptr(Adress:Int) = "inet_ntoa@4"
      Function getsockname_:Int(Socket:Int, Name:Byte Ptr, NameLen:Int Ptr) = "getsockname@12"

   ?MacOS
      Const FIONREAD = $4004667F
      Function ioctl_(Socket:Int, Command:Int, Arguments:Byte Ptr) = "ioctl"
      Function inet_addr_:Int(Address$z) = "inet_addr"
      Function inet_ntoa_:Byte Ptr(Adress:Int) = "inet_ntoa"
      Function getsockname_:Int(Socket:Int, Name:Byte Ptr, NameLen:Int Ptr) = "getsockname"

   ?Linux
      Const FIONREAD = $0000541B
      Function ioctl_(Socket:Int, Command:Int, Arguments:Byte Ptr) = "ioctl"
      Function inet_addr_:Int(Address$z) = "inet_addr"
      Function inet_ntoa_:Byte Ptr(Adress:Int) = "inet_ntoa"
      Function getsockname_:Int(Socket:Int, Name:Byte Ptr, NameLen:Int Ptr) = "getsockname"
   ?
End Extern

Public

Type TNetwork
   Function DottedIP:String(IP:Int)
      Return String.FromCString(inet_ntoa_(htonl_(IP)))
   End Function
   
   Function IntIP:Int(IP:String)
      Return htonl_(inet_addr_(IP))
   End Function
End Type

Type TUDPStream Extends TStream
   Field Socket      : Int
   Field LocalPort   : Short
   Field RemotePort  : Short
   Field RemoteIP    : Int
   Field MessageIP   : Int
   Field MessagePort : Short
   Field ReadTimeout : Int
   Field RecvBuffer  : TBank
   Field SendBuffer  : TBank
   Field SendBufferSize : Short
   Field RecvBufferSize : Short
   Field ReadBufferSize : Short

   Method New()
      Self.Socket      = socket_(AF_INET_, SOCK_DGRAM_, 0)
      Self.LocalPort   = 0
      Self.RemotePort  = 0
      Self.RemoteIP    = 0
      Self.ReadTimeout = 0
	  Self.RecvBuffer = CreateBank ( 1024 )
	  Self.SendBuffer = CreateBank ( 1024 )
   End Method

   Method Delete()
      Self.Close()
   End Method

   Method SetLocalPort:Int(Port:Short=0)
      Local Address:TSockAddr, NameLen:Int

      If Self.Socket = INVALID_SOCKET_ Then Return False

      If bind_(Self.Socket, AF_INET_, Port) = SOCKET_ERROR_ Then
         Return False
      Else
         Address = New TSockAddr
         NameLen = 16
         If getsockname_(Self.Socket, Address, Varptr(NameLen)) = SOCKET_ERROR_ Then
            Return False
         Else
            Self.LocalPort = ntohs_(Address.SinPort)
            Return True
         EndIf
      EndIf
   End Method
   
   Method GetLocalPort:Short()
      Return Self.LocalPort
   End Method
   
   Method SetRemotePort(Port:Short)
      Self.RemotePort = Port
   End Method
   
   Method GetRemotePort:Short()
      Return Self.RemotePort
   End Method
   
   Method SetRemoteIP(IP:Int)
      Self.RemoteIP = IP
   End Method
   
   Method GetRemoteIP:Int()
      Return Self.RemoteIP
   End Method

   Method GetMessagePort:Short()
      Return Self.MessagePort
   End Method

   Method GetMessageIP:Int()
      Return Self.MessageIP
   End Method

   Method SetReadTimeout(ReadMillisecs:Int)
      Self.ReadTimeout = ReadMillisecs
   End Method

   Method GetReadTimeout:Int()
      Return Self.ReadTimeout
   End Method

	Method Send:Int()
		'Bank aus lessen und Senden und danach lerren.
		Local Result:Int
		
		Result = sendto_ ( Self.Socket,  Self.SendBuffer.buf(), Self.SendBufferSize, 0, Self.RemoteIP, Self.RemotePort )
		
		If Result = SOCKET_ERROR_ Then Return False Else Return True
		
		Self.SendBufferSize = 0
		
	End Method

	Method Recv:Int()

		Local size:Int = Self.ReadAvail()
		Local Result:Int, MessagePort:Int
		
		If size = 0 Then Return False

		Result = recvfrom_ ( Self.Socket, Self.RecvBuffer.buf(), 1024, 0, Self.MessageIP, MessagePort ) 
		
		Self.MessagePort = Short(MessagePort)
		
		Self.RecvBufferSize = 0
		
		Self.ReadBufferSize = Size
		
		Return True

	End Method
	
	Method Read:Int (Buffer:Byte Ptr, Size:Int)

		Print "Reading"

		Local BBuffer:Byte Ptr = Self.RecvBuffer.buf()
		
		If Self.Socket = INVALID_SOCKET_ Then Return False
		
		'Set Offset in Bank
		BBuffer:+ Self.RecvBufferSize
		
		'Copy Data
		MemCopy Buffer, BBuffer, Size
		
		Self.RecvBufferSize:+ Size
		
		Return True
	
	End Method
	
	Method Write:Int (Buffer:Byte Ptr, Size:Int)
		
		Print "Writing"
		
		Local BBuffer:Byte Ptr = Self.SendBuffer.buf()
		
		If Self.Socket = INVALID_SOCKET_ Then Return False

		BBuffer:+ Self.SendBufferSize
		
		MemCopy BBuffer, Buffer, Size
		
		Self.SendBufferSize:+ Size
		
		Return True

	End Method
   
	Method Eof:Int()
      Local Read:Int

      ' If socket does not exist
      	If Self.Socket = INVALID_SOCKET_ Then
         	Return True
		End If
		
		If RecvBufferSize >= ReadBufferSize Then 
			Return True
		Else
			Return False
		End If

  	 End Method

   Method Size:Int()
      Return Self.ReadAvail()
   End Method
   
   Method Close()
      If Self.Socket <> INVALID_SOCKET_ Then
         shutdown_(Self.Socket, 2)
         closesocket_(Self.Socket)
         
         Self.Socket = INVALID_SOCKET_
      EndIf
   End Method

   Method ReadAvail:Int()
      Local Size:Int
      
      If Self.Socket = INVALID_SOCKET_ Then Return 0

      If ioctl_(Self.Socket, FIONREAD, Varptr(Size)) = SOCKET_ERROR_ Then
         Return 0
      Else
         Return Size
      EndIf
   End Method
End Type

And some Sampels

Const Port = 1234

Global Stream:TUDPStream

Stream = New TUDPStream
If Not Stream.SetLocalPort(Port) Then RuntimeError "Server can not bind to port: "+ Port

Repeat
	
	Delay 200
		
	If Stream.Recv() 
		While Not Stream.eof()
			Print "New Byte:" +	Stream.ReadByte()
		Wend
	EndIf
	
	FlushMem()	

Forever

Const Port = 5200

Global Stream:TUDPStream

Stream = New TUDPStream
If Not Stream.SetLocalPort(Port) Then RuntimeError "Server can not bind to port: "+ Port

Stream.SetRemoteIP TNetwork.IntIP("127.0.0.1")
Stream.SetRemotePort 1234

Stream.WriteByte(33)
Stream.WriteByte(33)
Stream.WriteByte(33)
Stream.WriteByte(33)
Stream.WriteByte(33)
Stream.WriteByte(33)
Stream.WriteByte(33)

Stream.Send()

Tom	(Posted 2005) [#8]

I still don't get what you're on about. I'm not using streams, and as Wave said, sendTo() & recvFrom() are working fine for me too.

If there's a problem with sockets when using the additional code I posted, can you show us a simple example?

Thanks
Tom