Tweener functions set?

BlitzMax Forums/BlitzMax Tutorials/Tweener functions set?
coffeedotbean
(Posted 2015) [#1]
I've used Monkey for some time and got used to having access to the excellent http://www.monkey-x.com/Community/posts.php?topic=4173 that allowed all kinds of Transitions e.g; http://hosted.zeh.com.br/tweener/docs/en-us/misc/transitions.html

Wondering if any one has converted this or the original by Robert Penner for use in MAX? I've search but thought I'd ask.
Yan	(Posted 2015) [#2]
Most of the Penner stuff...
'Converted from Robert Penner's easing equations - <a href="http://www.robertpenner.com/easing/" target="_blank">http://www.robertpenner.com/easing/</a>
'Original copyright notice follows...

'Copyright © 2001 Robert Penner
'All rights reserved.
'
'Redistribution And use in source And binary forms, with Or without modification, are permitted provided that the following conditions are met:
'
'    * Redistributions of source code must retain the above copyright notice, this list of conditions And the following disclaimer.
'    * Redistributions in binary form must reproduce the above copyright notice, this list of conditions And the following disclaimer in the documentation And/Or other materials provided with the distribution.
'    * Neither the name of the author nor the names of contributors may be used To endorse Or promote products derived from this software without specific prior written permission.
'
'THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS And CONTRIBUTORS "AS IS" And ANY EXPRESS Or IMPLIED WARRANTIES, INCLUDING, BUT Not LIMITED To, THE IMPLIED WARRANTIES OF MERCHANTABILITY And FITNESS For A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER Or CONTRIBUTORS BE LIABLE For ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, Or CONSEQUENTIAL DAMAGES (INCLUDING, BUT Not LIMITED To, PROCUREMENT OF SUBSTITUTE GOODS Or SERVICES; LOSS OF USE, DATA, Or PROFITS; Or BUSINESS INTERRUPTION) HOWEVER CAUSED And ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, Strict LIABILITY, Or TORT (INCLUDING NEGLIGENCE Or OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN If ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

Function LinearInterpolation!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	Return (distance! * (time! / duration!)) + begin!
End Function

Function RegularEaseIn!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ duration!
	Return distance! * time! * time! + begin!
End Function

Function RegularEaseOut!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ duration!
	Return -distance! * time! * (time! - 2!) + begin!
End Function

Function RegularEaseBoth!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ (duration! / 2!)
	If time! < 1! Then Return distance! / 2! * time! * time! + begin!
	
	time! :- 1!
	Return -distance! / 2! * (time! * (time! - 2!) - 1!) + begin!
End Function

Function StrongEaseIn!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ duration!
	Return distance! * time! * time! * time! * time! * time! + begin!
End Function

Function StrongEaseOut!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ (duration! - 1!)
	Return distance! * (time! * time! * time! * time! * time! + 1!) + begin!
End Function

Function StrongEaseBoth!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ (duration! / 2!)
	If time! < 1! Then Return distance! / 2! * time! * time! * time! * time! * time! + begin!
		
	time! :- 2!
	Return distance! / 2! * (time! * time! * time! * time! * time! + 2) + begin!
End Function

Function SinEaseIn!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	Return -distance! * Cos(time! / duration! * 90!) + distance! + begin!
End Function

Function SinEaseOut!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	Return distance! * Sin(time! / duration! * 90!) + begin!
End Function

Function SinEaseBoth!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	Return -distance! / 2! * (Cos(180! * time! / duration!) - 1!) + begin!
End Function

Function CircEaseIn!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ duration!
	Return -distance! * (Sqr(1! - time! * time!) - 1!) + begin!
End Function

Function CircEaseOut!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ (duration! - 1!)
	Return distance! * Sqr(1! - time! * time!) + begin!
End Function

Function CircEaseBoth!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ (duration! / 2!)
	If time! < 1! Return -distance! / 2! * (Sqr(1! - time! * time!) - 1!) + begin!
		
	time! :- 2!
	Return distance! / 2! * (Sqr(1! - time! * time!) + 1!) + begin!
End Function

Function CubicEaseIn!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ duration!
	Return distance! * time! * time! * time! + begin!
End Function

Function CubicEaseOut!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ (duration! - 1!)
	Return distance! * (time! * time! * time! + 1!) + begin!
End Function

Function CubicEaseBoth!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ (duration! / 2!)
	If (time! < 1!) Then Return distance! / 2! * time! * time! * time! + begin!
		
	time! :- 2!
	Return distance! / 2! * (time! *time! * time! + 2!) + begin!
End Function

Function QuadraticEaseIn!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ duration!
	Return ((distance! * time!) * time!) + begin!
End Function

Function QuadraticEaseOut!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ duration!
	Return ((-distance! * time!) * (time! - 2)) + begin!
End Function

Function QuadraticEaseBoth!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ (duration! / 2!)
	If time! < 1 
		Return ((distance! / 2!) * (time! * time!)) + begin!
	Else
		time! :- 1
		Return ((-distance! / 2!) * ((time! * (time! - 2)) - 1)) + begin!
	EndIf
End Function

Function QuarticEaseIn!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ duration!
	Return distance! * time! * time! * time! * time! + begin!
End Function

Function QuarticEaseOut!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! = (time! / duration!) - 1!
	Return -distance! * (time! * time! * time! * time! - 1!) + begin!
End Function

Function QuarticEaseBoth!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ (duration! / 2!)
	If time! < 1 Then Return distance! / 2! * time! * time! * time! * time! + begin!
	
	time! :- 2!
	Return -distance! / 2! * (time! * time! * time! * time! - 2!) + begin!
End Function

Function ExponentialEaseIn!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	If time! = 0
		Return begin!
	Else
		Return (distance! * (2 ^ (10 * ((time! / duration!) - 1)))) + begin!
	EndIf
End Function

Function ExponentialEaseOut!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	If time! = duration!
		Return distance! + begin!
	Else
		Return (distance! * (-(2 ^ (-10 * (time! / duration!))) + 1)) + begin!
	EndIf
End Function

Function ExponentialEaseBoth!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	If time! = 0
		Return begin!
	Else
		If time! = duration!
			Return distance! + begin!
		Else
			time! :/ (duration! / 2!)
			If 	time! < 1
				Return ((distance! / 2!) * (2 ^ (10 * (time! - 1)))) + begin!
			Else
				time! :- 1
				Return ((distance! / 2!)  * (-(2 ^ (-10 * time!)) + 2)) + begin!
			EndIf
		EndIf
	EndIf
End Function

Function ElasticIn!(time!, begin!, distance!, duration!, amplitude!, frequency!)
	If distance! = 0 Then Return begin!
	
	If time! = 0
		Return begin!
	Else
		time! :/ duration!
		If time! = 1 Then Return distance! + begin!
	EndIf
	
	If frequency! = Null Then frequency! = (duration! * 0.3!)
	
	Local s!
	If amplitude! < Abs(distance!)
		amplitude! = distance!
		s! = frequency! / 4!
	Else
		s! = (frequency! / 360!) * ASin(distance! / amplitude!)
	EndIf
	
	time! :- 1
	
	Return -((amplitude! * (2 ^ (10 * time!))) * Sin(((time! * duration!) - s!) * (360! / frequency!))) + begin!
End Function

Function ElasticOut!(time!, begin!, distance!, duration!, amplitude!, frequency!)
	If distance! = 0 Then Return begin!
	
	If time! = 0
		Return begin!
	Else
		time! :/ duration!  
		If time! = 1 Then Return distance! + begin!
	EndIf
	
	If frequency! = Null Then frequency! = (duration! * 0.3!)
	
	Local s!
	If amplitude! < Abs(distance!)
		amplitude! = distance!
		s! = frequency! / 4!		
	Else
		s! = (frequency! / 360!) * ASin(distance! / amplitude!)
	EndIf
	
	Return (((amplitude! * (2 ^ (-10 * time!))) * Sin(((time! * duration!) - s!) * (360! / frequency!))) + distance!) + begin!
End Function

Function ElasticBoth!(time!, begin!, distance!, duration!, amplitude!, frequency!)
	If distance! = 0 Then Return begin!
	
	If time! = 0
		Return begin!
	Else
		time! :/ (duration! / 2!)
		If time! = 2 Then Return distance! + begin!
	EndIf
	
	If frequency! = Null Then frequency! = duration! * (0.3! * 1.5!)
	
	Local s!
	If amplitude! < Abs(distance!)
		amplitude! = distance!
		s! = frequency! / 4!		
	Else
		s! = (frequency! / 360!) * ASin(distance! / amplitude!)
	EndIf
	
	If time! < 1
		time! :- 1
		Return (((amplitude! * (2 ^ (10 * time!))) * Sin(((time! * duration!) - s!) * (360! / frequency!))) * -0.5!) + begin!
	Else
		time! :- 1			
		Return ((((amplitude! * (2 ^ (-10 * time!))) * Sin(((time! * duration!) - s!) * (360! / frequency!))) * 0.5!) + distance!) + begin!
	EndIf
End Function

Function OverShootIn!(time!, begin!, distance!, duration!, overshoot!=Null, dummy2!=Null)
	If overshoot! = Null Then overshoot! = 1.70158
	time! :/ duration!
	
	Return ((distance! * time!) * time! * (((overshoot! + 1) * time!) - overshoot!)) + begin!
End Function

Function OverShootOut!(time!, begin!, distance!, duration!, overshoot!=Null, dummy2!=Null)
	If overshoot! = Null Then overshoot! = 1.70158
	time! = (time! / duration!) - 1
	
	Return (distance! * (time! * time! * (((overshoot! + 1) * time!) + overshoot!) + 1)) + begin! 
End Function

Function OverShootBoth!(time!, begin!, distance!, duration!, overshoot!=Null, dummy2!=Null)
	If overshoot! = Null Then overshoot! = 1.70158
	time! :/ (duration! / 2)
	overshoot! :* 1.525
			
	If time! < 1	
		Return (distance! / 2) * (time! * time! * ((overshoot! + 1) * time! - overshoot!)) + begin!
	Else
		time! :- 2
		Return (distance! / 2) * (time! * time! * ((overshoot! + 1) * time! + overshoot!) + 2) + begin!
	EndIf
End Function

Function BounceIn!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	Return (distance! - BounceOut(duration! - time!, 0, distance!, duration!)) + begin!
End Function

Function BounceOut!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	time! :/ duration!
	
	If time! < (1! / 2.75)
		Return (distance! * (7.5625 * time! * time!)) + begin!
	ElseIf time! < (2! / 2.75)
		time! :- (1.5! / 2.75)
		Return (distance! * ((7.5625 * time! * time!) + 0.75)) + begin!
	ElseIf time! < (2.5! / 2.75)
		time! :- (2.25! / 2.75)
		Return (distance! * ((7.5625 * time! * time!) + 0.9375)) + begin!
	Else
		time! :- (2.625! / 2.75)
		Return (distance! * ((7.5625 * time! * time!) + 0.984375)) + begin!
	EndIf
End Function

Function BounceBoth!(time!, begin!, distance!, duration!, dummy1!=Null, dummy2!=Null)
	If time! < (duration! / 2)
		Return (BounceIn(time! * 2, 0, distance!, duration!) * 0.5) + begin!
	Else
		Return ((BounceOut((time! * 2) - duration!, 0, distance!, duration!) * 0.5) + (distance! * 0.5)) + begin!
	EndIf
End Function

' ------------------------------------------------- TEST CODE -------------------------------------------------
'
'Function test(interpFunction!(a!, b!, c!, d!, e!, f!)=Null)
'	
'	If interpFunction = Null
'		Print LinearInterpolation(0.75, 0, 100, 1)
'	Else
'		Print interpFunction(0.75, 0, 100, 1, 2, Null)
'	EndIf
'End Function
'
'test()
'test(ElasticBoth)
'test(LinearInterpolation)
'
' ------------------------------------------------- TEST CODE -------------------------------------------------
coffeedotbean
(Posted 2015) [#3]
You crazy mofo! hope you didn't do all this just for me. Thanks for sharing.