How do you delete images ?

SuperStrict

Const APP_NAME$ = "BAT AND BALL GAME!"
SeedRnd MilliSecs()

Const SCREEN_WIDTH% = 800
Const SCREEN_HEIGHT% = 600

HideMouse()

AppTitle = APP_NAME

Global paddleImage:TImage, ballImage:TImage, brickImage:TImage

Global game:TGame = New TGame

game.Setup()
game.Run()

Type TGame
	Field paddle:TPaddle ' the player
	Field ball:TBall

	Method Setup()
		Graphics SCREEN_WIDTH, SCREEN_HEIGHT
		SetBlend ALPHABLEND
		CreateImages()
		
		' create paddle and ball
		paddle = TPaddle.Create(paddleImage, SCREEN_WIDTH / 2, SCREEN_HEIGHT - paddleImage.height / 2)
		ball = TBall.Create(ballImage, SCREEN_WIDTH / 2, SCREEN_HEIGHT / 2)
		
		paddle.reset()
		
		' create bricks
		For Local i% = 0 To 12
			For Local j% = 0 To 5
				TBrick.Create(brickImage, i * (brickImage.width + 5) + 45 , j * (brickImage.height + 5) + 100)
			Next
		Next
		
		MoveMouse(SCREEN_WIDTH / 2, SCREEN_HEIGHT / 2)
	End Method

	Method Run()
		Repeat
			Logic()
			Draw()
		Until AppTerminate() Or KeyHit(KEY_ESCAPE)
	End Method
	
	Method Logic()
		paddle.Logic()
		ball.Logic()
		
		Collisions()
	End Method
	
	Method Collisions()
		If (ImagesCollide(paddle.image, MouseX(), paddle.y, 0, ball.image, ball.x, ball.y,0))
			ball.speedy = -ball.speedy
		EndIf
		
		If TBrick.list
			For Local b:TBrick = EachIn TBrick.list
				If (ImagesCollide(b.image, b.x, b.y, 0, ball.image, ball.x, ball.y, 0))
					paddle.score:+100
					ball.speedy = -ball.speedy
					b.Kill()
				EndIf
			Next
		EndIf
	End Method
	
	Method Draw()
		Cls
			paddle.Draw()
			ball.Draw()
			TBrick.DrawAll()
			DrawHUD()
		Flip
	End Method
	
	Method DrawHUD()
		DrawText "SCORE: " + paddle.score, 10, 10
		DrawText "LIVES: " + paddle.lives, 10, 25		
	End Method

	Method CreateImages()
		Cls
		' create the paddle
		paddleImage = CreateImage(100,20)	
		SetColor 255, 0, 0
		DrawRect 0, 0, 100, 20
		GrabImage paddleImage, 0, 0
		SetImageHandle paddleImage, 50, 20
		
		Cls
		' create the ball
		ballImage = CreateImage(16,16)	
		SetColor 0, 255, 0
		DrawOval 0, 0, 16, 16
		GrabImage ballImage, 0, 0
		SetImageHandle ballImage, 8, 8
			
		Cls	
		' create the brick
		brickImage = CreateImage(50,20)	
		SetColor 255, 255, 255
		DrawRect 0, 0, 50, 20
		GrabImage brickImage, 0, 0
				
	End Method 	
End Type

Type TSprite
	Field x#, y#, speedX#, speedY#
	Field image:TImage
	Field red% = 255, green% = 255, blue% = 255
	
	Method Draw()
		SetColor red, green, blue
		DrawImage image, x, y
		SetColor 255, 255, 255	
	End Method
	
	Method Logic()
	End Method
End Type

Type TPaddle Extends TSprite
	Field lives%, score%
	
	Function Create:TPaddle(image:TImage, x#, y#)
		Local p:TPaddle = New TPaddle
		p.x = x
		p.y = y
		p.image = image
		Return p
	End Function
	
	Method Reset()
		lives = 3
		score = 0
	End Method
	
	Method Draw()
		Super.Draw()
		DrawText "^",MouseX(),MouseY()
	End Method
	
	Method Logic()
		x = MouseX()
	End Method
End Type

Type TBall Extends TSprite
	Function Create:TBall(image:TImage, x#, y#)
		Local b:TBall = New TBall
		b.x = x
		b.y = y
		b.speedX = 5
		b.speedY = 5
		b.image = image
		Return b
	End Function

	Method Reset()
		x = SCREEN_WIDTH / 2
		y = SCREEN_HEIGHT / 2
	End Method
	
	Method Logic()
		X:+speedX
		y:+speedY
		
		If x > SCREEN_WIDTH Or x < 0
			speedX = -speedX
		End If
		If y > SCREEN_HEIGHT Or y <0
			speedY = -speedY
		End If		
	End Method
End Type

Type TBrick Extends TSprite
	Global list:TList

	Function Create:TBrick (image:TImage, x#, y#)
		Local b:TBrick = New TBrick 
		If list = Null list = CreateList()
		b.x = x
		b.y = y
		b.red = Rand(50,255)
		b.green = Rand(50,255)
		b.blue = Rand(50,255)
		b.image = image
		
		list.AddLast b
		
		Return b
	End Function

	Function DrawAll()
		If Not list Return
		For Local b:TBrick = EachIn TBrick.list
			b.Draw()
		Next
	End Function
	
	Method Kill()
		If Not list Return
		list.Remove(Self)
	End Method

	Function KillAll()
		If Not list Return
		For Local b:TBrick = EachIn list
			b.Kill()
		Next
	End Function
End Type

Type TBrick Extends TSprite
	Global list:TList = New TList
	Field _link:TLink

	Method New()
		_link = list.AddLast Self
	End Method

	Function Create:TBrick (image:TImage, x#, y#)
		Local b:TBrick = New TBrick 
		b.x = x
		b.y = y
		b.red = Rand(50,255)
		b.green = Rand(50,255)
		b.blue = Rand(50,255)
		b.image = image

		Return b
	End Function

	Function DrawAll()
		For Local b:TBrick = EachIn TBrick.list
			b.Draw()
		Next
	End Function
	
	Method Kill()
		_link.Remove()
		_link = Null
	End Method

	Function KillAll()
		For Local b:TBrick = EachIn list
			b.Kill()
		Next
	End Function
End Type