One pixel colliding with image

BlitzMax Forums/BlitzMax Programming/One pixel colliding with image

Pineapple

(Posted 2010) [#1]

How can I check if a single pixel is overlapping an image considering alpha transparency without too large a hit on performance?

matibee

(Posted 2010) [#2]

Will the image be rotated and scaled?? If not, keep a copy in system memory with a TPixmap and look directly into that, taking into account it's relative position on screen and the pixel you're looking at; ie If the image is drawn at 100,100 and your pixel is at screen position 140,125, look into the pixmap at (40,25).

Zeke	(Posted 2010) [#3]

use 1x1 size image and use imagescollide() if no rotation, or if rotation use imagescollide2()

small example:

SuperStrict

Graphics 800 , 600
AutoMidHandle(True)
Global img_oval:TImage = CreateImage(128 , 128)
Global img_rect:TImage = CreateImage(128 , 128)
Global pixel:TImage = CreateImage(1,1)


Plot 0,0
GrabImage(pixel , 0 , 0)

SetColor 255,255,255
Cls
DrawOval 42 , 0 , 64,128 'oval image
GrabImage(img_oval , 0 , 0)

Cls
DrawRect 0 , 0 , 128 , 128 'rect image
GrabImage(img_rect , 0 , 0)

Global rot1:Int,rot2:Int

While Not (KeyHit(key_escape) Or AppTerminate() )
	Cls
	rot1 = MilliSecs() / 60 Mod 360 'oval rotation
	rot2 = MilliSecs() / 30 Mod 360 'rect rotation
	
	SetRotation rot1 'set rotation
	DrawImage img_oval , 200 , 200 'draw oval
	
	SetRotation rot2
	DrawImage img_rect , 340 , 200 'draw rect
	

	'Why imagesCollide2?
	'because: if there is any rotation, then imagesCollide give wrong return if other image size is 1x1 pixels
	'so if no rotation ImagesCollide
	'if rotation, use ImagesCollide2, and use 'pixelimage' rotation=0,scale=0,0
	If ImagesCollide2(pixel , MouseX() , MouseY() , 0 , 0 , 1 , 1 , img_oval , 200 , 200 , 0 , rot1 , 1 , 1)
		SetRotation 0
		DrawText "Collide to OVAL" , 0 , 0
	endif

	If ImagesCollide2(pixel , MouseX() , MouseY() , 0 , 0 , 1 , 1 , img_rect , 340 , 200 , 0 , rot2 , 1 , 1)
		SetRotation 0
		DrawText "Collide to RECT" , 400, 0
	EndIf
	
	If ImagesCollide2(img_oval , 200 , 200 , 0 , rot1 , 1 , 1 , img_rect , 340 , 200 , 0 , rot2 , 1 , 1)
		SetRotation 0
		DrawText "Oval and Rect collide" , 200 , 0
	EndIf
	Flip
Wend

GfK	(Posted 2010) [#4]

Are you using collision layers?

If so, the easiest way it to use:

CollideRect(MouseX(),MouseY(),1,1,layerID%,0)

ImaginaryHuman

(Posted 2010) [#5]

The fastest way by far is you use a pixmap in main memory and use pointers to access the pixels to find out if they collide.