Panning your view

BlitzMax Forums/BlitzMax Programming/Panning your view

Cruis.In

(Posted 2012) [#1]

Hey guys I am working on a 2d top down space game for fun.

My view is centered on the player ship. Drawn at the centre of your resolution.

Using mouseX and MouseY and setorigin, I want to add a panable viewspace.

Strict

Graphics 800,600

Global newplayer:tplayer = New tplayer


Type TPlayer

	Field X:Float
	Field Y:Float

	
	
	Method Render()
		SetColor(235,110,214)
		SetRotation (0)
		SetAlpha 1.0
		
		
		'variables to hold the value of MOUSE X & Y POSITION. DIVIDED BY 2, so that your ENTITY/PLAYER doesn't scroll off screen. When Moving the cursor around.
		'remove the /2 and you'll see what I mean
		Local PanX:Float = MouseX() /2
		Local panY:Float = MouseY() /2
	
		'setting the origin
		SetOrigin(x - panx , y - pany)
		
		'the rect
		DrawRect(GraphicsWidth()/2 + x, GraphicsHeight()/2 + y, 20,20)
	End Method
	
	'standard input	
	Method GetInput()
		If KeyDown(Key_left)
			x:-1
		End If
		
		If KeyDown(key_right)
			x:+1
		End If
		
		If KeyDown(key_UP)
			y:-1
		End If
		
		If KeyDown(Key_Down)	
			y:+1
		End If
	End Method

End Type

	
	While Not KeyHit(key_ESCAPE)
		Cls
		
		newplayer.render()
		newplayer.getInput()
		
		Flip
	Wend

this works 'okish' Problem is. Just pan your mouse around. FIRST: Pan your mouse arrow to the bottom RIGHT HAND corner. You will notice your 'entity' move to the top left corner.

Now pan your mouse arrow to the top LEFT corner. You will notice the entity stays in the middle and does not move to the bottom right corner, like when you did the above first example.

Since the setorigin is drawing based on the mousex & y. The mouse x and y are at 0 when you are in the top left corner...

So it won't 'draw' your entity any further than the starting middle position (centre of screen)

So you see the issue it creates? I can move the mouse to the bottom of the screen or move the mouse to the right of the screen and get the appropriate movement out of the entity. But moving the cursor to the left of the screen or top of the screen won't work as intended.

Any ideas?

Last edited 2012

Cruis.In

(Posted 2012) [#2]

double post

Last edited 2012

Midimaster

(Posted 2012) [#3]

You did things twice, but more than this is not necessary:

Strict

Graphics 800,600

Global StarsX%[500], StarsY%[500]

For Local i%=0 To 499
	StarsX[i]=Rand(-1000,1000)
	StarsY[i]=Rand(-1000,1000)
Next

Global newplayer:tplayer = New tplayer


Type TPlayer

	Field X:Float
	Field Y:Float

	
	
	Method Render()
		SetColor(235,110,214)
		SetRotation (0)
		SetAlpha 1.0
		
		
		Local PanX:Float = -MouseX()
		Local panY:Float = -MouseY()
	
		'setting the origin
		SetOrigin GraphicsWidth()/2+PanX,GraphicsHeight()/2+PanY

		For Local i%=0 To 499
			DrawOval StarsX[i],StarsY[i],3,3
		Next
		'the rect
		DrawRect MouseX(),MouseY(), 20,20
	End Method

Last edited 2012

Cruis.In

(Posted 2012) [#4]

Strict

Graphics 800,600

Global newplayer:tplayer = New tplayer
Global starsx%[500]
Global starsy%[500]

For Local I= 0 To 499
	starsx[i]=Rnd(-1600, 1600)
	starsy[i]=Rnd(-1600, 1600)
Next

Type TPlayer

	Field X:Float 
	Field Y:Float 
	
	
	Method Render()
		SetColor(235,110,214)
		SetRotation (0)
		SetAlpha 1.0
		
		
		'variables to hold the value of MOUSE X & Y POSITION. Since my intention is to focus the 'cam' on the player at the centre of the screen, I want to
		'start out at the centre, hence the division of graphics resolution
		
		Local tx = GraphicsWidth()/2 - x 
		Local ty = GraphicsHeight()/2 - y
		
		Local PanX:Float = MouseX() - GraphicsWidth()/2
		Local panY:Float = MouseY() - GraphicsHeight()/2
		
		
	
		'setting the origin
		SetOrigin(tx - panx , ty - pany)
		
		
	End Method
	
	'standard input	
	Method GetInput()
		If KeyDown(Key_left)
			x:-1
		End If
		
		If KeyDown(key_right)
			x:+1
		End If
		
		If KeyDown(key_UP)
			y:-1
		End If
		
		If KeyDown(Key_Down)	
			y:+1
		End If
	End Method

End Type

	
	While Not KeyHit(key_ESCAPE)
		Cls
	
		
			
		newplayer.getInput()
		newplayer.render()
		
		DrawRect(newplayer.x, newplayer.y, 20,20)
		
		DrawText("X= "+newplayer.x, 100,100)
		DrawText("Y= "+newplayer.y, 100,120)
	
	
		For Local I% = 0 To 499
			DrawOval starsx[i], starsy[i], 3, 3
		Next
		
		Flip
	Wend

thanks for the input midimaster. It wasn't quite right, but I had figured it out soon after.

Don't want the player kept in the centre. So when you move the mouse in yours it seems to move the background which is a cool effect. In my case it carries the view towards the mouse pointer.

And it does so equally now without issues for all sides, above and below.

UnderwoodNullium

(Posted 2012) [#5]

Here's a 'cam-look' I made from a long time ago. It keeps the camera at a place between the mouse and the cursor, allowing you to look everywhere around you. Its pretty cool.

http://blitzmax.com/codearcs/codearcs.php?code=2382