Possible to Grab the Call Stack?

BlitzMax Forums/BlitzMax Programming/Possible to Grab the Call Stack?

Macguffin

(Posted 2009) [#1]

Is it possible to grab the call stack as an object in BlitzMax? I was thinking that info would be really helpful to attach to events in my event system. Thanks.

grable

(Posted 2009) [#2]

I guess you could do this in debug mode (seeing as the debugger can).

Release mode is a different story. Its possible, but would require some black magic ;)

grable

(Posted 2009) [#3]

If anyone wonders,
To make a call-chain, one has to trace through the call-frames on the stack, then decode the address from the call instruction before the return ip.

Heres an example for x86 and win32 (mac & linux should work too, but not tested)
note that it will crash for functions without a call-frame

Framework BRL.StandardIO

Import BRL.Retro

SuperStrict

Global GLOB:TTest = New TTest

Function GetMethodPtr:Byte Ptr( obj:Object, ofs:Int)
	Local vmt:Byte Ptr = Byte Ptr Int Ptr(Byte Ptr(obj)-8)[0]
	Return Byte Ptr Int Ptr(vmt + ofs)[0]
EndFunction

Print "A=" + Hex(Int Byte Ptr A)
Print "B=" + Hex(Int Byte Ptr B)
Print "C=" + Hex(Int Byte Ptr C)
Print "TTest.D=" + Hex(Int GetMethodPtr( GLOB, $30)) ' new methods start at offset $30 (may change in the future)
Print "->"
init_trace()
A()
End

Function A()
	B()
EndFunction

Function B()
	C()
EndFunction

Function C()
	GLOB.D()
EndFunction



Type TTest
	Method D()
		trace()
	EndMethod
EndType


Global main_frame:Int Ptr

Function init_trace()
	Local dummy:Int = $BAADF00D
	Local stack:Int Ptr = Int Ptr Varptr dummy
	' grab main frame pointer
	main_frame = Int Ptr stack[1]
EndFunction

Function trace()
	Function decode_call_addr:Byte Ptr( vmt:Byte Ptr, ip:Byte Ptr)
		Local call:Byte Ptr
		
		' check 5 byte calls
		call = ip - 5
		If call[0] = $E8 Then
			' call $addr
			Return Byte Ptr(Int ip + Int Ptr(call+1)[0])
		EndIf
	
		'check 3 byte calls
		call = ip - 3
		If call[0] = $FF Then
			If call[1] >= $50 And call[1] <= $57 Then
				' call [reg+byte]	
				Return Byte Ptr Int Ptr(vmt + call[2])[0]
			EndIf
		EndIf
		
		' check 6 byte calls
		call = ip - 6
		If call[0] = $FF Then
			If call[1] >= $90 And call[1] <= $97 Then
				' call [reg+int]
				Return Byte Ptr(vmt + Int Ptr(call+2)[0])
			EndIf
		EndIf
		
		' check 2 byte calls
		call = ip - 2
		If call[0] = $FF Then
			If call[1] >= $D0 And call[1] <= $D7 Then
				' call reg
				DebugLog "unhandled: call reg"
				Return Byte Ptr $BAADF00D
			ElseIf call[1] >= $10 And call[1] <= $17 Then
				' call [reg]
				DebugLog "unhandled: call [reg]"
				Return Byte Ptr $BAADF00D
			EndIf
		EndIf
		
		DebugLog "unhandled: unknown"
		Return Byte Ptr($BAADF00D)
	EndFunction
		
	Local dummy:Int = $BAADF00D
	Local stack:Int Ptr = Int Ptr Varptr dummy
	 ' start at calling frame
	Local sp:Int Ptr = Int Ptr stack[1]
	While sp < main_frame
		' bp=sp[0]
		' ip=sp[1]
		' this=sp[2] (if method)
		' vmt=sp[2][0] (if method)
		Print Hex(Int decode_call_addr( Byte Ptr Int Ptr(sp[2])[0], Byte Ptr sp[1]))
		' goto last frame
		sp = Int Ptr sp[0]
	Wend
EndFunction

UPDATE: added decoding of more call instructions, allowing to trace methods as well.

Macguffin

(Posted 2009) [#4]

Thanks, Grable. I figured odds were low that it would just mean including a pointer to an object... I'll have to hold off until after we get our IGF entry in. Appreciate it!

Scott