Making a Rotating platform in a Platform game

BlitzMax Forums/BlitzMax Programming/Making a Rotating platform in a Platform game

Rico	(Posted 2011) [#1]

I just made a boat in my platform game which rotates/tips a bit in the water. the main character can stand on top of the boat. i have never made a platfrom that rotates before so i wanted to ask for tips before i attempt it. i can draw it ok using SetRotation its just the collision detection i need help with.

whats the best way of detecting if the main character has collided with the top of the boat?. i could do imagecollide but i thought it might be more efficent to check for a collision between the main character's box and the standing surface on the boat. so i suppose between a rectangle and a line. does anyone have a function for this?

im planning to use trig functions to determine the position of the line (standing surface) as it rotates, but im not the best with these things. im sure once the man is actually on the boat i can move him about pretty easily using trig. thanks for any help or tips! :)

Jesse

(Posted 2011) [#2]

you can use polygon collision. One way of doing it is by following the principle in this thread:
http://www.blitzmax.com/Community/posts.php?topic=93221#1066645

Rico	(Posted 2011) [#3]

Thanks very much Jesse, i like that program a lot. so to check a character square against the rotating polygon - i just check each corner point against the rotating polygon?

Jesse

(Posted 2011) [#4]

Yea. something like this:


SuperStrict

'this code lands a player on a moving platform(entity) and
'moves it along with it.
'once landed(attached to entity) no test are performed to see
'if player is fallen of platform(entity).


Type Tplayer
	Field x:Float
	Field y:Float
	Field attached:Int
	Field angle:Float
	Field image:TImage
	Field lengthfs:Float
	Field angfs:Float
	
	Function Create:Tplayer(x:Float,y:Float,angle:Float)
		Local p:Tplayer = New Tplayer
		p.x = x
		p.y = y
		p.attached = False
		p.angle = angle
		p.image = CreateImage(20,20)
		Local pix:TPixmap = LockImage(p.image)
		pix.ClearPixels($ffff0000)
		SetImageHandle(p.image,10,20)
		Return p
	End Function
	
	'orbits player ang(number of degrees) from current position
	'relative to pivotx, pivoty
	Method rotate(ang:Float,pivotx:Float,pivoty:Float)
		Local tx:Float = x - pivotx
		Local ty:Float = y - pivoty
		x = tx*Cos(ang) - ty*Sin(ang) +pivotx
		y = ty*Cos(ang) + tx*Sin(ang) +pivoty
		angle :+ ang
	End Method
	
	'orbits player ang(number of degrees) relative to 0 degrees,
	'pivotx and pivoty
	Method setAngle(ang:Float,pivotx:Float,pivoty:Float)
		Local tx:Float = x - pivotx
		Local ty:Float = y - pivoty
		x = tx*Cos(ang-angle) - ty*Sin(ang-angle) + pivotx
		y = ty*Cos(ang-angle) + tx*Sin(ang-angle) + pivoty
		angle = ang
	End Method
	
	'translet player relative to pivotx, pivoty and angle
	Method translate(vx:Float,vy:Float)
		x :+ vx*Cos(angle) - vy*Sin(angle) 
		y :+ vy*Cos(angle) + vx*Sin(angle)
	End Method
	
	'normal movement along x and y
	Method move(vx:Float,vy:Float)
		x :+ vx
		y :+ vy
	End Method
	
	Method display()
		SetRotation angle
		DrawImage image,x,y
	End Method
	
End Type

Type Tentity

	Field x:Float
	Field y:Float
	Field image:TImage
	Field angle:Float
	Field x1:Float 
	Field y1:Float 
	Field x3:Float
	Field y3:Float
	
	Function Create:Tentity(x:Float,y:Float,image:TImage,angle:Float)
		Local e:Tentity = New Tentity
		e.x = x
		e.y = y
		e.image = image
		e.angle = angle
		e.x1:Float = -image.handle_x                    'rectangle top left corner
		e.y1:Float = -image.handle_y
		e.x3:Float =  image.width - image.handle_x      'rectangle bottom right corner 
		e.y3:Float =  image.height - image.handle_y  
		Return e
	End Function

	Method collidedpoint:Int(px:Float,py:Float)
		px = px - x
		py = py - y
		Local tx:Float = px*Cos(-angle) - py*Sin(-angle) 
		Local ty:Float = py*Cos(-angle) + px*Sin(-angle)  
		If tx > x1  
			If ty >y1 
				If tx < x3
					If ty < y3
						Return True
					EndIf
				EndIf
			EndIf
		EndIf
		Return False
	End Method
	
	Method rotate(ang:Float)
		angle :+ ang
	End Method
	
	Method setAngle(ang:Float)
		angle = ang
	End Method
	
	Method move(x:Float,y:Float)
		Self.x :+ x
		Self.y :+ y
	End Method
	
	Method display()
		SetRotation angle
		DrawImage image,x,y
	End Method

End Type

'test player to image collisiton and sets player on top of entity
'once It collides with image. sets player image.handle on top of 
'entity image_handle_y any where along entity image.width
  

Function landPlayer:Int(p:Tplayer,e:Tentity)
	Local collided1:Int = False
	Local collided2:Int = False
	Local img:TImage = p.image
	If p.attached = False
		Local tx:Float = p.x-img.handle_x
		Local ty:Float = p.y+(img.height-img.handle_y)
		If e.collidedpoint(tx,ty)
			collided1 = True
		EndIf
	
		tx = p.x+(p.image.width-p.image.handle_x)
		ty = p.y+(p.image.height-p.image.handle_y)
		If e.collidedPoint(tx,ty)
			collided2 = True
		EndIf
		
	EndIf
	If p.attached = False
		If collided1 Or collided2 
			Local tx:Float = p.x - e.x
			Local ty:Float = p.y - e.y
			Local px:Float = tx*Cos(-e.angle) - ty*Sin(-e.angle) 
			Local py:Float = ty*Cos(-e.angle) + tx*Sin(-e.angle)
			py = -e.image.handle_y
			tx = px*Cos(e.angle) - py*Sin(e.angle) 
			ty = py*Cos(e.angle) + px*Sin(e.angle)
			p.x = tx + e.x
			p.y = ty + e.y
			p.angle = e.angle
			p.attached = True
		EndIf
	EndIf
End Function


Graphics 800,600,0
SetBlend alphablend

Local img:TImage = CreateImage(256,32)
Local pixls:Int Ptr = Int Ptr(LockImage(img).pixels)
For Local i:Int = 0 Until img.width*img.height
	pixls[Rand(img.width*img.height-1)] = $ff00ff00
Next

SetImageHandle img,128,0


Global entity:tentity = Tentity.Create(300,400,img,45)
Global player:Tplayer = Tplayer.Create(180,50,0)
Local angle:Float  = 0
Local temp:Float = 0
Local temp2:Float = 0
Local oldtemp:Float =0
Repeat
	Cls()
	angle  = (Sin(temp)*20)
	temp2 = (Sin(temp*4)*20)
	temp = (temp+1) Mod 360
	If player.attached = True
		player.translate((KeyDown(key_right)-KeyDown(key_left))*5,0)
		entity.move(0,temp2-oldtemp)
		player.move(0,temp2-oldtemp)
		entity.setAngle(angle)
		player.setAngle(angle,entity.x,entity.y)
	Else
		entity.rotate(angle-entity.angle)
		player.move(0,5)
		landPlayer(player,entity)
	EndIf
	entity.display()
	player.display()
	oldtemp = temp2
	SetRotation 0
	DrawText "Use arrows to move once landed on platform",20,20
	Flip()
Until KeyDown(key_escape)

Last edited 2011

Rico	(Posted 2011) [#5]

Thanks very much Jesse, i have already implemeneted the rotating platfrom in my game but your code looks much neater! :D

in my game the main character always stays vertical so he doesnt rotate with the platform. i like your version though.

i have found a problem though with my version and i presume it would happen in yours too. when the platform is rotated at quite a steep angle - a collision is not detected when it should be if the man lands on the end of the platform. this is because the points that are checked for collision are on either side of the corner he lands on. i dont think putting an extra point in the middle of the man's character sqaure at the bottom would help much - so am i thinking i need to check the whole of the bottom of the man's character square against the platform.

do you have a function that can detect a collision between a line and a rectangle?, where the rectangle could be rotated. so i suppose i really want onr that detects a collision between a line and a polygon? i could then just check the horizontal line at the bottom of my man against the platform.

Jesse

(Posted 2011) [#6]

do you have a function that can detect a collision between a line and a rectangle?,

No, but i believe Warpy posted one in the code archives. I can't remember if it works with rotated rectangles but I believe it does.

Rico	(Posted 2011) [#7]

thanks Jesse. i have found this for line and polygon:

http://www.blitzbasic.com/codearcs/codearcs.php?code=1676

Rico	(Posted 2011) [#8]

i fixed that problem, but i thought 'how would they have done it in the old days?'. so i just added a couple of IF statements to check if the character square was over each corner of the boat and if it was then checked to see if the character-square was overlapping vertically with the y-position of that corner. very easy fix and no need for a polygon/line collision check.