What are Events?

BlitzMax Forums/BlitzMax Programming/What are Events?

BLaBZ

(Posted 2010) [#1]

I've heard some incredible great things about events, is there an events tutorial? A place I could find an explanation of Hooks and EventQueues and their common usage?

Thanks!

Czar Flavius

(Posted 2010) [#2]

Events are useful when your program will spend most of its time sitting around waiting for user input. For example a text editor. When the user isn't typing or clicking on a button, the text editor probably won't be doing anything either. For standard games, where action is always going on, I personally prefer the good old-fashioned game loop.

MaxGUI makes use of events - reading some tutorials for it might help you understand the concept behind events.

http://www.2dgamecreators.com/maxgui/

CS_TBL

(Posted 2010) [#3]

It's also a different way to let actions happen. Imagine one general and 10 soldiers. In the old days of code, the general would instruct all soldiers individually to attack the enemy. In the event-days, the general sends out an event called 'AttackEnemies_KThxBye' and the soldiers are programmed to react on that specific event.

Or, in concrete code, the old days:

for t=0 to 9
soldier[t].AttackEnemy
next

And in the event days:

General.InstructTroupsToAttackEnemy

After this, *if* you have soldiers waiting for this event, then they'll attack. But if there aren't any soldiers waiting (haven't trained them, or they're already dead) then nothing happens. Also, the amount of soldiers or whether their index number is consecutive, doesn't matter, whoever reacts to this event will attack. You could even program a turtle to attack, as long as it reacts to that event (and has relevant attack code) This is a specific difference between the 'hardwired' first code. With events, things get less hardwired, and in a way 'easier', more natural perhaps.

Czar Flavius

(Posted 2010) [#4]

Has anybody made an action or strategy game based around events? I'd be interested to see how that looks in concrete code.

BLaBZ

(Posted 2010) [#5]

Wow thats sounds incredible! I'm guessing hooks are created via AddHook?!

It also sounds like if you have lets say 1000 soldiers, you don't have to continually loop through their updates, just feed what happens?! So you could have a ton more units as oppose to not using events.

Would it make multiplayer a bit easier? Through networking events?

If it's not to much to ask, how would you create an object that reacts to simple event?

CS_TBL

(Posted 2010) [#6]

Well, the fun bit is that these 1000 soldiers aren't in any loop that's of your concern, they just 'are'. They manage themself, you don't have to worry about who listens when, that's all done automatically for you.

In the old days, you programmed actions. In these event days you program behaviour. And if that behaviour involves doing actions, then you have actions.

Czar Flavius

(Posted 2010) [#7]

The lack of concrete code from a working prototype should warn you that this idea is better on paper than in practice. Programming isn't magic or sentient, no matter how many tricks you add.

So you could have a ton more units as oppose to not using events.

You can hide it or make it easier to manage, but you still have to program the nitty gritty of your game somewhere. Neither method would inherently be able to support more units than the other.

Of course if you can provide me with a non-trivial working example to prove me wrong...

Last edited 2010

Last edited 2010

CS_TBL

(Posted 2010) [#8]

code+comments should be enough to get the idea..

' event example with a lame army!
'
' CS_TBL

SuperStrict
Global EVENT_ATTACK:Int=AllocUserEventId()
Global EVENT_SOLDIERDIED:Int=AllocUserEventId()

Type TSoldier
	Field life:Int=100
	Field rank:Int ' 0 puki, 1 footman, 2 archer, 3 ogre, 4 mage, 5 corporal
	Field name$
	Field legion:Int
	
	Function eventhook:Object(id:Int,data:Object,context:Object)
		If TSoldier(context) TSoldier(context).ev TEvent(data);Return data	' don't bother understanding this line, just c/p + fix
	EndFunction
	
	Method New()
		AddHook EmitEventHook,eventhook,Self
	End Method
	
	Method Free()
		RemoveHook EmitEventHook,eventhook; GCCollect()
	End Method
	
	Method ev(event:TEvent)
		If life>0 ' am I still alive?
			If event.id=EVENT_ATTACK ' attack order?
				If event.x=legion ' my legion?
					If event.y=rank ' my rank?
						If Attack()=0 ' soldier attacks, but did he.. die??
							Local e:TEvent=New TEvent ' oh dear..
							e.id=EVENT_SOLDIERDIED
							EmitEvent e ' send msg to the general
							e=Null
						EndIf
					EndIf
				EndIf
			EndIf
		EndIf
	End Method
	
	Method Attack:Int()
		Print name+" (rank: "+rank+", legion: "+legion+") says: ~q"+Mid(..
		"OMFG DIE!   "+..
		"Take this!  "+..
		"Kiss my Ass!"+..
		"Feel my axe!"+..
		"Puppypowah!!",+..
		1+Int(Rnd(4))*12,12)+"~q [life: "+life+"]"
		
		life:-Rnd(50)
		
		If life>0 Return 1 ' if we're not dead, return a 1 so that the general knows this particular soldier is still alive
		Return 0
	End Method
	
	Method Identify()
		Print "Name  : "+name
		Print "Legion: "+legion
		Print "Rank  : "+rank
		Print "Life  : "+life
		Print "--------------------"
	End Method
End Type

Function CreateSoldier:TSoldier(rank:Int=0,name$="Garfield",legion:Int=1337)
	Local a:TSoldier=New TSoldier
	a.rank=rank
	a.name=name
	a.legion=legion
	Return a
End Function

Function GimmeName$()
	Local n$="Andy Bert Claude Denny Ernie Frank Gerard Hank Inky Jack Kraken Leonard Manly Neo Ottman Pooki Quint Randy Sandy Trevor Uma Victor Wendy Mr.X Yasmin Zack"
	Local name$[]=n.split(" ")
	Return name[Rnd(Len(name))]
End Function

Function Conclusion()
	Print
	Print
	Print "**************************************************************************"
	Print "* Your army died, you are an epic faillure of a general. Bah, humbug you! *"
	Print "**************************************************************************"
End Function




' let's form an army here
Local totalsoldiers:Int=8
Local soldier:TSoldier[totalsoldiers]
For Local t:Int=0 To totalsoldiers-1
	soldier[t]=CreateSoldier(Rnd(5),GimmeName(),Rnd(3))
Next
' soldier[] contains your soldiers
' note how the code below *no where* referrs to this array! It's there, it manages itself whether you do something or not



' here be your game
Local e:TEvent=New TEvent
Local timer:ttimer=CreateTimer(6) ' pick a lower number if you want to see less fast scrolling

OnEnd Conclusion

Repeat
	WaitEvent()
	
	If EventID()=EVENT_SOLDIERDIED
		totalsoldiers:-1
		If totalsoldiers<1 End
	EndIf
	If EventID()=event_timertick ' select a legion and a rank, and let them attack!
		e.id=EVENT_ATTACK
		e.x=Rnd(3) ' pick a legion - it could be that no one will be selected!
		e.y=Rnd(5) ' pick a rank - it could be that no one will be selected!
		EmitEvent e
		Print "======================="
		Print "Soldiers left: "+totalsoldiers
		Print "=======================~n"
	EndIf
Forever

Last edited 2010

BLaBZ

(Posted 2010) [#9]

haha love the dialog

This is an awesome example and exactly what I was looking for, thanks so much!