Grey Alien Games Framework - Music Issue Help!

BlitzMax Forums/BlitzMax Programming/Grey Alien Games Framework - Music Issue Help!

therevills

(Posted 2011) [#1]

Hi All,

I've just started a new project using Grey Alien Framework (GAF), but for some strange reason when I quit my game the music fades but just when the game exits you can hear a slight noise. I'm pretty sure I've had this in the past but I can't remember how I've fixed it in the past - too much Monkey I think!!

Has anyone had this issue?

Heres my code:

SuperStrict

?Win32
'Import "projecticon.o" 'only enable this if you have made a projecticon.o file.
Import "Include/fullaccess.cpp"
Import "-ladvapi32"
?

?MacOs
Import "Include/GAGMacLib.m"
?

Include "Include/commoncode.bmx" 'common functions
Include "TitleScreen.bmx"
Include "GameScreen.bmx"
Include "Player.bmx"

ccCreateMutex("Test") 'this calls End if app is already running

'Consts

Const DEMO_MODE:Int = 0
Global GAMENAME:String = "Test"

If DEMO_MODE
	GAMENAME = "Test - Demo"
Else
	GAMENAME = "Test"
End If

Const VERSION:String = "v1.00"
Const COPYRIGHT:String = " - The Revills Games © 2011"
Global FULLNAME:String = GAMENAME + " " + VERSION + COPYRIGHT

Const cFontWidth:Int = 16, cFontHeight:Int = 16		' size of single character in font
Const cFirstChar:Int = 32, cLastChar:Int = 90		' range of characters in font file

AppTitle = FULLNAME 'set before graphics is called.

Global buttonText:String[100]
Global gameMusic:String[20]
Global tutorialText:String[50]

'Globals
ScreenWidth = 800
ScreenHeight = 600

'game object
ccGraphicalErrors = 0
Game = New TGame
'Game.DataInAppBundle=1  'Optional Flag for Macs.  Must set this before SetSubPathWrapper is called
Game.SetSubPathWrapper("The Revills Games/Test") 'must do before Init
Game.CheckGoodExit()
Game.Init()
Game.ChannelsCreate(16)
Game.Channels.MaxVol = 16
Game.DebugDisplayX = 5
Game.DebugDisplayY = 5
Game.LogicFix = 1

?Not Debug
Game.IgnoreDebugKey = True
Game.IgnoreFrameworkKeys = True
?
?Debug
Game.FullScreen = 0
?
Game.FullScreen = 0

Game.MaxLevels = 20
Game.FadeMouse = 1
Game.TerminatedUserFunction = TerminateFunction

'data banks
Global images:TImageBank = New TImageBank
images.SetPath(Game.ImagePath)
Global sounds:TSoundBank = New TSoundBank
sounds.SetPath(Game.SoundPath)

'Fonts
Global FontsPath:String = Game.DataPrefix + "Data/fonts/"
Global MainButtonFont:TImageFont = LoadImageFont(FontsPath + "gamefont.ttf", 40, SMOOTHFONT)

'Screens
Global TitleScreen:TTitleScreen = New TTitleScreen
Global GameScreen:TGameScreen = New TGameScreen

Const GRAVITY:Float = 0.12
Const PARTICLE_FADE:Float = 1000

'Initialisation Code
?Not Debug
Try
?
ccGraphicalErrors = 1
Game.GraphicsCreate()

HideMouse()

'?Not Debug
'If Game.Fade Then PortalSplash(Game.Sound, 1)
'If Game.Fade Then CompanySplash(Game.Sound, 1)
'?

LoadData()
ccFlushAll()

'Main loop
Local LoopExit:Int = 0
Game.FixedRateLogic.Init()

Repeat
	'do the logic separately from the drawing
	If Game.MainLogicLoop() = -1 Then ShutDown()
	
	'draw the screen and flip it to show it
	Game.ScreenDraw()							
Until LoopExit = 1

ShutDown()
?Not Debug
'This bit traps and handles general errors. (Comment this section out when developing)
Catch o:Object
	HandleGeneralError(o)
	Shutdown()
End Try
?
'#ShutDown as a label doesn't compile, due to being in Strict mode so I've made a function instead.
Function Shutdown()
	TGame.MakeGoodExit()
	ShowMouse() 'just in case it was hidden.
	CleanUp() 'Free up memory

	'Exit the program
	End
End Function

'Loading Data
Function LoadData()
	AutoMidHandle True
	
	'Ensure clear screen when loading
	ccClsVSync()
	Game.LoadingScreen.SpecialLoad("gui/loadingscreen.jpg", "gui/loadingbar.png", "gui/loading.png")
	Game.LoadingScreen.LoadingBar.Centre(ScreenHeight - 85)
	Game.LoadingScreen.LoadingBar.Mode = 0
	Game.LoadingScreen.SetSteps(10 + 4 + 1)

	Game.LoadingScreen.Draw()
	Game.Mouse.Off()
	Game.LoadingScreen.Destination = TitleScreen
	
	LoadSounds()
	LoadImages()
	Game.CurrentTScreen = Null
	TitleScreen.Load()
	Game.MoveBar()
	Game.CurrentTScreen = Game.LoadingScreen
	Game.MusicPlay() 
	'Has the app been suspended whilst loading?  If so, deal with it.
	?Win32
	If GetForegroundWindow()<>Game.WindowHandle Then Game.SuspendedEvent = 1
	?
End Function

Function LoadSounds()
	Local no:Int = 0
	DebugLog "No of sounds >" + no
End Function

Function LoadImages()
	Local no:Int = 0
	DebugLog "No of images >" + no
End Function

'Clean Up
Function CleanUp()
	'free stuff here (not really needed in Blitz Max)
	Game.Kill()
End Function

Function TerminateFunction:Int()
	
End Function

Type TTitleScreen Extends TScreen

	Method Load:Int()
		name = "title"
	'	If Game.CurrentTScreen = Game.LoadingScreen Then Return 0
		
		Local firstTime:Int = False
		
		If Game.CurrentTScreen = Null Then firstTime = True
		If Not firstTime Then
			Game.LoadingScreen.DrawLoading(1)
		EndIf
		
		If firstTime Or ..
			Game.CurrentTScreen = GameScreen Then
			Game.MusicLoad("Plans in Motion.ogg")
		End If
		Game.FadeMusic = 1
		
	End Method

	Method Kill()
		Super.Kill()
	End Method
	
	Method Start()
		Game.Mouse.UpdateCoords() 'I'm calling this now so that Super.Start() can use the coords for Menu.ManageNoSound()
		Super.Start()
		
		If Game.LastTScreen = GameScreen Then
			Game.MusicPlay()
		End If
		
		Game.GameFade.Init(FADE_SPEED, 0, Null, True) 'fade in (allow anim)
		Game.FixedRateLogic.Init() 'make sure the fixed rate logic is reset from now
	End Method
	
	Method Logic:Int()
		Super.Logic() 'handles menu core logic
		If KeyHit(KEY_SPACE)
			Game.GameFade.Init(FADE_SPEED, 1, Game.MusicChannel, True)
			Game.DestinationTScreen = GameScreen
		End If
	End Method
	
	Method Draw()
		SetBlend SOLIDBLEND
	End Method
End Type

I've been banging my head against the desk for the past few days on this!!

Cheers!

therevills

(Posted 2011) [#2]

Jake (Grey Alien) has found a workaround to fix this, but it looks like it might be a BlitzMax issue, I'll do some more testing with just pure BlitzMax code.

Jake's suggested fix is to add this, to the top of Shutdown():

For Local i%=0 To 60
        Flip 1
Next

Thanks again Jake :)

Last edited 2011

Grey Alien

(Posted 2011) [#3]

A loop of 20 works on my PC. It must be some kinda Blitz or OpenAL bug because delaying the shutdown of a game so a fadeout stays at 0 volume shouldn't need to be done...