IcmpSendEcho() problem

BlitzMax Forums/BlitzMax Programming/IcmpSendEcho() problem

Scaremonger

(Posted 2012) [#1]

Hi there,

I'm adding PING to another utility and I'm seeing something odd!

From the code I can ping 8.8.8.8 (Google I think) but I cannot ping my gateway or localhost. If I open a windows command prompt I can ping them but I cannot figure out why I cannot from my code.

Any suggestions?

Here is my test code (Windows Only):

SuperStrict

'# ICMP EXAMPLE

Global ip:Int
'ip = HostIp( "bbc.co.uk" )
'ip = HostIp( "192.168.1.254" )
'ip = HostIp( "8.8.8.8" )
ip = HostIp( "127.0.0.1" )
;;DebugLog DottedIP( ip)

Extern "Win32"
	Function GetLastError() = "GetLastError@0"
'	Function FormatMessage(err%) = "FormatMessage@0"
End Extern

Const INVALID_HANDLE_VALUE:Int = -1

Const ICMP_SUCCESS% = 0
Const ICMP_STATUS_BUFFER_TO_SMALL% = 11001                   'Buffer Too Small
Const ICMP_STATUS_DESTINATION_NET_UNREACH% = 11002           'Destination Net Unreachable
Const ICMP_STATUS_DESTINATION_HOST_UNREACH% = 11003          'Destination Host Unreachable
Const ICMP_STATUS_DESTINATION_PROTOCOL_UNREACH% = 11004      'Destination Protocol Unreachable
Const ICMP_STATUS_DESTINATION_PORT_UNREACH% = 11005          'Destination Port Unreachable
Const ICMP_STATUS_NO_RESOURCE% = 11006                       'No Resources
Const ICMP_STATUS_BAD_OPTION% = 11007                        'Bad Option
Const ICMP_STATUS_HARDWARE_ERROR% = 11008                    'Hardware Error
Const ICMP_STATUS_LARGE_PACKET% = 11009                      'Packet Too Big
Const ICMP_STATUS_REQUEST_TIMED_OUT% = 11010                 'Request Timed Out
Const ICMP_STATUS_BAD_REQUEST% = 11011                       'Bad Request
Const ICMP_STATUS_BAD_ROUTE% = 11012                         'Bad Route
Const ICMP_STATUS_TTL_EXPIRED_TRANSIT% = 11013               'TimeToLive Expired Transit
Const ICMP_STATUS_TTL_EXPIRED_REASSEMBLY% = 11014            'TimeToLive Expired Reassembly
Const ICMP_STATUS_PARAMETER% = 11015                         'Parameter Problem
Const ICMP_STATUS_SOURCE_QUENCH% = 11016                     'Source Quench
Const ICMP_STATUS_OPTION_TOO_BIG% = 11017                    'Option Too Big
Const ICMP_STATUS_BAD_DESTINATION% = 11018                   'Bad Destination
Const ICMP_STATUS_NEGOTIATING_IPSEC% = 11032                 'Negotiating IPSEC
Const ICMP_STATUS_GENERAL_FAILURE% = 11050                   'General Failure

'############################################################
'# <a href="http://msdn.microsoft.com/en-us/library/windows/desktop/aa366053(v=vs.85).aspx" target="_blank">http://msdn.microsoft.com/en-us/library/windows/desktop/aa366053(v=vs.85).aspx</a>
Type ICMP_ECHO_REPLY
	Field Address:Long			'IPAddr
	Field Status:Long			'ULONG
	Field RoundTripTime:Long	'ULONG
	Field DataSize:Short		'USHORT
	Field Reserved:Short		'USHORT
	Field Data:Byte Ptr			'PVOID
	Field Options:IP_OPTION_INFORMATION = New IP_OPTION_INFORMATION
End Type

'############################################################
'# <a href="http://msdn.microsoft.com/en-us/library/windows/desktop/aa366275(v=vs.85).aspx" target="_blank">http://msdn.microsoft.com/en-us/library/windows/desktop/aa366275(v=vs.85).aspx</a>
Type IP_OPTION_INFORMATION
	Field Ttl:Byte
	Field Tos:Byte
	Field Flags:Byte
	Field OptionsSize:Byte
	Field OptionsData:Byte Ptr
End Type

'############################################################

Global hLibrary:Int
'# Windows XP and above
hLibrary:Int = loadLibraryA( "lphlpapi.dll" )
'# Windows 2000++
If hLibrary = Null Then hLibrary = loadLibraryA( "icmp.dll" )
'# If still null, then fail
If hLibrary = Null Then 
	;;DebugLog "Loadlibrary failed"
	End
End If

Global IcmpCreateFile%() "win32"
Global icmpSendEcho%( IcmpHandle:Int,			..	'# HANDLE
					  destinationAddress:Int,	..	'# IPAddr
					  RequestData:Byte Ptr,		..	'# LPVOID
					  RequestSize:Short,		..	'# WORD
					  RequestOptions:Byte Ptr,	..	'# PIP_OPTION_INFORMATION
					  ReplyBuffer:Byte Ptr,		..	'# LPVOID
					  ReplySize:Int,			..	'# DWORD
					  Timeout:Int				..	'# DWORD
					)
Global icmpCloseHandle(IcmpHandle:Int)

IcmpCreateFile		 = GetProcAddress( hLibrary, "IcmpCreateFile" )
icmpSendEcho		 = GetProcAddress( hLibrary, "IcmpSendEcho" )
icmpCloseHandle		 = GetProcAddress( hLibrary, "IcmpCloseHandle" )

If Not icmpsendecho Or Not icmpcreatefile Or Not icmpclosehandle Then
	;;DebugLog "Error in getprocaddress"
	End
End If

Global hICMP:Int = IcmpCreateFile()
If hICMP = INVALID_HANDLE_VALUE Then
	;;DebugLog "Unable to open handle"
	;;DebugLog getlasterror()
	End
End If

Global message$ = "GPING"
Global sendbuf:Byte Ptr = message.tocstring()

Global replysize:Int  = SizeOf(ICMP_ECHO_REPLY) +Len(sendbuf)+ 9
;;DebugLog "REPLYSIZE:"+replysize
Global replybuf:TBank = CreateBank( replysize )
Global reply:ICMP_ECHO_REPLY = New ICMP_ECHO_REPLY
Global retval:Int = icmpSendEcho( hICMP, ip, sendbuf, message.length, Null, replybuf.buf(), 50, 100 )

reply.address		= PeekInt( replybuf, 0 )
reply.status		= PeekInt( replybuf, 4 )
reply.RoundTripTime = PeekInt( replybuf, 8 )
reply.DataSize 		= PeekShort( replybuf, 12 )
reply.Reserved		= PeekShort( replybuf, 14 )
'		reply.Data:Byte Ptr
'		reply.Options:IP_OPTION_INFORMATION = New IP_OPTION_INFORMATION

If retval<>0 Then
	;;DebugLog "SUCCESS: " 
	;;DebugLog "ADDRESS: " +DottedIP(reply.address)
	;;DebugLog "STATUS: " +reply.status + " [" + responsetext( reply.status ) + "]"
	;;DebugLog "ROUNDTRIP: " +reply.roundtriptime
Else
	;;DebugLog getlasterror()
	Global e% = getlasterror()
	;;DebugLog "- Retval = " + retval + ", 0x" + Hex(retval)
	;;DebugLog "FAIL: " + e + " - " + Hex( e )
'	;;Debuglog responsetext( e )
	;;DebugLog "STATUS: " +reply.status + " [" + responsetext( reply.status ) + "]"
End If
icmpclosehandle( hIcmp )

End

Function ResponseText:String(code:Long)

	Select code
	
	'Success
	Case ICMP_SUCCESS Return "Success!"
	
	'Some error occurred
	Case ICMP_STATUS_BUFFER_TO_SMALL Return "Buffer Too Small"
	Case ICMP_STATUS_DESTINATION_NET_UNREACH Return  "Destination Net Unreachable"
	Case ICMP_STATUS_DESTINATION_HOST_UNREACH Return  "Destination Host Unreachable"
	Case ICMP_STATUS_DESTINATION_PROTOCOL_UNREACH Return  "Destination Protocol Unreachable"
	Case ICMP_STATUS_DESTINATION_PORT_UNREACH Return  "Destination Port Unreachable"
	Case ICMP_STATUS_NO_RESOURCE Return  "No Resources"
	Case ICMP_STATUS_BAD_OPTION Return  "Bad Option"
	Case ICMP_STATUS_HARDWARE_ERROR Return  "Hardware Error"
	Case ICMP_STATUS_LARGE_PACKET Return  "Packet Too Big"
	Case ICMP_STATUS_REQUEST_TIMED_OUT Return  "Request Timed Out"
	Case ICMP_STATUS_BAD_REQUEST Return  "Bad Request"
	Case ICMP_STATUS_BAD_ROUTE Return  "Bad Route"
	Case ICMP_STATUS_TTL_EXPIRED_TRANSIT Return  "TimeToLive Expired Transit"
	Case ICMP_STATUS_TTL_EXPIRED_REASSEMBLY Return  "TimeToLive Expired Reassembly"
	Case ICMP_STATUS_PARAMETER Return  "Parameter Problem"
	Case ICMP_STATUS_SOURCE_QUENCH Return  "Source Quench"
	Case ICMP_STATUS_OPTION_TOO_BIG Return  "Option Too Big"
	Case ICMP_STATUS_BAD_DESTINATION Return  "Bad Destination"
	Case ICMP_STATUS_NEGOTIATING_IPSEC Return  "Negotiating IPSEC"
	Case ICMP_STATUS_GENERAL_FAILURE Return  "General Failure"
	
	'Unknown error occurred
	Default Return  "Unknown Response"
	
	End Select
End Function

BlitzSupport

(Posted 2012) [#2]

I believe it's due to the byte order of the 'ip' integer, which is supposed to be in 'network byte order', or big-endian, rather than the current [x86] little-endian order.

This appears to work, but please test further!

SuperStrict

'# ICMP EXAMPLE

Global ip:Int
'ip = HostIp( "bbc.co.uk" )
'ip = HostIp( "192.168.1.254" )
ip = HostIp( "8.8.8.8" )
ip = HostIp( "216.34.181.45") ' slashdot.org

;;DebugLog DottedIP( ip)

' ADDED THIS!

Function FlipByteOrder:Int (ip:Int)
	Return (ip Shr 24) | (ip Shr 8 & $ff00) | (ip Shl 8 & $ff0000) | (ip Shl 24)
End Function

Extern "Win32"
	Function GetLastError() = "GetLastError@0"
'	Function FormatMessage(err%) = "FormatMessage@0"
End Extern

Const INVALID_HANDLE_VALUE:Int = -1

Const ICMP_SUCCESS% = 0
Const ICMP_STATUS_BUFFER_TO_SMALL% = 11001                   'Buffer Too Small
Const ICMP_STATUS_DESTINATION_NET_UNREACH% = 11002           'Destination Net Unreachable
Const ICMP_STATUS_DESTINATION_HOST_UNREACH% = 11003          'Destination Host Unreachable
Const ICMP_STATUS_DESTINATION_PROTOCOL_UNREACH% = 11004      'Destination Protocol Unreachable
Const ICMP_STATUS_DESTINATION_PORT_UNREACH% = 11005          'Destination Port Unreachable
Const ICMP_STATUS_NO_RESOURCE% = 11006                       'No Resources
Const ICMP_STATUS_BAD_OPTION% = 11007                        'Bad Option
Const ICMP_STATUS_HARDWARE_ERROR% = 11008                    'Hardware Error
Const ICMP_STATUS_LARGE_PACKET% = 11009                      'Packet Too Big
Const ICMP_STATUS_REQUEST_TIMED_OUT% = 11010                 'Request Timed Out
Const ICMP_STATUS_BAD_REQUEST% = 11011                       'Bad Request
Const ICMP_STATUS_BAD_ROUTE% = 11012                         'Bad Route
Const ICMP_STATUS_TTL_EXPIRED_TRANSIT% = 11013               'TimeToLive Expired Transit
Const ICMP_STATUS_TTL_EXPIRED_REASSEMBLY% = 11014            'TimeToLive Expired Reassembly
Const ICMP_STATUS_PARAMETER% = 11015                         'Parameter Problem
Const ICMP_STATUS_SOURCE_QUENCH% = 11016                     'Source Quench
Const ICMP_STATUS_OPTION_TOO_BIG% = 11017                    'Option Too Big
Const ICMP_STATUS_BAD_DESTINATION% = 11018                   'Bad Destination
Const ICMP_STATUS_NEGOTIATING_IPSEC% = 11032                 'Negotiating IPSEC
Const ICMP_STATUS_GENERAL_FAILURE% = 11050                   'General Failure

'############################################################
'# <a href="http://msdn.microsoft.com/en-us/library/windows/desktop/aa366053(v=vs.85).aspx" target="_blank">http://msdn.microsoft.com/en-us/library/windows/desktop/aa366053(v=vs.85).aspx</a>
Type ICMP_ECHO_REPLY
	Field Address:Long			'IPAddr
	Field Status:Long			'ULONG
	Field RoundTripTime:Long	'ULONG
	Field DataSize:Short		'USHORT
	Field Reserved:Short		'USHORT
	Field Data:Byte Ptr			'PVOID
	Field Options:IP_OPTION_INFORMATION = New IP_OPTION_INFORMATION
End Type

'############################################################
'# <a href="http://msdn.microsoft.com/en-us/library/windows/desktop/aa366275(v=vs.85).aspx" target="_blank">http://msdn.microsoft.com/en-us/library/windows/desktop/aa366275(v=vs.85).aspx</a>
Type IP_OPTION_INFORMATION
	Field Ttl:Byte
	Field Tos:Byte
	Field Flags:Byte
	Field OptionsSize:Byte
	Field OptionsData:Byte Ptr
End Type

'############################################################

Global hLibrary:Int
'# Windows XP and above
hLibrary:Int = loadLibraryA( "iphlpapi.dll" )
'# Windows 2000++
If hLibrary = Null Then hLibrary = loadLibraryA( "icmp.dll" )
'# If still null, then fail
If hLibrary = Null Then 
	;;DebugLog "Loadlibrary failed"
	End
End If

Global IcmpCreateFile%() "win32"
Global icmpSendEcho%( IcmpHandle:Int,			..	'# HANDLE
					  destinationAddress:Int,	..	'# IPAddr
					  RequestData:Byte Ptr,		..	'# LPVOID
					  RequestSize:Short,		..	'# WORD
					  RequestOptions:Byte Ptr,	..	'# PIP_OPTION_INFORMATION
					  ReplyBuffer:Byte Ptr,		..	'# LPVOID
					  ReplySize:Int,			..	'# DWORD
					  Timeout:Int				..	'# DWORD
					)
Global icmpCloseHandle(IcmpHandle:Int)

IcmpCreateFile		 = GetProcAddress( hLibrary, "IcmpCreateFile" )
icmpSendEcho		 = GetProcAddress( hLibrary, "IcmpSendEcho" )
icmpCloseHandle		 = GetProcAddress( hLibrary, "IcmpCloseHandle" )

If Not icmpsendecho Or Not icmpcreatefile Or Not icmpclosehandle Then
	;;DebugLog "Error in getprocaddress"
	End
End If

Global hICMP:Int = IcmpCreateFile()
If hICMP = INVALID_HANDLE_VALUE Then
	;;DebugLog "Unable to open handle"
	;;DebugLog getlasterror()
	End
End If

Global message$ = "GPING"
Global sendbuf:Byte Ptr = message.tocstring()

Global replysize:Int  = SizeOf(ICMP_ECHO_REPLY) +Len(sendbuf)+ 9
;;DebugLog "REPLYSIZE:"+replysize
Global replybuf:TBank = CreateBank( replysize )
Global reply:ICMP_ECHO_REPLY = New ICMP_ECHO_REPLY

' Flip ip byte order when passing here...

Global retval:Int = icmpSendEcho( hICMP, FlipByteOrder (ip), sendbuf, message.length, Null, replybuf.buf(), 50, 100 )

' Flip back here...

reply.address		= FlipByteOrder (PeekInt( replybuf, 0 ))


reply.status		= PeekInt( replybuf, 4 )
reply.RoundTripTime = PeekInt( replybuf, 8 )
reply.DataSize 		= PeekShort( replybuf, 12 )
reply.Reserved		= PeekShort( replybuf, 14 )
'		reply.Data:Byte Ptr
'		reply.Options:IP_OPTION_INFORMATION = New IP_OPTION_INFORMATION

If retval<>0 Then
	;;DebugLog "SUCCESS: " 
	;;DebugLog "ADDRESS: " +DottedIP(reply.address)
	;;DebugLog "STATUS: " +reply.status + " [" + responsetext( reply.status ) + "]"
	;;DebugLog "ROUNDTRIP: " +reply.roundtriptime
Else
	;;DebugLog getlasterror()
	Global e% = getlasterror()
	;;DebugLog "- Retval = " + retval + ", 0x" + Hex(retval)
	;;DebugLog "FAIL: " + e + " - " + Hex( e )
'	;;Debuglog responsetext( e )
	;;DebugLog "STATUS: " +reply.status + " [" + responsetext( reply.status ) + "]"
End If
icmpclosehandle( hIcmp )

End

Function ResponseText:String(code:Long)

	Select code
	
	'Success
	Case ICMP_SUCCESS Return "Success!"
	
	'Some error occurred
	Case ICMP_STATUS_BUFFER_TO_SMALL Return "Buffer Too Small"
	Case ICMP_STATUS_DESTINATION_NET_UNREACH Return  "Destination Net Unreachable"
	Case ICMP_STATUS_DESTINATION_HOST_UNREACH Return  "Destination Host Unreachable"
	Case ICMP_STATUS_DESTINATION_PROTOCOL_UNREACH Return  "Destination Protocol Unreachable"
	Case ICMP_STATUS_DESTINATION_PORT_UNREACH Return  "Destination Port Unreachable"
	Case ICMP_STATUS_NO_RESOURCE Return  "No Resources"
	Case ICMP_STATUS_BAD_OPTION Return  "Bad Option"
	Case ICMP_STATUS_HARDWARE_ERROR Return  "Hardware Error"
	Case ICMP_STATUS_LARGE_PACKET Return  "Packet Too Big"
	Case ICMP_STATUS_REQUEST_TIMED_OUT Return  "Request Timed Out"
	Case ICMP_STATUS_BAD_REQUEST Return  "Bad Request"
	Case ICMP_STATUS_BAD_ROUTE Return  "Bad Route"
	Case ICMP_STATUS_TTL_EXPIRED_TRANSIT Return  "TimeToLive Expired Transit"
	Case ICMP_STATUS_TTL_EXPIRED_REASSEMBLY Return  "TimeToLive Expired Reassembly"
	Case ICMP_STATUS_PARAMETER Return  "Parameter Problem"
	Case ICMP_STATUS_SOURCE_QUENCH Return  "Source Quench"
	Case ICMP_STATUS_OPTION_TOO_BIG Return  "Option Too Big"
	Case ICMP_STATUS_BAD_DESTINATION Return  "Bad Destination"
	Case ICMP_STATUS_NEGOTIATING_IPSEC Return  "Negotiating IPSEC"
	Case ICMP_STATUS_GENERAL_FAILURE Return  "General Failure"
	
	'Unknown error occurred
	Default Return  "Unknown Response"
	
	End Select
End Function

I've simply added a function to flip the order of the ip bytes (borrowed from JoshK's Networking Library in the Code Archives) and used it twice, once when calling the echo command and again when parsing its results. I *think* it's right, but you should probably check, and check if it's needed elsewhere too...

(BTW, I think "lphlpapi.dll" should be "iphlpapi.dll".)

Scaremonger

(Posted 2012) [#3]

That seems to be the solution; Many thanks and well spotted on the DLL name typo. That would have bitten me further down the line.

:)

Scaremonger

(Posted 2012) [#4]

Just in case anyone else tries this code, I found a bug that causes exception errors. The following should fix it:

Global IcmpCreateFile%() "win32"
Global icmpSendEcho%( IcmpHandle:Int, 	..  '# HANDLE
	destinationAddress:Int,       	..  '# IPAddr
  	RequestData:Byte Ptr,	      	..  '# LPVOID
  	RequestSize:Short,		..  '# WORD
  	RequestOptions:Byte Ptr,	..  '# PIP_OPTION_INFORMATION
  	ReplyBuffer:Byte Ptr,		..  '# LPVOID
  	ReplySize:Int,			..  '# DWORD
  	Timeout:Int			..  '# DWORD
  	) "win32"
Global icmpCloseHandle(IcmpHandle:Int) "win32"