SetVirtualResolution With Aspect Correction?

BlitzMax Forums/BlitzMax Programming/SetVirtualResolution With Aspect Correction?

CyBeRGoth

(Posted 2010) [#1]

Hi

It has been a while since I checked but has anyone come up with a soloution for using SetVirtualResolution with aspect correction.

For example creating your game to work widescreen at say 1280 x 800, then using SetVirtualResolution to allow people with non-widescreen monitors to play the game at 800 x 600 with black borders at the top/bottom of their screen?

ima747

(Posted 2010) [#2]

I don't know much about virtual resolution so apologies if this is off track. I think you could use SetViewPort to create the resolution frame... would probably have to have an offset as well to have it centered, but SetOrigin() should cover that...

Perhaps there's some catch with virtual resolution I'm unaware of.

MGE	(Posted 2010) [#3]

I thought for sure this would have been added in the latest fix. Maybe the next one if we all beg Mark? Please?

BlitzSupport

(Posted 2010) [#4]

Me too!

Russell

(Posted 2010) [#5]

I just use SetOrigin() and use the x and y offsets as the parameters. For example, if your game is developed in 1280 x 720 (a nice 16:9 ratio), but the user has a 4:3 display (likely!), then you can set the actual display to, say, 1280 x 960 and SetOrigin would be SetOrigin(0,120). {120 is half of the difference between 960 and 720}.

SetVirtualResolution() is awesome, except that depending on how far the display has to be stretched (the backbuffer is scaled to the actual display when you flip(), I'm guessing) the resulting graphics can be a little fuzzy. (You'll notice this fuzziness in other programs, too, like MAME in fullscreen mode).

If you use the SetOrigin method, keep in mind that this only affects drawing operations. SetViewPort(), for example, will have to take this into account by adding the x offset and y offset to the x/y parameters. The payoff is that the display is much cleaner.

Automatic letterboxing/pillarboxing would be nice, but this is easily done.

Russell

Oddball

(Posted 2010) [#6]

You mean something like this?

'Code: David 'Oddball' Williamson
'6th May 2010
'Enjoy!

SuperStrict

Const ASPECT_STRETCH:Int=0
Const ASPECT_LETTERBOX_FILL:Int=2
Const ASPECT_LETTERBOX_BORDER:Int=3
Const ASPECT_BESTFIT_FILL:Int=4
Const ASPECT_BESTFIT_BORDER:Int=5	'Bestfit border may not work with all drivers(i.e. DirectX)

Private

Global _xoffset:Float
Global _yoffset:Float
Global _vwidth:Float
Global _vheight:Float
Global _mode:Int=0
Global _bred:Int=0
Global _bgreen:Int=0
Global _bblue:Int=0

Public

Function SetVirtualResolution( width:Float, height:Float, mode:Int=ASPECT_STRETCH )
	If mode=ASPECT_STRETCH
		_xoffset=0;_yoffset=0;_vwidth=width;_vheight=height;_mode=mode
		brl.max2d.SetVirtualResolution(width,height)
		brl.max2d.SetViewport _xoffset,_yoffset,_vwidth,_vheight
		brl.max2d.SetOrigin _xoffset,_yoffset
		Return
	EndIf
	Local gwidth:Int=GraphicsWidth()
	Local gheight:Int=GraphicsHeight()
	_vwidth=width
	_vheight=height
	_mode=mode
	Local wratio:Float=gwidth/_vwidth
	Local hratio:Float=gheight/_vheight
	If wratio<hratio Then hratio=wratio
	If _mode&4
		hratio=Floor(hratio)
		hratio=Max(hratio,1)
	EndIf
	height=gheight/hratio
	width=gwidth/hratio
	
	_xoffset=(width-_vwidth)*.5
	_yoffset=(height-_vheight)*.5
	If _mode&4
		_xoffset=Floor(_xoffset)
		_yoffset=Floor(_yoffset)
	EndIf
	brl.max2d.SetVirtualResolution(width,height)
	
	If _mode&1
		Local red:Int,green:Int,blue:Int
		GetClsColor red,green,blue
		SetClsColor _bred,_bgreen,_bblue
		Cls
		SetClsColor red,green,blue
		brl.max2d.SetViewport _xoffset,_yoffset,_vwidth,_vheight
	Else
		brl.max2d.SetViewport 0,0,brl.max2d.VirtualResolutionWidth(),brl.max2d.VirtualResolutionHeight()
	EndIf
	
	brl.max2d.SetOrigin _xoffset,_yoffset
	
End Function

Function SetBorderColor( red:Int, green:Int, blue:Int )
	_bred=red
	_bgreen=green
	_bblue=blue
End Function

Function SwitchAspectMode( mode:Int )
	SetVirtualResolution _vwidth,_vheight,mode
End Function

Function Flip( sync:Int=-1 )
	brl.Graphics.Flip sync
	If _mode&1
		brl.max2d.SetViewport 0,0,brl.max2d.VirtualResolutionWidth(),brl.max2d.VirtualResolutionHeight()
		Local red:Int,green:Int,blue:Int
		GetClsColor red,green,blue
		SetClsColor _bred,_bgreen,_bblue
		Cls
		SetClsColor red,green,blue
		brl.max2d.SetViewport _xoffset,_yoffset,_vwidth,_vheight
	EndIf
End Function

Function SetOrigin( x:Float, y:Float )
	brl.max2d.SetOrigin x+_xoffset,y+_yoffset
End Function

Function GetOrigin( x:Float Var, y:Float Var )
	brl.max2d.GetOrigin x,y
	x:-_xoffset
	y:-_yoffset
End Function

Function SetViewport( x:Int, y:Int, width:Int, height:Int )
	Local x2:Float=Min(x+width,_xoffset+_vwidth)
	Local y2:Float=Min(y+height,_yoffset+_vheight)
	x=Max(x,_xoffset)
	y=Max(y,_yoffset)
	brl.max2d.SetViewport x,y,x2-x,y2-y
End Function

Function GetViewport( x:Int Var,y:Int Var,width:Int Var,height:Int Var )
	brl.max2d.GetViewport x,y,width,height
	x:-_xoffset
	y:-_yoffset
End Function

Function VirtualMouseX:Float()
	Return brl.max2d.VirtualMouseX()-_xoffset
End Function

Function VirtualMouseY:Float()
	Return brl.max2d.VirtualMouseY()-_yoffset
End Function

Function VirtualResolutionWidth:Float()
	Return _vwidth
End Function

Function VirtualResolutionHeight:Float()
	Return _vheight
End Function

'-----------------------
'Test code
'-----------------------
SeedRnd MilliSecs()
Graphics Rand(320,DesktopWidth()),Rand(240,DesktopHeight())

SetBorderColor 32,32,32
SetClsColor 223,223,223
SetColor 255,127,0

SetVirtualResolution 320,240,ASPECT_LETTERBOX_BORDER

Repeat
	If KeyHit(KEY_1) Then SwitchAspectMode ASPECT_STRETCH
	If KeyHit(KEY_2) Then SwitchAspectMode ASPECT_LETTERBOX_FILL
	If KeyHit(KEY_3) Then SwitchAspectMode ASPECT_LETTERBOX_BORDER
	If KeyHit(KEY_4) Then SwitchAspectMode ASPECT_BESTFIT_FILL
	If KeyHit(KEY_5) Then SwitchAspectMode ASPECT_BESTFIT_BORDER
	Cls
	DrawText "Aspect correction demo",5,5
	DrawText VirtualMouseX()+","+VirtualMouseY(),VirtualMouseX(),VirtualMouseY()
	Flip
Until KeyHit(KEY_ESCAPE)

I literally just spewed the code into the ide so haven't tested it that much. Let me know if anything needs correcting or adding.

EDIT: Just corrected a couple of bugs.

Enjoy!

CyBeRGoth

(Posted 2010) [#7]

Cheers guys and thanks to oddball for the code, that is some nice stuff and does exactly what we need :)

I am just wondering now though if creating a game that is developed from the ground up to be played at a 16:9 aspect is a good idea, seeing as we mostly make casual games, do the people who buy casual games generally have access to widescreen?

I know the steam statistics thing released a while ago suggested that a lot of people do use 16:9, on steam, but then casual buyers tend not to be hardcore like a lot of people who play stuff on steam.

Anyhoo just rambling, thanks again for the soloution :)

therevills

(Posted 2010) [#8]

For the past casual games Ive made Ive stuck with 800 x 600 (although I did do Gunslinger originally as 1024 x 768) as most casual games do this res...

@Oddball, nice code there - my only issue is that you are using SetViewport and there have been reported problems with this...

GfK	(Posted 2010) [#9]

I am just wondering now though if creating a game that is developed from the ground up to be played at a 16:9 aspect is a good idea, seeing as we mostly make casual games, do the people who buy casual games generally have access to widescreen?

Widescreen is probably the de-facto standard now, although 16:10 (or 8:5, if you like) is more common than 16:9 as far as computer resolutions are concerned.

That said, I still code for 4:3 as there is still a not insignificant number of 4:3 monitors out there.

Oddball

(Posted 2010) [#10]

On the subject of which ratio to target when developing I always go for 16:9 so that on almost all other shape monitors it'll black band at the top and bottom, which most casual gamers are already used to seeing on films.

therevills wrote:

@Oddball, nice code there - my only issue is that you are using SetViewport and there have been reported problems with this...

The only issue that should occur with this is when using ASPECT_BESTFIT_BORDER and DirectX as it sometimes does not clip two of the sides. All other modes should be fine and work consistently across all systems. If I get a little time I might convert this into a module and also a module tweak for Max2D.

Oddball

(Posted 2010) [#11]

Sorry to double post, but I made this into a module for those that find them more convenient.

>>Get it here<<

Enjoy!

therevills

(Posted 2010) [#12]

work consistently across all systems

I was under the impression that the SetViewPort commands doesnt work consistently across all graphics cards - esp old ones and the on-board intels ones...

OT: Can you remind how your "IF" statements are working:

If _mode&4

Thanks!

Oddball

(Posted 2010) [#13]

SetViewport works on every machine I've tested it on in both DirectX and OpenGL, but I have been told that it only clips two sides when using DirectX on some machines. I have no reason to suspect they are lying hence my proviso on best fit with borders. The code is there so feel free to test it on any machine you can get your hands on. I'd certainly be interested to know how widespread this issue is. Either way only the two bordered modes use SetViewport if you feel this is an issue stick with the other modes and draw your own borders just before flipping.

That if statement is merely performing a bit flag test on the third bit of _mode. The best fit constants both have the third bit on and both bordered modes have the first bit set to on. The code just tests the individual bit to see if it is set. So _mode&4 is true if _mode is either of the best fit modes and _mode&1 is true if it is either of the bordered modes.

MGE	(Posted 2010) [#14]

SetViewPort is not something you should rely on in a commercial game, according to everything I've read on it at least.

Grafos

(Posted 2010) [#15]

I had problems with setviewport on the DX7 drivers, but it seems to work great with the dx9 one on my machnine

Chapman7

(Posted 2016) [#16]

Sorry for bringing back an old thread but I am trying to get this to work with MaxGUI and I am having some issues with it...

'Code: David 'Oddball' Williamson
'6th May 2010
'Enjoy!

SuperStrict

Import MaxGUI.Drivers

Const ASPECT_STRETCH:Int=0
Const ASPECT_LETTERBOX_FILL:Int=2
Const ASPECT_LETTERBOX_BORDER:Int=3
Const ASPECT_BESTFIT_FILL:Int=4
Const ASPECT_BESTFIT_BORDER:Int=5	'Bestfit border may not work with all drivers(i.e. DirectX)

Private

Global _xoffset:Float
Global _yoffset:Float
Global _vwidth:Float
Global _vheight:Float
Global _mode:Int=0
Global _bred:Int=0
Global _bgreen:Int=0
Global _bblue:Int=0

Public

Function SetVirtualResolution( width:Float, height:Float, mode:Int=ASPECT_STRETCH )
	If mode=ASPECT_STRETCH
		_xoffset=0;_yoffset=0;_vwidth=width;_vheight=height;_mode=mode
		brl.max2d.SetVirtualResolution(width,height)
		brl.max2d.SetViewport _xoffset,_yoffset,_vwidth,_vheight
		brl.max2d.SetOrigin _xoffset,_yoffset
		Return
	EndIf
	Local gwidth:Int=GraphicsWidth()
	Local gheight:Int=GraphicsHeight()
	_vwidth=width
	_vheight=height
	_mode=mode
	Local wratio:Float=gwidth/_vwidth
	Local hratio:Float=gheight/_vheight
	If wratio<hratio Then hratio=wratio
	If _mode&4
		hratio=Floor(hratio)
		hratio=Max(hratio,1)
	EndIf
	height=gheight/hratio
	width=gwidth/hratio
	
	_xoffset=(width-_vwidth)*.5
	_yoffset=(height-_vheight)*.5
	If _mode&4
		_xoffset=Floor(_xoffset)
		_yoffset=Floor(_yoffset)
	EndIf
	brl.max2d.SetVirtualResolution(width,height)
	
	If _mode&1
		Local red:Int,green:Int,blue:Int
		GetClsColor red,green,blue
		SetClsColor _bred,_bgreen,_bblue
		Cls
		SetClsColor red,green,blue
		brl.max2d.SetViewport _xoffset,_yoffset,_vwidth,_vheight
	Else
		brl.max2d.SetViewport 0,0,brl.max2d.VirtualResolutionWidth(),brl.max2d.VirtualResolutionHeight()
	EndIf
	
	brl.max2d.SetOrigin _xoffset,_yoffset
	
End Function

Function SetBorderColor( red:Int, green:Int, blue:Int )
	_bred=red
	_bgreen=green
	_bblue=blue
End Function

Function SwitchAspectMode( mode:Int )
	SetVirtualResolution _vwidth,_vheight,mode
End Function

Function Flip( sync:Int=-1 )
	brl.Graphics.Flip sync
	If _mode&1
		brl.max2d.SetViewport 0,0,brl.max2d.VirtualResolutionWidth(),brl.max2d.VirtualResolutionHeight()
		Local red:Int,green:Int,blue:Int
		GetClsColor red,green,blue
		SetClsColor _bred,_bgreen,_bblue
		Cls
		SetClsColor red,green,blue
		brl.max2d.SetViewport _xoffset,_yoffset,_vwidth,_vheight
	EndIf
End Function

Function SetOrigin( x:Float, y:Float )
	brl.max2d.SetOrigin x+_xoffset,y+_yoffset
End Function

Function GetOrigin( x:Float Var, y:Float Var )
	brl.max2d.GetOrigin x,y
	x:-_xoffset
	y:-_yoffset
End Function

Function SetViewport( x:Int, y:Int, width:Int, height:Int )
	Local x2:Float=Min(x+width,_xoffset+_vwidth)
	Local y2:Float=Min(y+height,_yoffset+_vheight)
	x=Max(x,_xoffset)
	y=Max(y,_yoffset)
	brl.max2d.SetViewport x,y,x2-x,y2-y
End Function

Function GetViewport( x:Int Var,y:Int Var,width:Int Var,height:Int Var )
	brl.max2d.GetViewport x,y,width,height
	x:-_xoffset
	y:-_yoffset
End Function

Function VirtualMouseX:Float()
	Return brl.max2d.VirtualMouseX()-_xoffset
End Function

Function VirtualMouseY:Float()
	Return brl.max2d.VirtualMouseY()-_yoffset
End Function

Function VirtualResolutionWidth:Float()
	Return _vwidth
End Function

Function VirtualResolutionHeight:Float()
	Return _vheight
End Function

'-----------------------
'Test code
'-----------------------
SeedRnd MilliSecs()
'Graphics Rand(320,DesktopWidth()),Rand(240,DesktopHeight())

Local Window:TGadget = CreateWindow("Test", 0, 0, Rand(320,DesktopWidth()), Rand(240,DesktopHeight()), Null, WINDOW_DEFAULT|WINDOW_CENTER)
Local canvas:TGadget = CreateCanvas(0, 0, ClientWidth(Window), ClientHeight(Window), Window)

CreateTimer 60
SetGraphics CanvasGraphics(canvas)


SetBorderColor 32,32,32
SetClsColor 223,223,223
SetColor 255,127,0

SetVirtualResolution 320,240,ASPECT_LETTERBOX_BORDER


While WaitEvent()
	Select EventID()
		Case EVENT_TIMERTICK
			RedrawGadget canvas
		Case EVENT_GADGETPAINT
			SetGraphics CanvasGraphics(canvas)
			Cls
			DrawText "Aspect correction demo",5,5
			DrawText VirtualMouseX()+","+VirtualMouseY(),VirtualMouseX(),VirtualMouseY()
			Flip
	EndSelect
	
	If KeyHit(KEY_1) Then SwitchAspectMode ASPECT_STRETCH
	If KeyHit(KEY_2) Then SwitchAspectMode ASPECT_LETTERBOX_FILL
	If KeyHit(KEY_3) Then SwitchAspectMode ASPECT_LETTERBOX_BORDER
	If KeyHit(KEY_4) Then SwitchAspectMode ASPECT_BESTFIT_FILL
	If KeyHit(KEY_5) Then SwitchAspectMode ASPECT_BESTFIT_BORDER
Wend

any idea?

Chapman7

(Posted 2016) [#17]

I got it

'Code: David 'Oddball' Williamson
'6th May 2010
'Enjoy!

SuperStrict

Import MaxGUI.Drivers

Const ASPECT_STRETCH:Int=0
Const ASPECT_LETTERBOX_FILL:Int=2
Const ASPECT_LETTERBOX_BORDER:Int=3
Const ASPECT_BESTFIT_FILL:Int=4
Const ASPECT_BESTFIT_BORDER:Int=5	'Bestfit border may not work with all drivers(i.e. DirectX)

Local ModeSet:Int = 3

Private

Global _xoffset:Float
Global _yoffset:Float
Global _vwidth:Float
Global _vheight:Float
Global _mode:Int=0
Global _bred:Int=0
Global _bgreen:Int=0
Global _bblue:Int=0

Public

Function SetVirtualResolution( width:Float, height:Float, mode:Int=ASPECT_STRETCH )
	If mode=ASPECT_STRETCH
		_xoffset=0;_yoffset=0;_vwidth=width;_vheight=height;_mode=mode
		brl.max2d.SetVirtualResolution(width,height)
		brl.max2d.SetViewport _xoffset,_yoffset,_vwidth,_vheight
		brl.max2d.SetOrigin _xoffset,_yoffset
		Return
	EndIf
	Local gwidth:Int=GraphicsWidth()
	Local gheight:Int=GraphicsHeight()
	_vwidth=width
	_vheight=height
	_mode=mode
	Local wratio:Float=gwidth/_vwidth
	Local hratio:Float=gheight/_vheight
	If wratio<hratio Then hratio=wratio
	If _mode&4
		hratio=Floor(hratio)
		hratio=Max(hratio,1)
	EndIf
	height=gheight/hratio
	width=gwidth/hratio
	
	_xoffset=(width-_vwidth)*.5
	_yoffset=(height-_vheight)*.5
	If _mode&4
		_xoffset=Floor(_xoffset)
		_yoffset=Floor(_yoffset)
	EndIf
	brl.max2d.SetVirtualResolution(width,height)
	
	If _mode&1
		Local red:Int,green:Int,blue:Int
		GetClsColor red,green,blue
		SetClsColor _bred,_bgreen,_bblue
		Cls
		SetClsColor red,green,blue
		brl.max2d.SetViewport _xoffset,_yoffset,_vwidth,_vheight
	Else
		brl.max2d.SetViewport 0,0,brl.max2d.VirtualResolutionWidth(),brl.max2d.VirtualResolutionHeight()
	EndIf
	
	brl.max2d.SetOrigin _xoffset,_yoffset
	
End Function

Function SetBorderColor( red:Int, green:Int, blue:Int )
	_bred=red
	_bgreen=green
	_bblue=blue
End Function

Function SwitchAspectMode( mode:Int )
	SetVirtualResolution _vwidth,_vheight,mode
End Function

Function Flip( sync:Int=-1 )
	brl.Graphics.Flip sync
	If _mode&1
		brl.max2d.SetViewport 0,0,brl.max2d.VirtualResolutionWidth(),brl.max2d.VirtualResolutionHeight()
		Local red:Int,green:Int,blue:Int
		GetClsColor red,green,blue
		SetClsColor _bred,_bgreen,_bblue
		Cls
		SetClsColor red,green,blue
		brl.max2d.SetViewport _xoffset,_yoffset,_vwidth,_vheight
	EndIf
End Function

Function SetOrigin( x:Float, y:Float )
	brl.max2d.SetOrigin x+_xoffset,y+_yoffset
End Function

Function GetOrigin( x:Float Var, y:Float Var )
	brl.max2d.GetOrigin x,y
	x:-_xoffset
	y:-_yoffset
End Function

Function SetViewport( x:Int, y:Int, width:Int, height:Int )
	Local x2:Float=Min(x+width,_xoffset+_vwidth)
	Local y2:Float=Min(y+height,_yoffset+_vheight)
	x=Max(x,_xoffset)
	y=Max(y,_yoffset)
	brl.max2d.SetViewport x,y,x2-x,y2-y
End Function

Function GetViewport( x:Int Var,y:Int Var,width:Int Var,height:Int Var )
	brl.max2d.GetViewport x,y,width,height
	x:-_xoffset
	y:-_yoffset
End Function

Function VirtualMouseX:Float()
	Return brl.max2d.VirtualMouseX()-_xoffset
End Function

Function VirtualMouseY:Float()
	Return brl.max2d.VirtualMouseY()-_yoffset
End Function

Function VirtualResolutionWidth:Float()
	Return _vwidth
End Function

Function VirtualResolutionHeight:Float()
	Return _vheight
End Function

'-----------------------
'Test code
'-----------------------
SeedRnd MilliSecs()
'Graphics Rand(320,DesktopWidth()),Rand(240,DesktopHeight())
SetGraphicsDriver(GLMax2DDriver())

Local Window:TGadget = CreateWindow("Test", 0, 0, Rand(320,DesktopWidth()), Rand(240,DesktopHeight()), Null, WINDOW_DEFAULT|WINDOW_CENTER)
Local canvas:TGadget = CreateCanvas(0, 0, ClientWidth(Window), ClientHeight(Window), Window)
SetGadgetLayout(Canvas, 1, 1, 1, 1)

CreateTimer 60
SetGraphics CanvasGraphics(canvas)


SetBorderColor 32,32,32
SetClsColor 223,223,223
SetColor 255,127,0

SetVirtualResolution 320,240,ModeSet 

EnablePolledInput()
While WaitEvent()
	Select EventID()
		Case EVENT_TIMERTICK
			RedrawGadget canvas
		Case EVENT_GADGETPAINT
			SetGraphics CanvasGraphics(canvas)
			SetVirtualResolution 320,240,ModeSet 
			Cls
			DrawText "Aspect correction demo",5,5
			DrawText VirtualMouseX()+","+VirtualMouseY(),VirtualMouseX(),VirtualMouseY()
			Flip
		Case EVENT_KEYDOWN
			If KeyHit(KEY_1) Then ModeSet = 1
			If KeyHit(KEY_2) Then ModeSet = 2
			If KeyHit(KEY_3) Then ModeSet = 3
			If KeyHit(KEY_4) Then ModeSet = 4
			If KeyHit(KEY_5) Then ModeSet = 5
			SwitchAspectMode ModeSet
	EndSelect
	

Wend