Unexpected behavior with MouseXSpeed and MouseYSpe

BlitzMax Forums/BlitzMax Programming/Unexpected behavior with MouseXSpeed and MouseYSpe

TomToad

(Posted 2011) [#1]

SuperStrict

Type Line
	Global List:TList = CreateList()
	Field x1:Int, y1:Int, x2:Int, y2:Int
	
	Function Add(x1:Int,y1:Int,x2:Int,y2:Int)
		Local l:Line = New Line
		l.x1 = x1
		l.x2 = x2
		l.y1 = y1
		l.y2 = y2
		List.Addlast(l)
	End Function
	
	Function Draw()
		For Local l:Line = EachIn List
			DrawLine l.x1,l.y1,l.x2,l.y2
		Next
	End Function
End Type

Graphics 800,600

Local mx:Int, my:Int 'store mouse position
Local oldx:Int, oldy:Int 'stores the old mouse position
Local First:Int = True 'flag for whether this is the first check or not

While Not KeyHit(KEY_ESCAPE) And Not AppTerminate()
	
	If MouseDown(1)
		If First
			oldx = MouseX()
			oldy = MouseY()
			First = False
		Else
			mx = oldx + MouseXSpeed()
			my = oldy + MouseYSpeed()
			Line.Add(oldx,oldy,mx,my)
			oldx = mx
			oldy = my
		End If
	Else
		First = True
	End If
	
	Cls
	Line.Draw()
	Flip
Wend

When you first press the mouse button, the program checks the absolute location of the mouse pointer. Every subsequent check should return the relative position from the last check. If you run the program above, you will notice that the first line goes from the mouse pointer to some random point, then works as expected from there.

Found out that MouseXSpeed() only checks the relative movement from the last MouseXSpeed(), but not from MouseX() so the very first time that MouseXSpeed() is called, it returns some unknown value.

If you put

MouseXSpeed()
MouseYSpeed()

on line 35, after the checks to MouseX() and MouseY() then the position is set to the current mouse position so the next calls are correct.

Jesse

(Posted 2011) [#2]

SuperStrict

Type Line
	Global List:TList = CreateList()
	Field x1:Int, y1:Int, x2:Int, y2:Int
	
	Function Add(x1:Int,y1:Int,x2:Int,y2:Int)
		Local l:Line = New Line
		l.x1 = x1
		l.x2 = x2
		l.y1 = y1
		l.y2 = y2
		List.Addlast(l)
	End Function
	
	Function Draw()
		For Local l:Line = EachIn List
			DrawLine l.x1,l.y1,l.x2,l.y2
		Next
	End Function
End Type

Graphics 800,600

Local mx:Int, my:Int 'store mouse position
Local oldx:Int, oldy:Int 'stores the old mouse position
Local First:Int = True 'flag for whether this is the first check or not

While Not KeyHit(KEY_ESCAPE) And Not AppTerminate()
	Local px:Int = MouseXSpeed()
	Local py:Int = MouseYSpeed()
	If MouseDown(1)
		If First
			oldx = MouseX()
			oldy = MouseY()
			First = False
		Else
			mx = oldx + px
			my = oldy + py
			Line.Add(oldx,oldy,mx,my)
			oldx = mx
			oldy = my
		End If
	Else
		First = True
	End If
	
	Cls
	Line.Draw()
	Flip
Wend

it seem to be accumulative. ~~"per flip()"~~ per motion amount until a request is made. At least that is what I am guessing.

Last edited 2011

Last edited 2011