Anyone has any issues with Max crashing on 64 bit

BlitzMax Forums/BlitzMax Programming/Anyone has any issues with Max crashing on 64 bit

sswift

(Posted 2009) [#1]

A publisher I've submitted Space Beetles to has indicated that the game crashed their Mac when they were running an XP emulator or something, and a test on a 64bit Vista installation crashed as well. The game runs fine otherwise.

Any ideas what might cause this issue? Also, I've heard there's a way to run games in some kind of 32bit emulation layer in Vista? How does one go about enabling that for a particular game?

Arowx

(Posted 2009) [#2]

I think in blitzmax the game is only built as a 32bit application so run's on 64bit Vista systems as a 32bit app by default, the OS works out that it's 32bit and runs it accordingly.

GfK	(Posted 2009) [#3]

Yep, Blitzmax builds win32 apps but I'm not aware of any specific problems with running them on 64-bit systems.

As for it not running on a Mac with Win emulation.... is that really such an issue? If you want to play PC games, get a PC.

Jim Teeuwen

(Posted 2009) [#4]

I never had any problems running blitz apps on my 64 bit linux system.

xlsior

(Posted 2009) [#5]

Are you using OpenAL, by any chance?

I'm just curious, what would happen if you have spread a 32-bit OpenAL DLL to a computer that may at some point have manually installed a 64-bit DLL, confusing your application? (32 bit Blitzmax App probably wouldn't be able to call / handle a 64-bit system DLL)

As far as the XP-on-a-Mac crashing: Perhaps a side-effect of hardware virtualization not being handled properly somewhere along the road?

for troubleshooting purposes, I'd wonder if you may wish to compile a version of your program will all sound routines and libraries stripped out, and see if that makes the problem go away. If it does, at least it may show you what area to focus on.

ziggy

(Posted 2009) [#6]

This or send the publisher a debug build with console mode and tell him to tell you any possible crash message in the console window, so you can locate any possible issue in the code.

skidracer

(Posted 2009) [#7]

From what I have read on these forums, I would be more suspicious of the high def mouse hacks you may have in place.

Tablet peripherals and touch pads being a possible source of confusion for your driver.

Also, are you overriding default audio driver?

SLotman

(Posted 2009) [#8]

No need for 32 bit emulation: blitzmax games run fine on Vista 64.

The only problem I had with my game was with OpenAL, which was distorting very badly the music, and even seemed to duplicate the audio in some part... switched back to directsound and it's working perfectly.

xlsior

(Posted 2009) [#9]

No need for 32 bit emulation: blitzmax games run fine on vista 64.

...That's because Vista64 does the emulating for you, through WOW64. :-?

sswift

(Posted 2009) [#10]

Skid:
I wouldn't call them "hacks". I'm simply accessing data the Win32 api provides.

Here's the code:


' This code is used only on Win32 systems.

?Win32

Extern "Win32"
	Function RegisterRawInputDevices:Int(pRawInputDevices:Byte Ptr, uiNumDevices:Int, cbSize:Int)
	Function GetRawInputData:Int(hRawInput:Byte Ptr, uiCommand:Int, pData:Byte Ptr, pcbSize:Int Ptr, cbSizeHeader:Int)
End Extern


Global OldWinProc:Int ' This is the old blitzmax WinProc() function pointer.  This is set when you call HookWinProc().  


Const HID_USAGE_PAGE_GENERIC%  = $1
Const HID_USAGE_GENERIC_MOUSE% = $2
Const RIDEV_INPUTSINK% = $100
Const RIM_TYPEMOUSE% = 0
Const RID_INPUT% = $10000003


' If more than one raw input device needs to be registered, you will need to duplicate the fields in this type, because BltizMax types don't work like C structs,
' and creating arrays of them creates arrays of pointers to the data, rather than arranging multiple copies of the data within the array itself.

Type RAWINPUTDEVICE
   Field usUsagePage:Short
   Field usUsage:Short
   Field dwFlags:Int
   Field hwndTarget:Int
End Type

Global Rid:RAWINPUTDEVICE = New RAWINPUTDEVICE


' This type is a combination of the Windows structs RAWINPUTHEADER, RAWINPUT, and RAWMOUSE.
' This was done to avoid the need for unions (which BlitzMAx does not support) and issues with type variables being a pointer to data rather than having the data at that location.

Type RAWINPUT 
	
	' RAWINPUTHEADER:
		Field dwType:Int
		Field dwSize:Int
		Field hDevice:Byte Ptr
		Field WPARAM:Int Ptr 
	
	' RAWMOUSE:
		Field usFlags:Short 
		Field ulButtons:Int ' Depending on flags, can either be single long value ulButtons or short values usButtonFlags in low word, and usButtonData in high word.  Again, a work around for unions.
	  	Field ulRawButtons:Int 
		Field lLastX:Int 
	  	Field lLastY:Int 
  		Field ulExtraInformation:Int 

End Type 


' ---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
' This function registers the mouse as a raw input device, so that WM_INPUT events will be generated for it.
' hWnd is the pointer to your window.  See HookWinProc() above for more details.
' ---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------


	Function RegisterRID_MOUSE(hWnd:Int)
		
		Rid.usUsagePage = HID_USAGE_PAGE_GENERIC
		Rid.usUsage = HID_USAGE_GENERIC_MOUSE 
		Rid.dwFlags = RIDEV_INPUTSINK   
		Rid.hwndTarget = hWnd			

		RegisterRawInputDevices(Rid, 1, SizeOf(Rid))

	End Function


' ---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
' hWnd is the pointer to your window.  hWnd is not the gadget pointer! 
' You can get hWnd with hWnd = GetActiveWindow(), or with hWnd = QueryGadget(Window, QUERY_HWND), where Window is your window's gadget pointer.
' ---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

	Function HookWinProc(hWnd:Int)
		Local GWL_WNDPROC:Int = -4
		OldWinProc = SetWindowLongA(hWnd, GWL_WNDPROC, Int(Byte Ptr(WinProc)))
	End Function  


' ---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
' This function is called automatically.  It grabs raw windows events before Blitzmax processes them, so that you can handle events that Blitzmax doesn't provide an interface for.
'
' Blitzmax has its own function like this internally, and this one calls that when it is done processing.
' Presumably, events handled by this function will still be passsed onto BlitzMax, so avoid processing the same data in both event handlers!
' ---------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------

	Function WinProc:Int(hWnd:Int, Msg:Int, wParam:Int, lParam:Int) "win32"
	
		Const WM_INPUT% = $00FF
	
		Function LWord:Short(I:Int) ' Returns the lower 16 bits of a 32 bit integer.
			Return I & $FFFF
		End Function
	
		Function HWord:Short(I:Int) ' Returns the upper 16 bits of a 32 bit integer.
			Return I Shr 16
		End Function
		
		Mouse_RawVx# = 0
		Mouse_RawVy# = 0
		
		Select Msg
	
		    Case WM_INPUT

	    			Local dwSize:Int = 40
				Local Raw:RAWINPUT = New RAWINPUT
    
				GetRawInputData(Byte Ptr(lParam), RID_INPUT, Raw, Varptr dwSize, 16) ' Get data in RAWINPUT structure.
    
				If Raw.dwType = RIM_TYPEMOUSE
				
					Mouse_NetDeltaX# = Mouse_NetDeltaX# + Raw.lLastX
					Mouse_NetDeltaY# = Mouse_NetDeltaY# + Raw.lLastY
				
					'Mouse_RawVx# = Raw.lLastX
					'Mouse_RawVy# = Raw.lLastY
					
					'DebugLog("Raw LastX = " + Raw.lLastX)
					'DebugLog("Raw LastY = " + Raw.lLastY)
					
				EndIf
				
			'Default
			'	DebugLog("Unknown Msg: " + Msg)
					
		End Select
	
		If OldWinProc <> 0 Then Return CallWindowProcA(Byte Ptr(OldWinProc), hWnd, Msg, wParam, lParam)   
		
	End Function

?

And this is how I handle the sound driver issue:

			' If running on windows, use the directsound audio driver to fix sound delays in Vista.
				?Win32
					If Not SetAudioDriver("directsound") Then DebugLog("Error in App.Create(): Could not set DirectSound audio driver!")
				?

So, DirectSound.

Here's the whole app setup actually, there's something in there about hooking the windows procedure that I don't remember what it was for. Maybe the mouse code.

		Function Create(AppName$, AppWidth%, AppHeight%, AppDepth%=0, UseGL%=False)
	
			Local X%, Y%	
			
			' If we should use OpenGL on all platforms, then enable the openGL driver.
				If UseGL% Then SetGraphicsDriver GLMax2DDriver()
			
			' Warn programmer if the game is running in debug mode so they don't wonder why game is running choppy.
				DebugLog("WARNING: Game running debug mode - Performance will be reduced!")
									
			' Store application settings.
				Name$  = AppName$
								
				Full_Width  = AppWidth
				Full_Height = AppHeight	
				
				' If Depth is 0, try to find a suitable fullscreen bit depth.
			
					If AppDepth = 0
						If GraphicsModeExists(Full_Width, Full_Height, 16) Then AppDepth = 16
						If GraphicsModeExists(Full_Width, Full_Height, 24) Then AppDepth = 24
						If GraphicsModeExists(Full_Width, Full_Height, 32) Then AppDepth = 32
					EndIf		
					
				Full_Depth     = AppDepth
				Windowed_Depth = AppDepth
					
			' Create a window in the center of the screen.
			' ClientWidth/Height is used because GadgetWidth/Height returns the entire width of the desktop in dual screen setups.
		
				X = ClientWidth(Desktop())/2  - Windowed_Width/2
				Y = ClientHeight(Desktop())/2 - Windowed_Height/2
				
				'Window = CreateWindow(Name$, X, Y, Windowed_Width, Windowed_Height, Null, WINDOW_TITLEBAR|WINDOW_RESIZABLE|WINDOW_CLIENTCOORDS|WINDOW_HIDDEN)
				'SetMinWindowSize(Window, GadgetWidth(Window), GadgetHeight(Window))

				
				' Create a non-resizable window.
					Window = CreateWindow(Name$, X, Y, Windowed_Width, Windowed_Height, Null, WINDOW_TITLEBAR|WINDOW_CLIENTCOORDS|WINDOW_HIDDEN)
				
				' If running on Windows, add minimize button to window.

					?Win32 
				
						Local xs%
				
						' Get window pointer.
							App.hWnd = QueryGadget(Window, QUERY_HWND) 
	
						' Get window appearance flags, and add Minimize button.
							xs = GetWindowLongA(hWnd, -16) | $20000 

						' Set new window appearance, and apply changes.
							SetWindowLongA(hWnd, -16, xs)
							UpdateWindowMenu(Window)
												
					?
											
			' Create a panel in the window, drawn behind the canvas, which fills the empty space around the gameplay area when the window is maximized.
				
			'	Panel = CreatePanel(0, 0, Windowed_Width, Windowed_Height, Window)
				
			'		SetPanelColor(Panel, 0, 0, 0)
			'		SetGadgetLayout(Panel, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED, EDGE_ALIGNED)
			
			' If running on windows, hook the window's event handler so we can capture events not exposed by BlitzMax.
				?Win32
					HookWinProc(App.hWnd) 
				?
			
			' Set game to windowed or fullscreen as desired.
				Select App.Windowed
					Case True  SetWindowed()
					Case False SetFullscreen()
				End Select
			
			' Enable polled input.
				EnablePolledInput()

			' Load mouse cursor and create mouse sprite.
				InitMouse()
			
			' If running on windows, use the directsound audio driver to fix sound delays in Vista.
				?Win32
					If Not SetAudioDriver("directsound") Then DebugLog("Error in App.Create(): Could not set DirectSound audio driver!")
				?
															
		End Function

This is the bit where I'm not sure what I was doing:
HookWinProc(App.hWnd)

I hate when I comment stuff and the comment I wrote wasn't clear enough to help me remember why I did something later. :-)

sswift

(Posted 2009) [#11]

Ah I figured out what I was doing.

(But as far as I know this has nothing to do with the crashing.)

That calls this function in the mouse code:

	Function HookWinProc(hWnd:Int)
		Local GWL_WNDPROC:Int = -4
		OldWinProc = SetWindowLongA(hWnd, GWL_WNDPROC, Int(Byte Ptr(WinProc)))
	End Function

Which tells Windows to hook the function WinProc, also in the mouse code, to the BlitzMax window procedure. This is what allows me to capture the mouse events BlitzMAx doesn't normally expose.