Small DrawText addition

BlitzMax Forums/BlitzMax Module Tweaks/Small DrawText addition

N	(Posted 2004) [#1]

Rem
bbdoc: Draw text
about:
#DrawText prints strings at position @x,@y of the graphics display using
the current image font specified by the #SetImageFont command.  The text will be centered based on your use of @centerx and @centery .<p>
Other commands that affect #DrawText include #SetColor, #SetHandle, 
#SetScale, #SetRotation, #SetOrigin, #SetViewPort, #SetBlend and #SetAlpha.
End Rem
Function DrawText( t$,x#,y#, centerx%=0, centery%=0 )
	If centerx Then x :- TextWidth(t$)*.5
	If centery Then y :- TextHeight(t$)*.5
	image_font.Draw t,..
	x+origin_x+handle_x*tform_ix+handle_y*tform_iy,..
	y+origin_y+handle_x*tform_jx+handle_y*tform_jy,..
	tform_ix,tform_iy,tform_jx,tform_jy
End Function

You can probably figure out where to put this if you decide to use it.

fredborg

(Posted 2004) [#2]

And more from the same drawer:

Rem
bbdoc: Draw text
about:
#DrawText prints strings at position @x,@y of the graphics display using
the current image font specified by the #SetImageFont command.  The text will be aligned based on your use of @alignx and @aligny. Possible values for @alignx are:<br>
ALIGN_LEFT - Aligns the text so the left most edge is at @x (Default)<br>
ALIGN_CENTER - Centers the text horizontaly at @x<br>
ALIGN_RIGHT - Aligns the text so the right most edge is at @x<br>
Possible values for @aligny are:<br>
ALIGN_TOP - Aligns the text so the top is at @y (Default)<br>
ALIGN_MIDDLE - Centers the text verticaly at @y<br>
ALIGN_BOTTOM - Aligns the text so the bottom edge is at @y<p>
Other commands that affect #DrawText include #SetColor, #SetHandle, 
#SetScale, #SetRotation, #SetOrigin, #SetViewPort, #SetBlend and #SetAlpha.
End Rem
Const ALIGN_LEFT   = 0
Const ALIGN_CENTER = 1
Const ALIGN_RIGHT  = 2
Const ALIGN_TOP    = 0
Const ALIGN_MIDDLE = 1
Const ALIGN_BOTTOM = 2
Function DrawText( t$,x#,y#, alignx%=0, aligny%=0 )
	If alignx = ALIGN_CENTER
		x :- TextWidth(t$)*.5
	ElseIf alignx = ALIGN_RIGHT
		x :- TextWidth(t$)
	EndIf
	If aligny = ALIGN_MIDDLE
		y :- TextHeight(t$)*.5
	ElseIf aligny = ALIGN_BOTTOM
		y :- TextHeight(t$)
	EndIf
	image_font.Draw t,..
	x+origin_x+handle_x*tform_ix+handle_y*tform_iy,..
	y+origin_y+handle_x*tform_jx+handle_y*tform_jy,..
	tform_ix,tform_iy,tform_jx,tform_jy
End Function

skidracer

(Posted 2004) [#3]

I would prefer DrawText x,y,w=0,h=0,align=0 where align is a combination of horizontal and vertical flags and w,h where specified are a rectangle area that produce multiline input when overflow occurs or when the text includes ~n characters.

Difference

(Posted 2004) [#4]

Sometimes you don't want multiline, even if the text is too wide to fit. (Lists and such)

fredborg

(Posted 2004) [#5]

This is a bit more advanced, but not perfect...

Peter, it works just like the regular DrawText if you omit the w# parameter or set it to 0.

Here's the code (place in 'max2d.bmx'):

Const H_ALIGN_LEFT   = 0
Const H_ALIGN_CENTER = 1
Const H_ALIGN_RIGHT  = 2
Const V_ALIGN_TOP    = 0
Const V_ALIGN_MIDDLE = 4
Const V_ALIGN_BOTTOM = 8
Function DrawTextEx( t$,x#,y#,w#=0,h#=0,align%=0 )

	Local textlines:String[1]
	Local linecount:Int = 1
	textlines[0] = t$

	Local fitwidth = true
	If w<=0
		' No fixed limit, if w isn't set
		w = 100000
		fitwidth = false
	End If
		
	' Try to fit inside x,y,w,h
	t$.Replace("~n",Chr(10))
		
	linecount = 1
	textlines[0] = ""
	Local index = 0
	Local oldindex = 0
	Local newline = False
	While oldindex<t.length-1
		
		newline = False
			
		index = t.length-1
			
		For Local i = oldindex To t.length-1
			If t[i] = 10
				index = i
				newline = True
				Exit
			ElseIf t[i]<=32
				index = i
				Exit
			EndIf
		Next
		
		If newline
			If TextWidth(textlines[linecount-1]+t[oldindex..index+1])<w
				textlines[linecount-1]:+t[oldindex..index+1]
				linecount:+1
				textlines=textlines[..linecount]
				textlines[linecount-1] = " "
			Else
				linecount:+1
				textlines=textlines[..linecount]
				textlines[linecount-1] = " "+t[oldindex..index+1]
			EndIf
		ElseIf TextWidth(textlines[linecount-1]+t[oldindex..index+1])<w Or textlines[linecount-1].length=0
			textlines[linecount-1]:+t[oldindex..index+1]
		Else 
			linecount:+1
			textlines=textlines[..linecount]
			textlines[linecount-1] = ""
			index = oldindex-1
		EndIf 
		oldindex = index+1
	Wend

	If fitwidth = False
		' Reset w to 0
		w = 0
	EndIf
				
	If align & V_ALIGN_MIDDLE
		y = y + h*0.5 - TextHeight(t$)*linecount*.5
	ElseIf align & V_ALIGN_BOTTOM
		y = y + h - TextHeight(t$)*linecount
	EndIf

	Local dx#

	For t$ = EachIn textlines
		dx = x
		If align & H_ALIGN_CENTER
			dx = x + w*0.5 - TextWidth(t$)*.5
		ElseIf align & H_ALIGN_RIGHT
			dx = x + w - TextWidth(t$)
		EndIf

		image_font.Draw t,..
		dx+origin_x+handle_x*tform_ix+handle_y*tform_iy,..
		y+origin_y+handle_x*tform_jx+handle_y*tform_jy,..
		tform_ix,tform_iy,tform_jx,tform_jy
		y :+ TextHeight(t$)
	Next
	
End Function

And a small example:

Graphics 640,480,16

t$ = "DrawTextEx Example~n~n~nJust some text to show how it works!!!"

Repeat
	Cls
	x0 = GraphicsWidth()/2
	y0 = GraphicsHeight()/2
	x1 = MouseX()
	y1 = MouseY()
	
	w = Abs(x0-x1)
	h = Abs(y0-y1)
	
	x0 = Min(x0,x1) 
	y0 = Min(y0,y1) 

	SetColor 255,0,0
	DrawRect x0,y0,w,h
	SetColor 255,255,255

	' Possible align flags are:
	' H_ALIGN_LEFT	(default)
	' H_ALIGN_CENTER
	' H_ALIGN_RIGHT
	' V_ALIGN_TOP		(default)
	' V_ALIGN_MIDDLE
	' V_ALIGN_BOTTOM
	'
	' Combine flags using | (binary or)	
	DrawTextEx t$,x0,y0,w,h,H_ALIGN_CENTER|V_ALIGN_MIDDLE
	
	Flip
Until KeyHit(KEY_ESCAPE)

End

I really like the way you can access a string like an array, great stuff!

Bot Builder

(Posted 2004) [#6]

Cool. Comments for the module entry:

Rem
bbdoc: Draw text
about:
#DrawText prints strings at position @x,@y of the graphics display using
the current image font specified by the #SetImageFont command.  The text 
will be aligned based on applying binary ORs (| operator) of 2 flags,
one from the top 3, one from the bottom. The flags for @align are:<br>
ALIGN_LEFT - Aligns the text so the left most edge is at @x (Default)<br>
ALIGN_CENTER - Centers the text horizontaly at @x<br>
ALIGN_RIGHT - Aligns the text so the right most edge is at @x<br>
ALIGN_TOP - Aligns the text so the top is at @y (Default)<br>
ALIGN_MIDDLE - Centers the text verticaly at @y<br>
ALIGN_BOTTOM - Aligns the text so the bottom edge is at @y<p>
Other commands that affect #DrawText include #SetColor, #SetHandle, 
#SetScale, #SetRotation, #SetOrigin, #SetViewPort, #SetBlend and #SetAlpha.
End Rem

Red	(Posted 2006) [#7]

bug fixed: SetRotation

Const H_ALIGN_LEFT   = 0
Const H_ALIGN_CENTER = 1
Const H_ALIGN_RIGHT  = 2
Const V_ALIGN_TOP    = 0
Const V_ALIGN_MIDDLE = 4
Const V_ALIGN_BOTTOM = 8
Rem
bbdoc: Draw wrapped text
about:
#DrawWrappedText prints wrapped texts in rectangle at position @x, @y of the graphics display using
the current image font specified by the #SetImageFont command.<br><br>  
@x, @y, @w, @h define the rectangle area.<br><br>
The text will be aligned based on applying binary ORs (| operator) of 2 flags,
one from the top, one from the bottom. The flags for @align are:<br><br>
<table>
<tr><th>Align values</th><th>Effect</th></tr>
<tr><td>ALIGN_LEFT</td><td>Aligns the text so the left most edge is at @x (Default)</td></tr>
<tr><td>ALIGN_CENTER</td><td>Centers the text horizontaly at @x</td></tr>
<tr><td>ALIGN_RIGHT</td><td>Aligns the text so the right most edge is at @x</td></tr>
<tr><td>ALIGN_TOP</td><td>Aligns the text so the top is at @y (Default)</td></tr>
<tr><td>ALIGN_MIDDLE</td><td>Centers the text verticaly at @y</td></tr>
<tr><td>ALIGN_BOTTOM</td><td>Aligns the text so the bottom edge is at @y</td></tr>
</table><br>
Other commands that affect #DrawWrappedText include #SetColor, #SetHandle, 
#SetScale, #SetRotation, #SetOrigin, #SetViewPort, #SetBlend and #SetAlpha.<br>
End Rem
Function DrawWrappedText( t$,x#,y#,w#=0,h#=0,align%=0 )

	Local textlines:String[1]
	Local linecount:Int = 1
	textlines[0] = t$

	Local fitwidth = True
	If w<=0
		' No fixed limit, if w isn't set
		w = 100000
		fitwidth = False
	End If
		
	' Try to fit inside x,y,w,h
	t$.Replace("~n",Chr(10))
		
	linecount = 1
	textlines[0] = ""
	Local index = 0
	Local oldindex = 0
	Local newline = False
	While oldindex<t.length-1
		
		newline = False
			
		index = t.length-1
			
		For Local i = oldindex To t.length-1
			If t[i] = 10
				index = i
				newline = True
				Exit
			ElseIf t[i]<=32
				index = i
				Exit
			EndIf
		Next
		
		If newline
			If TextWidth(textlines[linecount-1]+t[oldindex..index+1])<w
				textlines[linecount-1]:+t[oldindex..index+1]
				linecount:+1
				textlines=textlines[..linecount]
				textlines[linecount-1] = " "
			Else
				linecount:+1
				textlines=textlines[..linecount]
				textlines[linecount-1] = " "+t[oldindex..index+1]
			EndIf
		ElseIf TextWidth(textlines[linecount-1]+t[oldindex..index+1])<w Or textlines[linecount-1].length=0
			textlines[linecount-1]:+t[oldindex..index+1]
		Else 
			linecount:+1
			textlines=textlines[..linecount]
			textlines[linecount-1] = ""
			index = oldindex-1
		EndIf 
		oldindex = index+1
	Wend

	If fitwidth = False
		' Reset w to 0
		w = 0
	EndIf
			
	Local offset_x#
	Local offset_y#
	Local shift_y#
	Local dx#
	Local dy#
		
	If align & V_ALIGN_MIDDLE
		offset_y=(h - TextHeight(t$)*linecount)*.5
	ElseIf align & V_ALIGN_BOTTOM
		offset_y=(h - TextHeight(t$)*linecount)
	EndIf
	y:+ offset_y*gc.tform_jy
	x:+ offset_y*gc.tform_iy

	For t$ = EachIn textlines
		If align & H_ALIGN_CENTER
			offset_x=(w - TextWidth(t$))*.5
		ElseIf align & H_ALIGN_RIGHT
			offset_x=(w - TextWidth(t$))
		EndIf

		gc.image_font.Draw t,..
		x+gc.origin_x+(offset_x+gc.handle_x)*gc.tform_ix+gc.handle_y*gc.tform_iy,..
		y+gc.origin_y+(offset_x+gc.handle_x)*gc.tform_jx+gc.handle_y*gc.tform_jy,..
		gc.tform_ix,gc.tform_iy,gc.tform_jx,gc.tform_jy
		
		shift_y=TextHeight(t$)
		y :+ shift_y*gc.tform_jy
		x :+ shift_y*gc.tform_iy
	Next
	
End Function

N	(Posted 2006) [#8]

It's over a year old, Ed.