Going crazy over here...

BlitzMax Forums/BlitzMax Programming/Going crazy over here...

SLotman

(Posted 2010) [#1]

I'm trying to reproduce B3D 'entity' system (with parent-child assignments) in 2D for BlitzMax - but something is wrong, and I can't wrap my head around it to find the solution!

This is what I have:

Type fwEntity
	Field childList:TList
	Field x#,y#,z#
	Field angle#
	Field parent:fwEntity
	
	Field radius#
	Field colMethod%
	
	Method New()
		childList = CreateList()
		parent = Null
	End Method

	Method SetParent(p:fwEntity)
		If parent<>Null And p=Null Then
		   ' new parent is 'Null' (which means no parent)
		   ' remove this entity from ChildList
		   ListRemove parent.childList, Self
		End If
		
		' set new parent
		parent = p
		
		' add this entity on parent's child list
		If p<>Null Then ListAddLast parent.childList, Self
	End Method

	Method Translate(fx#, fy#, fz#, iGlobal%=True)
		If iGlobal Or parent=Null Then
			x:+fx
			y:+fy
			z:+fz
		Else
			' // translate relative to parent???
		End If

		' // also translate children if any
		If childList.IsEmpty()<>True Then 			
			For Local fwe:fwEntity = EachIn childList
				fwe.Translate fx,fy,fz
			Next	
		End If

	End Method

	Method Position(fx#, fy#, fz#, iGlobal%=True)
	Local oldX#=x, oldY#=y, oldZ#=z
	
		If iGlobal Or parent=Null Then
			x = fx
			y = fy
			z = fz
		Else
			If parent<>Null Then
			   ' translate
			   x=(parent.x + fx)
			   y=(parent.y + fy)
			   z=(parent.z + fz)
			End If
		End If
		
		' update children
		If childList.IsEmpty()<>True Then 			
			For Local fwe:fwEntity = EachIn childList
				fwe.translate x - oldx, y - oldy, z - oldz
			Next	
		End If
	End Method

	Method Turn(turnAngle#)
	Local oldAngle# = angle
		
		angle:+turnAngle		
		
		' update children
		If childList.IsEmpty()<>True Then 			
		
			For Local fwe:fwEntity = EachIn childList		
				
				Local dx# = fwe.x - x
				Local dy# = fwe.y - y
				
				Local dist# = Sqr(dx*dx+dy*dy)
				
				fwe.position x + Cos(angle) * dist, y + Sin(angle) * dist, 0

				fwe.angle:+turnAngle
			Next	
		End If
	End Method

End Type

Graphics 800,600

Local e1:fwEntity = New fwEntity
Local e2:fwEntity = New fwEntity

	e1.Position 400,300,0
	
	e2.setParent(e1)
	e2.Position -50, 50,0,False

	While Not KeyHit(KEY_ESCAPE)	
		Cls
		
		SetRotation e1.angle
		SetColor 255,255,255
		DrawRect e1.x, e1.y, 20, 20
		
		SetRotation e2.angle
		SetColor 255,0,0
		DrawRect e2.x, e2.y, 20, 20
		
		SetRotation 0
		SetColor 255,255,255
		DrawText "Hold [SPACE] to turn it", 10,10
		Flip 
		
		If KeyDown(KEY_SPACE) Then e1.turn 1
	Wend

End

So when I turn one object, it's child should turn also, and it's position should be also updated, to keep the original distance from it's parent.

This B3D code shows how it should behave:

Graphics3D 800,600,0,2


cam=CreateCamera()
MoveEntity cam,0,0,-10
CameraProjMode cam, 2

cube1=CreateCube()
cube2=CreateCube(cube1)
MoveEntity cube2, -4,-4,0

ScaleEntity cube1, 0.1,0.1,0.1

While Not KeyHit(1)

	Cls
	RenderWorld
	Text 10,10,"Hold [SPACE] to turn it"
	Flip
	
	If KeyDown(57) Then TurnEntity cube1, 0, 0, -1
Wend

End

Does anyone know how to correct calculate the child position? I'm completely lost here...

Jesse

(Posted 2010) [#2]

can you post running b3d code. I don't own it so I can't tell what you are doing different. I know there are a couple of issues with your code which I believe I resolved but I could be wrong:

Type fwEntity
	Field childList:TList
	Field x#,y#,z#
	Field angle#
	Field parent:fwEntity
	
	Field radius#
	Field colMethod%

	Method New()
		childList = CreateList()
		parent = Null
	End Method

	Method SetParent(p:fwEntity) '*******************************modified 
		' set new parent
		If p <> Null
			parent = p
			'add this entity on parent's child list
			ListAddLast p.childList, Self
		EndIf
	End Method

	Method Translate(fx#, fy#, fz#, iGlobal%=True)
		If iGlobal Or parent=Null Then
			x:+fx
			y:+fy
			z:+fz
		Else
			' // translate relative to parent???
		End If

		' // also translate children if any
		If childList.IsEmpty()<>True Then 			
			For Local fwe:fwEntity = EachIn childList
				fwe.Translate fx,fy,fz
			Next	
		End If

	End Method
	
	Method Position(fx#, fy#, fz#, iGlobal%=True)
		Local oldX#=x, oldY#=y, oldZ#=z
	
		If iGlobal Or parent=Null Then
			x = fx
			y = fy
			z = fz
		Else
			If parent<>Null Then
			   ' translate
			   x=(parent.x + fx)
			   y=(parent.y + fy)
			   z=(parent.z + fz)
			End If
		End If
		
		' update children
		If childList.IsEmpty()<>True Then 			
			For Local fwe:fwEntity = EachIn childList
				fwe.translate x - oldx, y - oldy, z - oldz
			Next	
		End If
	End Method

	Method Turn(turnAngle#)
		angle:+turnAngle		
		
		' update children
		If childList.IsEmpty()<>True Then 			
		
			For Local fwe:fwEntity = EachIn childList		
				
				Local dx# = fwe.x - x
				Local dy# = fwe.y - y
				Local ang# = ATan2(dy,dx)'*****************************************************
				Local dist# = Sqr(dx*dx+dy*dy)

				fwe.position x + Cos(turnAngle+ang) * dist, y + Sin(turnAngle+ang) * dist, 0

				fwe.turn(turnAngle) '*********************************************************
			Next	
		End If
	End Method

End Type

Graphics 800,600

Local e1:fwEntity =New  fwEntity
Local e2:fwEntity =New  fwEntity
Local e3:fwEntity =New  fwEntity	
	e1.Position 400,300,0
	e2.setParent(e1)	
	e2.Position -50, 50,0,False
	e3.setParent(e2)
	e3.position 25, 25,0,False


	While Not KeyHit(KEY_ESCAPE)	
		Cls
		
		SetRotation e1.angle
		SetColor 255,255,255
		DrawRect e1.x, e1.y, 20, 20
		
		SetRotation e2.angle
		SetColor 255,0,0
		DrawRect e2.x, e2.y, 20, 20

		SetRotation e3.angle
		SetColor 0,255,0
		DrawRect e3.x, e3.y, 20, 20
		
		SetRotation 0
		SetColor 255,255,255
		DrawText "Hold [SPACE] to turn it", 10,10
		Flip 
		
		If KeyDown(KEY_SPACE) Then e1.turn 1
	Wend

End

SLotman

(Posted 2010) [#3]

Yes, that did it! Thank you so much!!!!

I just didn't change SetParent function - I want "SetParent null" to remove the entity parent ;)

Once again, thank you!

Jesse

(Posted 2010) [#4]

you are welcome.

I just didn't change SetParent function - I want "SetParent null" to remove the entity parent ;)

I didn't quite understand that part when I first looked at the code so I just changed it to something that made sense to me but now I get it.

I like the code. I am going to integrate it in my code and use it for examples and demos if its OK with you.

SLotman

(Posted 2010) [#5]

Sure, go ahead :)