So many different timing methods; which to use?

BlitzMax Forums/BlitzMax Programming/So many different timing methods; which to use?

Amon	(Posted 2010) [#1]

There's so many timing methods which all look different I have no idea which one to use.

For startes can anybody make a module with the best one that can be used easily? I'm useless at this timing stuff probably because I've never bothered to look in to it and I don't have time to learn about it all.

So are there any takers on making one a module?

okee	(Posted 2010) [#2]

i'd like to +1 that

H&K	(Posted 2010) [#3]

GAs framework has one. Not sure if its part of the shareware bit or the commercial bit tho

Czar Flavius

(Posted 2010) [#4]

TimelineFX is a particle effects module but also comes with a Tweening module that the guy created too. You can download it and just use the Tweening module for your timing - thought you could use both, as the effects are pretty cool tool.

http://www.rigzsoft.co.uk/index.php?option=com_content&view=article&id=44&Itemid=25

EOF	(Posted 2010) [#5]

I use this method although I am not sure where I got it from now. It's nothing too fancy making it easy enough to follow. The Update() function contains its own variables which makes dropping it into other projects a doddle


	Function Update(Rate%=12)
		Global timeelapsed:Int
		' simple update limiter
		If MilliSecs()<timeelapsed+Rate Then Return
		timeelapsed=MilliSecs()
		'
		' **** Do all updating here (player/enemy movements)
		'
	End Function


	Function Render()
		Global oldTime%,frameCount%,FPS%
		'
		' **** Do the rendering here
		'
		' FPS monitor
		If MilliSecs()>oldTime
		   oldTime=MilliSecs()+1000
		   FPS=frameCount ; frameCount=0
		Else
		   frameCount:+1
		EndIf
		'
		Flip
	End Function

popcade

(Posted 2010) [#6]

Frame limiting is the easiest method, which should work on most fast-enough PCs.

However if you have to do network-related programming, it'll cause lots of issues, maybe try delta-timing or others instead.

Grey Alien

(Posted 2010) [#7]

Here's another simple method I used for my last 2 minigames:

Local gameTimer:TTimer = CreateTimer(60)

While Not (KeyHit(KEY_X) And (KeyDown(KEY_LCONTROL) Or KeyDown(KEY_RCONTROL)))	 
	If game.Logic() Then Finish()
	game.Draw()
	WaitTimer (gameTimer)
	Flip 0
	Delay(1) 'Give system time to catch up on things.
Wend
Finish()

Function Finish()
        'Perform any clean up here.
	End 'Exit the program
End Function

This will run a game at 60FPS, one logic per draw (so you can move things by 1 pixel a frame for example). It doesn't work that well with Flip 1 (vsync) though because there no guarantee the timer will stay in sync with the vsync. There's no delta timing so if the code got too slow it would just drop frames.

Grey Alien

(Posted 2010) [#8]

@Jim Brown: What does the main loop look like that calls your two functions? Does it just call update then draw? If so, and Flip 1 (vysnc) was used instead of Flip (default is -1), then the Rate param won't make much difference as the game will be locked to 60FPS. Same problem exists for mine if I use Flip 1 no matter what rate I set the timer at. The trick to getting faster or slower Updates than 60FPS with VSync on is to loop the updates until they are all done and then call draw only once - that's the Fixed Rate Logic approach. Of course Fixed Rate Logic falls down if the code becomes too slow, it can never keep up with what it supposed to be doing, and that's where Delta Time comes into it's own.

Last edited 2010

EOF	(Posted 2010) [#9]

Jake,

The main game loop is a simple:

Repeat
    Update ; Render
Until somestate

Flip is done in the Render() function (using default parameter)

I am not sure if what I am using is good implementation but I went for the easiest and least complex solution at the time. I can set the 'Rate' in the Update() function which changes how fast the games 'action' takes place

GW	(Posted 2010) [#10]

I use a slightly modified version of this:
Here
It's always worked well for me.
Remember to always cap the tween value though.

Tibit

(Posted 2010) [#11]

I'm just curious, but what you specifically mean by "timing stuff"? Intended use cases?

Do you mean stuff like: Stopwatch, CountDown timer, cooldown remaining timer, Date Comparison, FPS counter, Tweening, get timestamps, get timeSince timestamp, Delta time, slowmotion effect, profiling timer or perhaps a windows-based precision-timer in micro/nanosec?

Gabriel

(Posted 2010) [#12]

I'm just curious, but what you specifically mean by "timing stuff"?

He means making your game run at the same speed on all machines as consistently and nicely as possible, with all the associated factors.

Kryzon

(Posted 2010) [#13]

Why use only one? you have to deal with the fact that some machines will try to run the game faster than it's meant to run, whilst others will run it slower.

We have frame-limitting for the former case.
We have frame-skipping*, tweening or delta-timing for the latter.

*I'm not absolutely sure about what this is, but I remember some game emulators having this feature. I guess it's a somewhat crude way to make the game run faster, by disregarding some frames (using a Continue to skip to the next logic iteration).

Last edited 2010

Grey Alien

(Posted 2010) [#14]

@Kryzon: A simple timing system is just to get your game running the same on most computers (an includes frame-limiting), a better one would take into account both the cases you mentioned, although frame-skipping is only really needed for CPU/GPU heavy games - many games simply won't need it unless.

dmaz	(Posted 2010) [#15]

here's mine with example... (I have it as a mod as well) I used this in Rocks, invaders from space and others...

SuperStrict

Framework brl.D3D7Max2D
Import BRL.Random


Graphics 640,480

Local vwait:Int
Local rate:Int = 20
Local stage:TRL = New TRL
stage.SetFrameRate(rate)	' game login updates per second
stage.ResetCounters		' now, choose a frame at the start of your project and keep that one.
				' 30 or 60 are the best.... for a game with a whole lot of ai I'd go 30.
				' my games run at 60 though and do fine even on the slowest of machines.

SetBlend ALPHABLEND
' don't put too much in this main loop, all objects should be updated in the GameUpdate callback.
While Not KeyHit(KEY_ESCAPE) Or AppTerminate()
	If KeyHit(KEY_UP) Then rate :+ 1 ; stage.SetFrameRate(rate)
	If KeyHit(KEY_DOWN) Then rate :- 1 ; stage.SetFrameRate(rate)
	If KeyHit(KEY_V) Then vwait = 1-vwait


	' 2 functions will be called back to, one that capture the old position
	' and one that performs the game update logic.
	Local tween:Double = stage.Update( TObject.CaptureAll, GameUpdate )	
	
	' draw all object with a tween value
	TObject.DrawAll tween
	

	SetAlpha 1
	DrawText "balls: "+TObject.total,10,10
	DrawText "  fps: "+stage.GetFPS(),10,20
	DrawText "  ups: "+stage.GetUPS()+" [up/down]",10,30
	DrawText "vwait: "+vwait+" [v]",10,40
	Flip vwait
	Cls
Wend

' this will be updated at the framerate set by SetFrameRate
' pass it as a callback function pointer to obj:TRL.Update
Function GameUpdate()
	
	If TObject.total < 100 Then New TObject
	TObject.UpdateAll

End Function

' your object(s)
Type TObject
	Const GRAVITY:Float = 0.2
	Const FRICTION:Float = 0.99
	
	Global list:TList = New TList
	Global total:Int
	
	Field link:TLink
	Field x:Float, ox:Float
	Field y:Float, oy:Float
	Field xvel:Float
	Field yvel:Float
	Field alpha:Float = 1		' I could tween things like alpha, size, rotataion and so on if needed.
	
	' this is a callback, make sure you pass it to obj:TRL.Update
	Function CaptureAll()
		For Local o:TObject = EachIn list
			o.Capture
		Next
	End Function
	
	' this of course is called by your GameUpdate function that is passed to obj:TRL.Update
	Function UpdateAll()
		For Local o:TObject = EachIn list
			o.Update
		Next
	End Function
	
	Function DrawAll( tween:Double )
		For Local o:TObject = EachIn list
			o.Draw tween
		Next
	End Function

	' ---------------------------------------------------------------------
	Method New()
		link = list.AddLast(Self)
		x = GraphicsWidth()/2
		y = 20
		xvel = Rnd(-8,8)
		Capture
		total :+ 1
	End Method

	Method remove()
		total :- 1
		link.Remove
	End Method

	' ---------------------------------------------------------------------

	' capture (record current value before update) whatever values you want to
	' tween.  generally x and y but you could do alpha, size, rotation.... and more
	Method Capture()
		ox = x
		oy = y		
	End Method
	
	' this update routine gets called a fixed number per second...  I like this
	' over delta time because you don't have to add weird numbers to all of your
	' values.
	Method Update()
		yvel :+ GRAVITY
		xvel :* FRICTION
		yvel :* FRICTION
		
		x :+ xvel
		y :+ yvel

		If x < 0 Or x > GraphicsWidth() Then xvel = -xvel ; x :+ xvel
		If y < 0 Or y > GraphicsHeight() Then yvel = -yvel ; y :+ yvel
		
		alpha :- .005
		If alpha < 0 Then Remove
	End Method

	' render all tweened values.
	Method Draw( tween:Double )
		SetAlpha alpha
		DrawOval GetTween(ox,x,tween),GetTween(oy,y,tween),10,10
	End Method

	' ---------------------------------------------------------------------
	Method GetTween:Double( oldValue:Double, value:Double, tween:Double )
		Return oldValue + (value-oldValue)*tween 
	End Method

End Type


' end of example program

' I will turn this into a module and post it in the code archives.
Type TRL
	Field gameFPS			:Double	= 60.0:Double
	Field framePeriod		:Double	= 1000.0:Double / gameFPS
	Field frameTime		:Double	= MilliSecs() - framePeriod

	Field gamelogicframes	:Int
	
	Rem
	bbdoc:
	about:
	end rem
	Method Update:Double( captureCallback(), updateCallback() )
		Global frameElapsed:Double
		
		Repeat
			frameElapsed = MilliSecs() - frameTime
		Until frameElapsed
		Local frameTicks:Int = frameElapsed / framePeriod
		Local frameTween:Double = Double(frameElapsed Mod framePeriod) / framePeriod

		' update game and world state
		For Local frameLimit:Int = 1 To frameTicks
			If frameLimit = frameTicks
				captureCallback()
			End If
			frameTime = frameTime + framePeriod
		
			updateCallback()
			gamelogicframes = GetGameLogicFrames()
		Next

		Return frameTween
	End Method


	Rem
	bbdoc:
	end rem
	Method SetFrameRate( gameFPS:Double )
		Self.gameFPS = gameFPS
		framePeriod = 1000.0:Double / Self.gameFPS
	End Method 


	
	Rem
	bbdoc:
	end rem
	Method GetUPS:Int()
		Return gamelogicframes
	End Method


	Rem
	bbdoc:
	end rem
	Method GetFPS:Int()
		Global counter:Int
		Global time:Int
		Global framerate:Int
	
	    counter=counter+1
	    If time=0 Then time=MilliSecs()
	    If time+1001<MilliSecs() Then
	        framerate=counter
	           counter=0
	        time=MilliSecs()
	        EndIf
	       
		Return framerate
	End Method 
	

	Rem
	bbdoc:
	end rem
	Method GetGameLogicFrames:Int()
		Global counter:Int
		Global time:Int
		Global framerate:Int
	
	    counter=counter+1
	    If time=0 Then time=MilliSecs()
	    If time+1001<MilliSecs() Then
	        framerate=counter
	           counter=0
	        time=MilliSecs()
	        EndIf
	       
		Return framerate
	End Method 	


	Rem
	bbdoc:
	end rem
	Method ResetCounters()
		framePeriod	= 1000 / gameFPS
		frameTime	= MilliSecs() - framePeriod
	End Method



End Type

Last edited 2010

Last edited 2010

Last edited 2010

siread

(Posted 2010) [#16]

This is my tipple...
http://blitzbasic.com/codearcs/codearcs.php?code=2039

Amon	(Posted 2010) [#17]

@dmaz

Is the mod available? If not may I have it, please?

dmaz	(Posted 2010) [#18]

sure, I'll get it up in a couple hours...

Last edited 2010

dmaz	(Posted 2010) [#19]

here's the mod, fully documented with an example in help.
http://www.ooeyug.com/files/dmaz.mod.zip

make sure you rebuild documentation.

Amon	(Posted 2010) [#20]

Nice one man, thanks! :)

Last edited 2010

Last edited 2010

Amon	(Posted 2010) [#21]

I have tried modifying the template TObject but I'm getting problems. First I got a StackOverflow then it complained about the Drawimage command in the Draw Method!

Can someone help fix this so I can see how all this will fit together nicely?

Oh I've added comments etc to each in the hope I'd understand it better.

[EDIT] ISSUE FIXED. I was doing something majorly wrong with TLinks.

Last edited 2010