Platform issues...

BlitzMax Forums/BlitzMax Programming/Platform issues...

Twinprogrammer

(Posted 2012) [#1]

Hello,

I've been making a map editor. It works great but I want the editor to move the map around(so you can have a map larger than the screen). The drawing works when I use SetOrigin to my map offset, but the map(The array with the map data) itself doesn't move with the tiles. How would I be able to move the map array with the tiles ?

xlsior

(Posted 2012) [#2]

Use off-set variables -- instead of always drawing (0) to (screenwidth), draw (0+offset) to (screenwidth+offset)

When you scroll to the side, adjust the offset up or down

Twinprogrammer

(Posted 2012) [#3]

That is what I use. It works, but I can't seem to get the map array to follow the offset. Here's a piece of code from my editor...

Function DrawMap()
    For Local X:int = 0 Until MapWidth
        For Local Y:int = 0 Until MapHeight
            SetOrigin MapOffX, MapOffY ' The Map's Offset
            DrawImage MapTiles, X * TileWidth, Y * TileHeight, Map[X, Y]
            SetOrigin 0, 0
        Next
    Next
End Function

And the tile placing function(This is the one I need help on, tell me if something's wrong)...

Function UpdateEditor()
    'Check if the mouse is in the map boundaries
    If MouseX() > MapOffX and MouseX() < (TileWidth * MapWidth) + MapOffX
        If MouseY() > MapOffY And MouseY() < (TileHeight * MapHeight) + MapOffY
        
            If MouseDown(1)
                Map[MouseX() / TileWidth, MouseY() / TileHeight] = CurrentTile
            End If
        End If
    End If 
End Function

Last edited 2012

Jesse

(Posted 2012) [#4]

I suspect it's something like this:

Function UpdateEditor()
    'Check if the mouse is in the map boundaries
    If MouseX() > MapOffX and MouseX() < (TileWidth * MapWidth) + MapOffX
        If MouseY() > MapOffY And MouseY() < (TileHeight * MapHeight) + MapOffY
        
            If MouseDown(1)
                Map[(MapOffX+MouseX()) / TileWidth, (MapOffY+MouseY()) / TileHeight] = CurrentTile
            End If
        End If
    End If 
End Function

Twinprogrammer

(Posted 2012) [#5]

I tried that too. If the map offset is not 0, I get an index out of range exception. Any other suggestions ?

Last edited 2012

Chalky

(Posted 2012) [#6]

A few things to check:

Is your array big enough to allow for the required increase in offsets?

When you increase/decrease MapOffX/MapOffY do you check that MapOffX/MapOffY + Tile-Width/Height-Of-Screen does not fall outside the array boundaries?

Does your code assume base 0 or base 1?

TomToad

(Posted 2012) [#7]

Remember that SetOrigin adds the offset to the images, so that SetOrigin 10,10 will draw an image at 10,10 with DrawImage,Image,0,0. So to scroll the map properly, you need to use a negative origin. Also be sure to subtract the origin from the mouse coordinates to get the correct position on the map. Here is an example.

SuperStrict

Graphics 800,600

Local Border:TImage = CreateImage(32,32)
Local DOT:TImage = CreateImage(32,32)

DrawRect 0,0,32,32 'create an empty map square
SetColor 0,0,0
DrawRect 2,2,28,28
GrabImage(Border,0,0)
SetColor 255,255,0
DrawOval 10,10,12,12 'Create a dot to be displayed
GrabImage(DOT,0,0)
SetColor 255,255,255

Local MapArray:Int[100,100] 'Store the map of dots in this array
Local mapx:Int = 0 'the map offset
Local mapy:Int = 0
Local OriginX:Int = 0 'for use with the SetOrigin command
Local OriginY:Int = 0


While Not KeyHit(KEY_ESCAPE) And Not AppTerminate()
	Local HighX:Int = Mapx+11 'which of the map gets drawn
	Local HighY:Int = Mapy+11 'The map is 10x10, but we are using 11x11 for overscan
	
	If HighX > 99 Then HighX = 99
	If HighY > 99 Then HighY = 99
	
	SetOrigin OriginX,OriginY
	
	Cls
	For Local x:Int = Mapx To HighX 'draw the portion of the map that actually appears on the screen
		For Local y:Int = MapY To HighY
			If MapArray[x,y] 
				DrawImage DOT,x*32,y*32
			Else
				DrawImage Border,x*32,y*32
			End If
		Next
	Next
	
	SetOrigin 0,0
	SetColor 0,0,255 'draw the border
	DrawRect 320,0,480,600
	DrawRect 0,320,320,280
	SetColor 255,255,255
	
	Flip

	If KeyDown(KEY_RIGHT) 'move the map left
		OriginX :- 2
		If OriginX < -2880 Then OriginX = -2880
		MapX = -OriginX/32
	End If

	If KeyDown(KEY_LEFT) 'move map right
		OriginX :+ 2
		If OriginX > 0 Then OriginX = 0
		MapX = -OriginX/32
	End If
	
	If KeyDown(KEY_DOWN) 'move map up
		OriginY :- 2
		If OriginY < -2880 Then OriginY = -2880
		MapY = -OriginY/32
	End If
	
	If KeyDown(KEY_UP) 'move map down
		OriginY :+ 2
		If OriginY > 0 Then OriginY = 0
		MapY = -OriginY/32
	End If
	
	If MouseHit(1) 'Left mouse button pressed
		Local MX:Int = MouseX()-OriginX 'where on the map was the button pressed?
		Local MY:Int = MouseY()-OriginY
		Local TileX:Int = MX/32 'what tile is the mouse over?
		Local TileY:Int = MY/32
		If MapArray[TileX,TileY] 'invert the tile state
			MapArray[TileX,TileY] = 0
		Else
			MapArray[TileX,TileY] = 1
		End If
	End If
Wend

Note that this is not the only way of doing things and might even not be the most efficient.

Twinprogrammer

(Posted 2012) [#8]

Cool it works ! Now my editor is complete. Thanks for the help everybody !

Last edited 2012