scripting object events and movements

BlitzMax Forums/BlitzMax Programming/scripting object events and movements

Xin	(Posted 2011) [#1]

hi guys ive been using blitzmax for a couple of months now. Im not exactly new to programming but id say im somewhere between beginner and intermediate. well the problem i am having is im trying to make an event based engine. for example if any of you have ever used rpg maker. basically "the player collides with this object and triggers an event" such as a cutscene in an rpg. but ive been trying for 3 days to get an engine going and im not getting anywhere. i want something like this:

EVENTHANDLER.begin()

moveevent(player, 5 steps to the right)
moveevent(player, 5 steps down)
speakevent(player, "hello i am the hero")
speakevent(enemy1, "lets fight!")
battlebeginevent(player,enemy1)

EVENTHANDLER.end()

see this would be A lot easier than using many nested if statements which would be sloppy and difficult to debug and manage. Im not asking you guys to write my game for me. Im asking for an example or a link to something which might help. Any help would be greatly appreciated.

Kryzon

(Posted 2011) [#2]

Hi Xin, welcome to the forums.
There has been some discussion on this subject in this thread, so make sure to take a look.

Czar Flavius

(Posted 2011) [#3]

I haven't properly tested it, but should give some ideas.

' dummy type to model your players, enemies etc for this code example
Type TActor
	Method move(direction:Float, distance:Float)
		
	End Method
	
	Method attack(victim:TActor)
		
	End Method
End Type

Type TEventBase
	Field _start_time
	
	Method get_start_time:Int()
		Return _start_time
	End Method
	
	Method start_action() Abstract
	
	' to sort the event queue by time
	Method Compare:Int(other:Object)
		Local event:TEventBase = TEventBase(other)
		' a fail safe you just need
		If Not event Then Return Super.Compare(other)
		
		Local mytime = Self.get_start_time()
		Local theirtime = event.get_start_time()
		
		If mytime > theirtime Then Return 1 .. ' i'm greater
		ElseIf mytime < theirtime Then Return -1 ..' they're greter
		Else Return 0
	End Method
End Type

Type TMoveEvent Extends TEventBase
	Field _actor:TActor
	' change according to how you handle movement
	Field _direction:Float
	Field _distance:Float
	
	Method start_action()
		Print "moving"
		_actor.move(_direction, _distance)
	End Method
	
	Function Create:TMoveEvent(start_time, actor:TActor, direction:Float, distance:Float)
		Local move_event:TMoveEvent = New TMoveEvent
		move_event._start_time = start_time
		move_event._actor = actor
		move_event._direction = direction
		move_event._distance = distance
		Return move_event
	End Function
End Type

Type TAttackEvent Extends TEventBase
	Field _aggressor:TActor, _victim:TActor
	
	Method start_action()
		Print "attacking"
		_aggressor.attack(_victim)
	End Method
	
	Function Create:TAttackEvent(start_time, aggressor:TActor, victim:TActor)
		Local attack_event:TAttackEvent = New TAttackEvent
		attack_event._start_time = start_time
		attack_event._aggressor = aggressor
		attack_event._victim = victim
		Return attack_event
	End Function
End Type

Type TEventManager
	Field _event_queue:TList = New TList
	Field _ticks = -1 ' current time
	
	Method get_ticks:Int()
		Return _ticks
	End Method
	
	Method started_yet:Int()
		Return _ticks <> -1
	End Method
	
	' add a new event to the sequence
	Method register_event(event:TEventBase)
		Assert _ticks = -1, "registering events after event manager has been started"
		_event_queue.AddLast(event)
	End Method
	
	' call after all events have been registered
	Method prepare_to_start()
		Assert _ticks = -1, "preparing to start event manager while already started"
		' sort events by start time, soonest first
		_event_queue.Sort()
		_ticks = 0 'begin
	End Method
	
	Method update()
		Assert _ticks >= 0, "updating event manager that hasn't been prepared"
		Assert Not _event_queue.IsEmpty(), "ran out of events"
		_process_events()
		_ticks :+ 1
	End Method
	
	Method is_finished:Int()
		Return _event_queue.IsEmpty()
	End Method
	
	Method _process_events()
		If Not _event_queue.IsEmpty()
			' get the next event
			Local event:TEventBase = TEventBase(_event_queue.First())
			Local start_time = event.get_start_time()
			Assert start_time >= _ticks, "an event didn't get triggered in time"
			' is it time for this event?
			If start_time = _ticks
				' kick it off
				event.start_action()
				_event_queue.RemoveFirst()
				' the next event may start on the same ticks, so check again
				_process_events()
			End If
		End If
	End Method
End Type

' very rough sample usage
Local player1:TActor = New TActor, player2:TActor = New TActor
Local event_manager:TEventManager = New TEventManager
event_manager.register_event(TMoveEvent.Create(0, player1, 5, 10))
event_manager.register_event(TAttackEvent.Create(5, player1, player12))
event_manager.register_event(TMoveEvent.Create(0, New player1, 5, 10))
event_manager.register_event(TMoveEvent.Create(3, New player2, 5, 10))
event_manager.prepare_to_start()

While Not event_manager.is_finished()
	Print event_manager.get_ticks()
	event_manager.update()
WEnd

0
moving
moving
1
2
3
moving
4
5
attacking

Last edited 2011

Last edited 2011

Xin	(Posted 2011) [#4]

thanks for the responses and thank you Czar for that example. it was enough to help me understand how my types and the event manager should be structured. =D hopefully it will be enough to get a decent event system running. i just want to be able to do simple cutscenes without having to use pre-rendered video

Last edited 2011

Last edited 2011