10mb memory?

BlitzMax Forums/BlitzMax Programming/10mb memory?

Pineapple

(Posted 2010) [#1]

I'm writing a program I intend to use basically as a shortcut dock to run in the background when I'm programming to have all my utilities well organized and easy to execute on-the-fly. I want to keep it running in the background, so the program grids almost to a halt when the window is inactive.

When I build this code, it takes up 10mb of memory according to the task manager. Why is this so high when it's doing absolutely nothing?

'This file was edited with BLIde


SuperStrict

Framework brl.glmax2d
Import brl.random
'Import brl.GLGraphics
'Import brl.linkedlist
Import brl.retro


Global gw% = 120
Global gh% = 480



Type item
	Global root:TList = CreateList()

	Global lineh% = 16
	
	Global lmb%
	Global rmb%
	Global zmod%, lastmz% = MouseZ()
	Global mx%, my%
	
	Global remove:item

	Field name$
	Field path$
	Field icon$
	Field iconimg:TImage
	
	Field children:TList = CreateList()
	Field parent:item
	Field folded% = 0
	Field hidden% = 0
	
	Function Create:item(name$, path$, icon$, screen$)
		Local g:item = New item
		g.name = name
		g.path = path
		g.icon = icon
		'g.screen = screen
		Return g
	End Function
	
	Method Show%(x%, y%, active%)
		If hidden Return 0
		Local this:item = Self
		Local parents% = 0
		
		Repeat
			If this.parent
				If this.folded Return 0
				parents:+1
				this = this.parent
			Else
				Exit
			End If
		Forever
		
		Local disp$ = ""
		Local exists% = (FileType(path) = 1)
		
		If my >= y And my < y + lineh - 1 And active Then
			If lmb Activate
			If rmb remove = Self
			
			If exists
				SetColor 156, 160, 172
				DrawRect x, y, gw - x, lineh
			End If
			
		EndIf	
		
		SetColor 0, 0, 0
		If exists SetColor 64, 64, 64
		Local kids% = (children.Count() > 0)
		If kids Then
			disp = "+ "
			If folded Then disp = "- "
		EndIf
		If parents > 0
			For Local indent% = 1 To parents
				disp = "  " + disp
			Next
		EndIf
		DrawText disp, x, y	
	End Method
	
	Method Activate()
		If Not AppSuspended()
			If FileType(path) = 2 Then OpenURL path
			folded = Not folded
		EndIf
	End Method
	
	Function DoMouse()
		mx = MouseX()
		my = MouseY()
		lmb = MouseHit(1)
		rmb = MouseHit(2)
		Local nowz% = MouseZ()
		If Not (mx < 2 Or my < 2 Or mx > gh - 3 Or my > gh - 3 Or AppSuspended())
			If nowz > lastmz zmod:+1
			If nowz < lastmz zmod:-1
		EndIf
		lastmz = nowz
	End Function
	
	Function Draw(x%, y%, lines%, scroll%, active%)
		Local reached% = 0, yoff% = 0
		For Local i:item = EachIn root
			If reached >= scroll Then
				Local drew% = i.show(x, y + yoff * lineh, (remove = Null) & active )
				yoff:+drew
				If yoff + 1 >= lines Then Return
			Else
				reached:+1
			End If
		Next
		If remove Then
			SetColor 190, 200, 224
			DrawRect 12, gh / 2 - 18, gw - 24, 36
			SetColor 0, 0, 0
			Local txt$ = "Really delete item"
			DrawText txt, gw / 2 - TextWidth(txt) / 2, gh / 2 - 16
			txt$ = remove.name
			DrawText txt, gw / 2 - TextWidth(txt) / 2, gh / 2 - 16 + lineh
			txt$ = "and all its children"
			DrawText txt, gw / 2 - TextWidth(txt) / 2, gh / 2 - 16 + lineh * 2
			txt$ = "from the list?"
			DrawText txt, gw / 2 - TextWidth(txt) / 2, gh / 2 - 16 + lineh * 3
		End If
	End Function
End Type



Global ok:button = button.Create("Ok", gw / 2 - 12 - 32, gh / 2 + 16, 32, item.lineh + 4, 1)
Global cancel:button = button.Create("No", gw / 2 + 12, gh / 2 + 16, 32, item.lineh + 4, 1)

Type button
	Global list:TList = CreateList()

	Field name$
	Field x%, y%, w%, h%
	Field state%
	Field hidden% = 0
	
	Const DORMANT@ = 0
	Const MOUSEOVER@ = 1
	Const PRESSED@ = 2

	Function Create:button(name$, x%, y%, w%, h%, hide% = 0)
		Local b:button = New button
		b.name = name
		b.x = x; b.y = y
		b.w = w; b.h = h
		b.hidden = hide
		list.AddLast b
		Return b
	End Function
	Function Update()
		For Local b:button = EachIn list
			If b.hidden = 0 Then
				SetColor 0, 0, 0
				DrawRect b.x, b.y, b.w, b.h
				SetColor 198, 206, 224
				DrawRect b.x + 1, b.y + 1, b.w - 2, b.h - 2
				SetColor 24, 24, 24
				DrawText b.name, b.x + b.w / 2 - TextWidth(b.name) / 2, b.y + b.h / 2 - TextHeight(b.name) / 2 + 1
				b.state = DORMANT
				If item.mx >= b.x And item.mx < b.x + b.w And item.my >= b.y And item.my <= b.y + b.h b.state = MOUSEOVER
				If b.state = MOUSEOVER And item.lmb Then b.state = PRESSED
			EndIf
		Next
	End Function
End Type




Graphics gw, gh
SetClsColor 202, 208, 224




Global scroll% = 0

Global adding% = 0

Global boxh% = gh / item.lineh - 2

Global add:button = button.Create("Add new", 8, boxh * item.lineh + 4, gw - 16, gh - boxh * item.lineh - 8)

'main loop
Repeat
	Local go% = Not AppSuspended()
	If go
		Cls
		item.domouse
		SetColor 182, 186, 194
		DrawRect 0, 0, gw, boxh * item.lineh
		button.update
		scroll:+item.zmod
		item.Draw 0, 0, boxh, scroll, Not adding
		
		If add.state = button.PRESSED Then adding = 1; item.remove = Null
		
		If adding Then
			ok.hidden = 0; cancel.hidden = 0
			
			SetColor 190, 200, 224
			DrawRect 12, gh / 2 - 18, gw - 24, 36
			SetColor 0, 0, 0
			Local txt$ = "Create new item"
			DrawText txt, gw / 2 - TextWidth(txt) / 2, gh / 2 - 16
			txt$ = item.remove.name
			DrawText txt, gw / 2 - TextWidth(txt) / 2, gh / 2 - 16 + item.lineh
			txt$ = "and all its children"
			DrawText txt, gw / 2 - TextWidth(txt) / 2, gh / 2 - 16 + item.lineh * 2
			txt$ = "from the list?"
			DrawText txt, gw / 2 - TextWidth(txt) / 2, gh / 2 - 16 + item.lineh * 3
			
		Else
			If Not item.remove ok.hidden = 1; cancel.hidden = 1
		EndIf
		
		If KeyDown(27) Then End
	Else
		Delay 250
	EndIf
	Flip
	If AppTerminate() Then End
Forever

Thareh

(Posted 2010) [#2]

My guess is that the libraries you imported (brl.glmax2d, brl.random & brl.retro) is using those 10 megabytes of memory.

Pineapple

(Posted 2010) [#3]

Is there any way to reduce this?

Brucey

(Posted 2010) [#4]

I don't think it is much to be concerned about.

Czar Flavius

(Posted 2010) [#5]

My webcam's hiddenware uses 50mb even when my cam isn't plugged in. 10mb is nothing to worry about.

Zeke	(Posted 2010) [#6]

open task manager and run this:

Framework brl.hook 'change this
Delay 5000

and look how much memory each module use...
^^ change framework module then you can see how much memory module take

my byrathon takes about 100-200 mb...and its fine for me....

Grisu

(Posted 2010) [#7]

I think Glmax2d is a memory hook here.

Perhaps plain MAXGUI would be better for this kind of app. - Even my bloated radio player stays under 10 MB. :)