No DX9 16bit Graphic modes.

BlitzMax Forums/BlitzMax Programming/No DX9 16bit Graphic modes.

Richard Betson

(Posted 2011) [#1]

I may have missed something but I get no 16 bit color modes available on two different systems in DX9. Using this code will only list 32bit modes.

Print "Available graphics modes:"

For mode:TGraphicsMode=EachIn GraphicsModes()

	Print mode.width+","+mode.height+","+mode.depth+","+mode.hertz

Next

One systems an older XP with NVidia g4 mx 440 and a Win 7 with a NVidia Gforce 6150 SE. Is there a NVidia problem?

Thanks,

col	(Posted 2011) [#2]

Hiya,

Its not a problem with the Gfx card at all.
BRL have made only 32bit modes available in DX9.

I'm guessing this is just because to make things easier with the Max2D textures and colors etc. but I stand to be corrected.

Last edited 2011

Richard Betson

(Posted 2011) [#3]

That explains a lot. ;)

Thanks,

kfprimm

(Posted 2011) [#4]

I've already run into a similar issue when working with the D3D9 driver concerning the lack of depth and stencil buffering. The issue exists because only 32-bit formats are enumerated as evidence at line 311 of d3d9graphics.bmx (BRL.DXGraphics):

Local n=_d3d.GetAdapterModeCount( D3DADAPTER_DEFAULT,D3DFMT_X8R8G8B8 )

Throughout the module, the only format ever used is D3DFMT_X8R8G8B8.

Here are a list of all formats. D3DFMT_X1R5G5B5 or D3DFMT_R5G6B5 are probably the best choices for 16-bit.

As a note, here's a fix that'll add depth and stencil buffering. A similar solution could be created to allow 16-bit backbuffer formats.
https://github.com/kfprimm/maxb3d/wiki/BRL.DXGraphics-and-BRL.D3D9Max2D-Tweak

kfprimm

(Posted 2011) [#5]

Here's a quick solution but untested (nor compiled) because I'm on my Linux box and don't have a Windows machine close by.

In TD3D9GraphicsDriver.Create, replace the graphics mode enumeration code with this,

'enum graphics modes	
		Function EnumerateModes(format, depth)
			Local n=_d3d.GetAdapterModeCount( D3DADAPTER_DEFAULT,format )
			Local modes:TGraphicsMode=New TGraphicsMode[n]
			For Local i=0 Until n
				Local d3dmode:D3DDISPLAYMODE=New D3DDISPLAYMODE
	
				If _d3d.EnumAdapterModes( D3DADAPTER_DEFAULT,format,i,d3dmode )<0
					Continue
				EndIf
				
				Local mode:TGraphicsMode=New TGraphicsMode
				mode.width=d3dmode.Width
				mode.height=d3dmode.Height
				mode.hertz=d3dmode.RefreshRate
				mode.depth=depth
				
				modes[i]=mode
			Next
			Return modes
		End Function
			
		_modes=EnumerateModes(D3DFMT_X8R8G8B8, 32)+EnumerateModes(D3DFMT_X1R5G5B5, 16)

In OpenD3DDevice, modify it with this,

	Local format=D3DFMT_X8R8G8B8
	If depth=16 Or (depth=0 And _d3d.CheckDeviceFormat(0,D3DDEVTYPE_HAL,D3DFMT_X1R5G5B5,D3DUSAGE_RENDERTARGET,D3DFMT_X1R5G5B5) format=D3DFMT_X1R5G5B5
	
	Local pp:D3DPRESENT_PARAMETERS=New D3DPRESENT_PARAMETERS
	pp.BackBufferWidth=width
	pp.BackBufferHeight=height
	pp.BackBufferCount=1
	pp.BackBufferFormat=(format * fullscreen) + (D3DFMT_UNKNOWN * windowed)
	pp.MultiSampleType=D3DMULTISAMPLE_NONE
	pp.SwapEffect=(D3DSWAPEFFECT_DISCARD * fullscreen) + (D3DSWAPEFFECT_COPY * windowed)
	pp.hDeviceWindow=hwnd
	pp.Windowed=windowed
	pp.Flags=D3DPRESENTFLAG_LOCKABLE_BACKBUFFER
	pp.FullScreen_RefreshRateInHz=(hertz * fullscreen)
	pp.PresentationInterval=D3DPRESENT_INTERVAL_ONE	'IMMEDIATE

I plan on testing this later.

col	(Posted 2011) [#6]

I think you'll find there will be more needed than just setting the display resolution and format to 16bit modes.

The whole of Max2D is built and coded with 32bit graphics in mind, which includes the OpenGL side too. You may end up with difficult to find problems and possible gfx bugs/gfx anomalies with images and textures etc further down the line.

And don't forget about loading images that arent in the format you've proposed ? There are many options for 16bit other 5bits for R, G and B and 1 bit alpha. All images loaded that are 16 and 32bit will need converting to this format to display correctly.

If you look through the source you find thats exactly what BRL do when loading images into 32Bit. They convert the image to a 'BRL standard' format.

Already a bug is that the Direct3D interface doesnt even close unless an attempt to create a Direct3Device fails. Maybe thats the root cause that people have been having in regard to switching resolutions ??? Maybe not, I've not tested it.

Anyway, theres so much more than meets the eye with the DirectX setup that BRL have used. Dare I say - It almost seems rushed!

But again - I stand to be corrected.

Also, for those developing using Direct3D directly, use the PIX software than comes in the DirectX SDK - Its an awesome piece of software.

Last edited 2011

kfprimm

(Posted 2011) [#7]

BlitzMax/mod/brl.mod/dxgraphics.mod/d3d9graphics.bmx


Strict

Import BRL.Graphics

Import Pub.DirectX

Import BRL.LinkedList


Private

Global _wndClass$="BBDX9Device Window Class"

Global _driver:TD3D9graphicsDriver

Global _d3d:IDirect3D9
Global _d3dCaps:D3DCAPS9
Global _modes:TGraphicsMode[]

Global _d3dDev:IDirect3DDevice9
Global _d3dDevRefs

Global _presentParams:D3DPRESENT_PARAMETERS

Global _graphics:TD3D9Graphics

Global _autoRelease:TList

Type TD3D9AutoRelease
	Field unk:IUnknown
End Type

Function D3D9WndProc( hwnd,msg,wp,lp ) "win32"

	bbSystemEmitOSEvent hwnd,msg,wp,lp,Null
	
	Select msg
	Case WM_CLOSE
		Return
	Case WM_SYSKEYDOWN
		If wp<>KEY_F4 Return
	End Select

	Return DefWindowProcW( hwnd,msg,wp,lp )

End Function

Function OpenD3DDevice( hwnd,width,height,depth,hertz,flags )

	If _d3dDevRefs
		If Not _presentParams.Windowed Return False
		If depth<>0 Return False
		_d3dDevRefs:+1
		Return True
	EndIf

	Local windowed=(depth=0)
	Local fullscreen=(depth<>0)	

	'kfprimm was here	
	Function CheckBackFormat(format)
	    Return _d3d.CheckDeviceFormat(0,D3DDEVTYPE_HAL,format,D3DUSAGE_RENDERTARGET,D3DRTYPE_SURFACE,format)=D3D_OK
	End Function
	Function CheckDepthFormat(back_format,format)
	    Return _d3d.CheckDeviceFormat(0,D3DDEVTYPE_HAL,back_format,D3DUSAGE_DEPTHSTENCIL,D3DRTYPE_SURFACE,format)=D3D_OK
	End Function
	
	Local format=D3DFMT_X8R8G8B8
	If depth=16 Or (depth=0 And Not CheckBackFormat(D3DFMT_X8R8G8B8)) format=D3DFMT_R5G6B5
	
	Local pp:D3DPRESENT_PARAMETERS=New D3DPRESENT_PARAMETERS
	pp.BackBufferWidth=width
	pp.BackBufferHeight=height
	pp.BackBufferCount=1
	pp.BackBufferFormat=(format * fullscreen) + (D3DFMT_UNKNOWN * windowed)
	pp.MultiSampleType=D3DMULTISAMPLE_NONE
	pp.SwapEffect=(D3DSWAPEFFECT_DISCARD * fullscreen) + (D3DSWAPEFFECT_COPY * windowed)
	pp.hDeviceWindow=hwnd
	pp.Windowed=windowed
	pp.Flags=D3DPRESENTFLAG_LOCKABLE_BACKBUFFER
	pp.FullScreen_RefreshRateInHz=(hertz * fullscreen)
	pp.PresentationInterval=D3DPRESENT_INTERVAL_ONE	'IMMEDIATE	
	
	If flags&GRAPHICS_DEPTHBUFFER Or flags&GRAPHICS_STENCILBUFFER 
	    pp.EnableAutoDepthStencil = True
	    If flags&GRAPHICS_STENCILBUFFER 
	        If Not CheckDepthFormat( format,D3DFMT_D24S8 )
	            If Not CheckDepthFormat( format,D3DFMT_D24FS8 )
	                If Not CheckDepthFormat( format,D3DFMT_D24X4S4 )
	                    If Not CheckDepthFormat( format,D3DFMT_D15S1 )
	                        Return False
	                    Else
	                        pp.AutoDepthStencilFormat = D3DFMT_D15S1
	                    EndIf
	                Else
	                    pp.AutoDepthStencilFormat = D3DFMT_D24X4S4
	                EndIf
	            Else
	                pp.AutoDepthStencilFormat = D3DFMT_D24FS8
	            EndIf
	        Else
	            pp.AutoDepthStencilFormat = D3DFMT_D24S8
	        EndIf
	    Else
	        If Not CheckDepthFormat( format,D3DFMT_D32 )
	            If Not CheckDepthFormat( format,D3DFMT_D24X8 )
	                If Not CheckDepthFormat( format,D3DFMT_D16 )
	                    Return False
	                Else
	                    pp.AutoDepthStencilFormat = D3DFMT_D16
	                EndIf
	            Else
	                pp.AutoDepthStencilFormat = D3DFMT_D24X8
	            EndIf
	        Else
	            pp.AutoDepthStencilFormat = D3DFMT_D32
	        EndIf
	    EndIf
	EndIf 
		
	Local cflags=D3DCREATE_FPU_PRESERVE
	
	'OK, try hardware vertex processing...
	Local tflags=D3DCREATE_PUREDEVICE|D3DCREATE_HARDWARE_VERTEXPROCESSING|cflags
	If _d3d.CreateDevice( 0,D3DDEVTYPE_HAL,hwnd,tflags,pp,_d3dDev )<0

		'Failed! Try mixed vertex processing...
		tflags=D3DCREATE_MIXED_VERTEXPROCESSING|cflags
		If _d3d.CreateDevice( 0,D3DDEVTYPE_HAL,hwnd,tflags,pp,_d3dDev )<0
	
			'Failed! Try software vertex processing...	
			tflags=D3DCREATE_SOFTWARE_VERTEXPROCESSING|cflags
			If _d3d.CreateDevice( 0,D3DDEVTYPE_HAL,hwnd,tflags,pp,_d3dDev )<0
			
				'Failed! Go home and watch family guy instead...
				Return False
			EndIf
		EndIf
	EndIf

	_presentParams=pp

	_d3dDevRefs:+1
	
	_autoRelease=New TList
	
	Return True
End Function

Function CloseD3DDevice()
	_d3dDevRefs:-1
	If Not _d3dDevRefs

		For Local t:TD3D9AutoRelease=EachIn _autoRelease
			t.unk.Release_
		Next
		_autoRelease=Null

		_d3dDev.Release_
		_d3dDev=Null
		_presentParams=Null
	EndIf
End Function

Function ResetD3DDevice()
	If _d3dDev.Reset( _presentParams )<0
		Throw "_d3dDev.Reset failed"
	EndIf
		
End Function

Public

Type TD3D9Graphics Extends TGraphics

	Method Attach:TD3D9Graphics( hwnd,flags )
		Local rect[4]
		GetClientRect hwnd,rect
		Local width=rect[2]-rect[0]
		Local height=rect[3]-rect[1]

		OpenD3DDevice hwnd,width,height,0,0,flags
		
		_hwnd=hwnd
		_width=width
		_height=height
		_flags=flags
		_attached=True
		Return Self
	End Method
	
	Method Create:TD3D9Graphics( width,height,depth,hertz,flags )
		Local wstyle

		If depth
			wstyle=WS_VISIBLE|WS_POPUP
		Else
			wstyle=WS_VISIBLE|WS_CAPTION|WS_SYSMENU|WS_MINIMIZEBOX
		EndIf
		
		Local rect[4]

		If Not depth
			Local desktopRect[4]
			GetWindowRect GetDesktopWindow(),desktopRect
				
			rect[0]=desktopRect[2]/2-width/2;		
			rect[1]=desktopRect[3]/2-height/2;		
			rect[2]=rect[0]+width;
			rect[3]=rect[1]+height;
				
			AdjustWindowRect rect,wstyle,0
		EndIf

		Local hwnd=CreateWindowExW( 0,_wndClass,AppTitle,wstyle,rect[0],rect[1],rect[2]-rect[0],rect[3]-rect[1],0,0,GetModuleHandleA(Null),Null )
		If Not hwnd Return Null

		If Not depth
			GetClientRect hwnd,rect
			width=rect[2]-rect[0]
			height=rect[3]-rect[1]
		EndIf
		
		If Not OpenD3DDevice( hwnd,width,height,depth,hertz,flags )
			DestroyWindow hwnd
			Return Null
		EndIf
		
		_hwnd=hwnd
		_width=width
		_height=height
		_depth=depth
		_hertz=hertz
		_flags=flags
		
		Return Self
	End Method
	
	Method GetDirect3DDevice:IDirect3DDevice9()
		Return _d3dDev
	End Method

	Method ValidateSize()
		If _attached
			Local rect[4]
			GetClientRect _hwnd,rect
			_width=rect[2]-rect[0]
			_height=rect[3]-rect[1]
			If _width>_presentParams.BackBufferWidth Or _height>_presentParams.BackBufferHeight
				_presentParams.BackBufferWidth=Max( _width,_presentParams.BackBufferWidth )
				_presentParams.BackBufferHeight=Max( _height,_presentParams.BackbufferHeight )
				ResetD3DDevice
			EndIf
		EndIf
	End Method
	
	'NOTE: Returns 1 if flip was successful, otherwise device lost or reset...
	Method Flip( sync )
	
		Local reset

		If sync sync=D3DPRESENT_INTERVAL_ONE Else sync=D3DPRESENT_INTERVAL_IMMEDIATE
		If sync<>_presentParams.PresentationInterval
			_presentParams.PresentationInterval=sync
			reset=True
		EndIf
		
		Select _d3dDev.TestCooperativeLevel()
		Case D3D_OK
			If reset

				ResetD3DDevice

			Else If _attached
			
				Local rect[]=[0,0,_width,_height]
				Return _d3dDev.Present( rect,rect,_hwnd,Null )>=0

			Else

				Return _d3dDev.Present( Null,Null,_hwnd,Null )>=0

			EndIf
		Case D3DERR_DEVICENOTRESET

			ResetD3DDevice

		End Select
		
		
	End Method

	Method Driver:TGraphicsDriver()
		Return _driver
	End Method
	
	Method GetSettings( width Var,height Var,depth Var,hertz Var,flags Var )
		'
		ValidateSize
		'
		width=_width
		height=_height
		depth=_depth
		hertz=_hertz
		flags=_flags
	End Method

	Method Close()
		If Not _hwnd Return
		CloseD3DDevice
		If Not _attached DestroyWindow( _hwnd )
		_hwnd=0
	End Method

	Method AutoRelease( unk:IUnknown )
		Local t:TD3D9AutoRelease=New TD3D9AutoRelease
		t.unk=unk
		_autoRelease.AddLast t
	End Method
	
	Method ReleaseNow( unk:IUnknown )
		For Local t:TD3D9AutoRelease=EachIn _autoRelease
			If t.unk=unk
				unk.Release_
				_autoRelease.Remove t
				Return
			EndIf
		Next
	End Method

	
	Field _hwnd
	Field _width
	Field _height
	Field _depth
	Field _hertz
	Field _flags
	Field _attached

End Type

Type TD3D9GraphicsDriver Extends TGraphicsDriver

	Method Create:TD3D9GraphicsDriver()
		'create d3d9
		_d3d=Direct3DCreate9( 32 ) ' kfprimm was here (with thanks to col)
		If Not _d3d Return Null
		
		'get caps
		_d3dCaps=New D3DCAPS9
		If _d3d.GetDeviceCaps( D3DADAPTER_DEFAULT,D3DDEVTYPE_HAL,_d3dCaps )<0
			_d3d.Release_
			_d3d=Null
			Return Null
		EndIf

		'enum graphics modes (kfprimm was here)
		Function EnumerateModes:TGraphicsMode[](format, depth)
			Local n=_d3d.GetAdapterModeCount( D3DADAPTER_DEFAULT,format )
			Local modes:TGraphicsMode[]=New TGraphicsMode[n]
			For Local i=0 Until n
				Local d3dmode:D3DDISPLAYMODE=New D3DDISPLAYMODE
		
				If _d3d.EnumAdapterModes( D3DADAPTER_DEFAULT,format,i,d3dmode )<0
					Continue
				EndIf
				
				Local mode:TGraphicsMode=New TGraphicsMode
				mode.width=d3dmode.Width
				mode.height=d3dmode.Height
				mode.hertz=d3dmode.RefreshRate
				mode.depth=depth
				
				modes[i]=mode
			Next
			Return modes
		End Function
			
		_modes=EnumerateModes(D3DFMT_X8R8G8B8, 32)[..]+EnumerateModes(D3DFMT_R5G6B5, 16)[..]
	
		'register wndclass
		Local wndclass:WNDCLASSW=New WNDCLASSW
		wndclass.hInstance=GetModuleHandleW( Null )
		wndclass.lpfnWndProc=D3D9WndProc
		wndclass.hCursor=LoadCursorW( Null,Short Ptr IDC_ARROW )
		wndclass.lpszClassName=_wndClass.ToWString()
		RegisterClassW wndclass
		MemFree wndclass.lpszClassName

		Return Self
	End Method
	
	Method GraphicsModes:TGraphicsMode[]()
		Return _modes
	End Method
	
	Method AttachGraphics:TD3D9Graphics( widget,flags )
		Return New TD3D9Graphics.Attach( widget,flags )
	End Method
	
	Method CreateGraphics:TD3D9Graphics( width,height,depth,hertz,flags )
		Return New TD3D9Graphics.Create( width,height,depth,hertz,flags )
	End Method
	
	Method SetGraphics( g:TGraphics )
		_graphics=TD3D9Graphics( g )
	End Method
	
	Method Flip( sync )
		Return _graphics.Flip( sync )
	End Method
	
	Method GetDirect3D:IDirect3D9()
		Return _d3d
	End Method
	
End Type

Function D3D9GraphicsDriver:TD3D9GraphicsDriver()
	Global _done
	If Not _done
		_driver=New TD3D9GraphicsDriver.Create()
		_done=True
	EndIf
	Return _driver
End Function

Anybody wanna test this out? I can enumerate 32 and 16 bit modes and the firepaint example works with both.

EDIT: Found out it would always select 16bits in windowed mode. Fixed .
EDIT: Applied col's version fix.

Last edited 2011

col	(Posted 2011) [#8]

Works ok here.
I tried most of the samples too, forcing them to use this driver and 16bit, they work ok too.

So, I stand corrected :o)

Sony Vaio VGN-FW31M

[EDIT]
Just for information :-

Direct3D is being created with the wrong parameter.
Line 347-

_d3d=Direct3DCreate9( $900 )

The $900 parameter is incorrect.
The $900 is used in the c++ header files to include the D3D9 interfaces.

If you use any DirectX monitoring software, it will complain about a conflict of versions.

The correct value is a value defined in the SDK ( D3D_SDK_VERSION which equals 32 )
so setting this to -

_d3d=Direct3DCreate9( 32 )

will allow you to use monitoring and debug software on your exe.

Last edited 2011

kfprimm

(Posted 2011) [#9]

Updated with that! Awesome, thanks.

Richard Betson

(Posted 2011) [#10]

WOW!!

Thanks kfprimm and col. This seems to work fine so far. I even get all the 16bit modes that are available with GraphicModes() and GraphicModeExists(). I have a few beta testers and several computers here I'll try it out on and let ya know.

Need to archive this.

Great work,

joncom2000

(Posted 2011) [#11]

In my directx sdk the value of D3D_SDK_VERSION=32 but to call directx9 directly it is defined as DIRECT3D_VERSION=0x0900 this is ofc because D3D_SDK_VERSION changes as you get newer sdk's so the code isnt wrong to use the original value to specify directx 9

col	(Posted 2011) [#12]

@joncom2000

When you create a Direct3D9 interface, you're not supposed to use the DIRECT3D_VERSION constant. You are supposed to use D3D_SDK_VERSION constant.

If you look in the SDK documentation, this is clearly stated,
I've never seen any code that uses the DIRECT3D_VERSION constant when using creating Direct3D9 interface.

In the SDK header file, the DIRECT3D_VERSION constant is only ever checked and used whether to include the contents of that header file or not, ie to include the code to expose the whole of Direct3D9.

What do you mean by

to call directx9 directly

?? Using the .dll instead of .lib ?

Last edited 2011

joncom2000

(Posted 2011) [#13]

I dont disagree that we should really be using D3D_SDK_VERSION constant, but we are not actually building with the official dx sdk or even a full conversion of it. I suspect there's a few other constants missing since the dx files with bmax arent complete and probably some might be wrong.

But why is this constant defined "Const DIRECT3D_VERSION9=$900" in the pub.d3d9 module code and then the create graphics for the driver has it hardcoded as $900. Infact that constant isnt even used anywhere that I can find.

col	(Posted 2011) [#14]

Hiya,

but we are not actually building with the official dx sdk or even a full conversion of it

Yes, you are right, but we are accessing the full complete release version of it ( ie the DLL ), so it should be respected that it needs compliance to work correctly.

But why is this constant defined "Const DIRECT3D_VERSION9=$900" in the pub.d3d9 module code and then the create graphics for the driver has it hardcoded as $900

Only BRL would know the real answer to that question.

I've made a daring statement in the past saying that the D3D9 module seemed... well... rushed.
This is just one example that backs up my statement. Over time, many people have had varying problems with it, and some of the main issues have been fixed either by BRL or the community.

If you compare the DX7 module source with DX9 module source, you'll notice there is a lot more error checking going on in the DX7 module. It just reads to be so much more complete and robust.

Changing the source of the topic slightly ... I've even seen mistakes with redundant textures and redundant shader calculations used in the Unreal3 editor whilst looking through the examples!! So I guess we're all prone to being just regular human beings after all, and we can all make mistakes, leaving things in or taking them out.

:o)

Richard Betson

(Posted 2011) [#15]

I just wanted to let you know that so far this modification seems to be working on dozens of systems with no complaints. In fact, some older systems love the 16bit color depth as far as application performance.

Edit -- Also works with oddmod.

Thanks again,

Last edited 2011