Readstring needs to know the length of the string

BlitzMax Forums/BlitzMax Programming/Readstring needs to know the length of the string

slenkar

(Posted 2009) [#1]

I was trying to convert juicy fonts to blitzmax, it uses readstring at the beggining of a file but in blitzmax readstring needs to know the length.

How would I get the size of a string from a stream?

N	(Posted 2009) [#2]

Read until you find a 0 byte/short, depending on how it's stored. By this point, however, you will have read all of the characters, so you don't need to know the length, you just need to read the string in a different way (one that treats it as a null-terminated string instead of as a string of N characters).

plash

(Posted 2009) [#3]

How would I get the size of a string from a stream?

As Nilium said, you can use Null termination for string reading, or you can use length-included strings.

Some functions to do both approaches:

Rem
	bbdoc: Read newline-terminated String from a Stream.
	returns: The read string.
	about: This function may throw a TNStringReadException (search went past the max buffer), or it may throw a TStreamReadException (no more data to be read).
End Rem
Function ReadNString:String(stream:TStream, maxbuffer:Int = 256)
	Local str:String, Buf:Byte[1024], p:Int, count:Int
	
	Repeat
		Local n:Byte
		n = stream.ReadByte() 'Read(VarPtr n, 1) <> 1 Exit
		'Reached the newline character?
		If n = 10 Then Exit
		
		'Beyond the search amount?
		If p > maxbuffer Then Throw New TNStringReadException
		If stream.Eof() = True Then Throw New TStreamReadException
		
		Buf[p] = n; p:+1
		If p <> Buf.Length Then Continue
		str:+String.FromBytes(Buf, p)
		p = 0
	Forever
	
	If p Then str:+String.FromBytes(Buf, p)
	Return str
End Function

Rem
	bbdoc: Write newline-terminated String to a Stream.
	returns: Nothing.
End Rem
Function WriteNString(stream:TStream, value:String)
	stream.WriteString(value + "~n")
End Function

Rem
	bbdoc: Read a length-defined String from a Stream.
	returns: A String read from the given Stream.
End Rem
Function ReadLString:String(stream:TStream)
	stream.ReadString(stream.ReadInt())
End Function

Rem
	bbdoc: Write a length-defined String to a Stream.
	returns: Nothing.
End Rem
Function WriteLString(stream:TStream, value:String)
	stream.WriteInt(value.Length)
	stream.WriteString(value)
End Function

Blueapples

(Posted 2010) [#4]

slenkar,

Did you ever get anywhere with converting the Juicy Fonts library to BlitzMax? I'm looking to use it in a project and it's a fair bit of code to convert. If you've already made progress I'd rather not redo all that work.

slenkar

(Posted 2010) [#5]

i made my own instead,

Strict

Import BaH.libxml
Graphics 800,600,0

For Local x=32 To 126
Print Chr(x)
Next

Global font:Timagefont=Timagefont.Load("c:/windows/fonts/arial.ttf",60,SMOOTHFONT)
'Local g:TFreeTypeGlyph=font.loadglyph(32)

Global img_array:TImage[127]


Global texturewidth=512
Global textureheight=512

SetClsColor(0,0,0)

Global charnode:TxmlNode
Global imgnode:TxmlNode
Global rootnode:TxmlNode
Global doc:TxmlDoc
Global grabbed

While Not KeyHit(KEY_ESCAPE)

Cls
Local width
Local y
SetColor (255,255,255)

If grabbed=False
doc:TxmlDoc = TxmlDoc.newdoc("1.0")
rootnode:TxmlNode=TxmlNode.newnode("imagefont")
doc.setrootelement(rootnode)
imgnode:TxmlNode=rootnode.addchild("img")
charnode:TxmlNode=rootnode.addchild("chars")

imgnode.addattribute("width",texturewidth)
imgnode.addattribute("height",textureheight)
imgnode.addattribute("backgroundr",0)
imgnode.addattribute("backgroundg",0)
imgnode.addattribute("backgroundb",0)
imgnode.addattribute("fontheight", font.height())
EndIf

For Local x=32 To 126

Local s$=Chr(x)
Local n=font.CharToGlyph(x)
Local g:TimageGlyph=font.LoadGlyph(n)
Local img:TImage=g._image

Local thisnode:TxmlNode=charnode.addchild("Char")
thisnode.addattribute("ascnum",x)
img_array:TImage[x]=g._image
thisnode.addattribute("xadvance",g._advance)
thisnode.addattribute("yoffset",g._y)
thisnode.addattribute("xoffset",g._x)
thisnode.addattribute("width",g._w)
thisnode.addattribute("height",g._h)



If img<>Null

DrawImage img,width,y+g._y

If grabbed=False
thisnode.addattribute("x",width)
thisnode.addattribute("y",y+g._y)
EndIf

width=width+g._advance+(-g._x)+1

If x+1<126
Local n2=font.CharToGlyph(x+1)
Local g2:TimageGlyph=font.LoadGlyph(n2)

If g2<>Null

Local img2:TImage=g2._image
If width+g2._advance+(-g._x)+1>texturewidth
width=0
y=y+font.height()
EndIf
EndIf

EndIf
EndIf

Next

Flip

If grabbed=False
If doc <> Null Then
Print doc.savefile("-")
doc.savefile("arial.xml")
End If
Local pixy:TPixmap=GrabPixmap(0,0,texturewidth,textureheight)
SavePixmapPNG(pixy,"arial.png")
grabbed=True
EndIf

Wend

it has no gui, you have to modify the code to change the font etc.

to display a font I used this code with my own version of max2d

Function DrawText(txt$,x,y)
If imagefont=Null
RuntimeError "no font is set yet, use setfont"
EndIf
EnableTex imagefont.tex.num
Local colorrr
Local colorgg
Local colorbb
colorrr=colorr
colorgg=colorg
colorbb=colorb

Local x_place=x
Local highest_char

For x=1 To txt.length
Local char$=txt[x-1..x]
Local f:font_char=imagefont.char_array[Asc(char)]
If f<>Null
If f.pixel_height>highest_char
highest_char=f.pixel_height
EndIf 
EndIf
Next

For x=1 To txt.length

Local char$= txt[x-1..x]

Local f:font_char=imagefont.char_array[Asc(char)]

If f<>Null
'Local y_place=y+((highest_char-f.pixel_height)+f.yoffset)
Local y_place=y+(f.yoffset*scaley)


gltranslatef(x_place,y_place,0)
glrotatef(rotation,0,0,1)
glscalef(scalex,scaley,1)


glBegin(GL_QUADS)

SetColor(colorrr,colorgg,colorbb)
glTexCoord2f(f.x,f.y)
glVertex2f(f.vertex[0],f.vertex[1] )
glTexCoord2f(f.x+f.width,f.y)
 glVertex2f(f.vertex[2], f.vertex[3])
glTexCoord2f(f.x+f.width,f.y+f.height)
 glVertex2f(f.vertex[4], f.vertex[5])
glTexCoord2f(f.x,f.y+f.height)
 glVertex2f(f.vertex[6], f.vertex[7])
glEnd

glloadidentity()
gltranslatef(0.375,0.375,0)

'x_place=x_place+((f.pixel_width)*scalex)
'x_place=x_place+(f.pixel_width*scalex)'+(f.xoffset*scalex)
x_place:+((f.xadvance*scalex))
x_place=x_place+(-f.xoffset*scalex)
EndIf
Next
SetColor(colorrr,colorgg,colorbb)
EndFunction

you may be able to use animimage commands instead