How to use a DLL?

BlitzMax Forums/BlitzMax Programming/How to use a DLL?

BlitzProg

(Posted 2009) [#1]

I may seem stupid but the titles says it all... how to use a dll? I have a dll file and i would like to import it.

Very simple question, i don't know what to add =[]

kfprimm

(Posted 2009) [#2]

http://www.blitzbasic.com/Community/posts.php?topic=41803
I would suggest using Drago's method as opposed to skidracer's, though both work and have the same end result.

BlitzProg

(Posted 2009) [#3]

ok, wow, this looks way more complicated than i imaginated. This doesn't look like an "Extern" where you just tell which function to import or not then O_o

kfprimm

(Posted 2009) [#4]

Did you look at this? It is pretty straight forward...well, compared to the other way.

BlitzProg

(Posted 2009) [#5]

it stills doesn't look that simple! I never ever worked with imports and nothing about this seems to make sense (i mean i can't explain anything of why proceeding that way, lol)

Mahan

(Posted 2009) [#6]

Skidracers method is the "classic dynamic library method". While Dragos method is very smooth, Skidracers allow you to create a program where 3:rd parties can actually replace the DLL, and enhance functionality.

A few days ago I did a working wrapper for the bbEnet dll (userlib originally intended for b3d and b+) for BlitzMax using the Skidracer method:

Link to bbEnet userlib: http://www.leidel.net/dl/bbenet.zip (made by Xaron)

This is a fully working example so I hope it might be useful for you as reference if you are creating another DLL wrapper.

(filename: enet_dll.bmx)


Const ENET_EVENT_TYPE_NONE:Int = 0
Const ENET_EVENT_TYPE_CONNECT:Int = 1
Const ENET_EVENT_TYPE_DISCONNECT:Int = 2
Const ENET_EVENT_TYPE_RECEIVE:Int = 3


Global __ENET_DLL_HANDLE:Int = 0
Global __ENET_LAST_PEER_ID:Int = 0
Global __ENET_BANK_RECEIVE:TBank = CreateBank(100000)
Global __ENET_BANK_PEERID:TBank = CreateBank(4)
Global __ENET_BANK_RECSIZE:TBank = CreateBank(4)


Global __ENetInitialize() "win32"
Global __ENetDeInitialize() "win32"
Global ENetCreate:Int(server:Int, address$z, port:Int, maxClients:Int, IBW:Int, OBW:Int) "win32"
Global ENetDoEventCheck:Int(timeOut:Int) "win32"
Global __ENetCheckEvents:Int(peerID:Byte Ptr, dataSize:Byte Ptr, bank:Byte Ptr) "win32"
Global __ENetSendData:Int(packet:Byte Ptr, packetSize:Int, client:Int, reliable:Int) "win32"
Global ENetDisconnect:Int(client:Int) "win32"
Global ENetConnect:Int(address$z, port:Int) "win32"
Global ENetGetNumClients:Int() "win32"

Function ENetInitialize:Int()
	__ENET_DLL_HANDLE = LoadLibraryA("eNetDLL.dll")
	
	If __ENET_DLL_HANDLE Then
		__ENetInitialize = GetProcAddress(__ENET_DLL_HANDLE, "_ENetInitialize@0")
		__ENetDeInitialize = GetProcAddress(__ENET_DLL_HANDLE, "_ENetDeInitialize@0")
		ENetCreate = GetProcAddress(__ENET_DLL_HANDLE, "_ENetCreate@24")
		ENetDoEventCheck = GetProcAddress(__ENET_DLL_HANDLE, "_ENetDoEventCheck@4")
		__ENetCheckEvents = GetProcAddress(__ENET_DLL_HANDLE, "_ENetCheckEvents@12")
		__ENetSendData = GetProcAddress(__ENET_DLL_HANDLE, "_ENetSendData@16")
		ENetDisconnect = GetProcAddress(__ENET_DLL_HANDLE, "_ENetDisconnect@4")
		ENetConnect = GetProcAddress(__ENET_DLL_HANDLE, "_ENetConnect@8")
		ENetGetNumClients = GetProcAddress(__ENET_DLL_HANDLE, "_ENetGetNumClients@0")
                __ENetInitialize()
	EndIf
	
	Return __ENET_DLL_HANDLE
End Function

Extern "win32"
	Function FreeLibrary(hLibrary:Int)
End Extern

Function ENetDeInitialize()
	__ENetDeInitialize()
	FreeLibrary(__ENET_DLL_HANDLE)
End Function

Type TENetEventResult
	Field result:Int
	Field peerId:Int
	Field treshold:TBank
End Type

Function ENetCheckEvents:TENetEventResult()

	Local result:Int
	result = __ENetCheckEvents(__ENET_BANK_PEERID.Buf(), __ENET_BANK_RECSIZE.Buf(), __ENET_BANK_RECEIVE.Buf())
	If (result = ENET_EVENT_TYPE_NONE) Then Return Null
	Local _ret:TENetEventResult = New TENetEventResult
	_ret.result = result
	_ret.peerId = __ENET_BANK_PEERID.PeekInt(0)
	If (result = ENET_EVENT_TYPE_RECEIVE) Then
		Local size:Int = __ENET_BANK_RECSIZE.PeekInt(0)
		_ret.treshold = CreateBank(size)
		Local fs:TBankStream = CreateBankStream(__ENET_BANK_RECEIVE)
		fs.ReadBytes(_ret.treshold.Buf(), size)
	EndIf
	Return _ret
End Function

Function ENetSendData:Int(data:TBank, peerId:Int, reliable:Int = True)

  Return __ENetSendData(data.Buf(), data.Size(), peerId, reliable)
  
End Function

Here is a demo program that uses this wrapper, just to show it in action:


Include "enet_dll.bmx"

Function Main()
	ENetInitialize()
	
	
	Local s:String
	s = Input("server?")
	
	Local host:Int

	Local peer:Int = -1

		
	If Upper(s) = "Y" Then
		host = ENetCreate(True, "any", 9999, 32, 0, 0)
	Else
		host = ENetCreate(False, "", 0, 1, 0, 0)
		ENetConnect("127.0.0.1", 9999)
		peer = 0
	EndIf

	
	Local time:Int = MilliSecs()
	
	While Not KeyHit(KEY_ESCAPE)
		
		While ENetDoEventCheck(0)
			Local evRes:TENetEventResult = ENetCheckEvents()
			
			If evRes Then
				Select evRes.result
					Case ENET_EVENT_TYPE_CONNECT
						Print evRes.peerId + " connected"
						peer = evRes.peerId
					Case ENET_EVENT_TYPE_DISCONNECT
						Print evRes.peerId + " disconnected"
						peer = -1
					Case ENET_EVENT_TYPE_RECEIVE
						Local recStr:String
						recStr = String.FromCString(evRes.treshold.Buf())
						Print "Received: " + recStr
				End Select
			End If
		Wend
		If ((MilliSecs() - time) > 1000) And (peer <> - 1) Then
			time = MilliSecs()
			Local message:String = "Hi"
			Local msgPtr:Byte Ptr = message.ToCString()
			Local bank:TBank = TBank.CreateStatic(msgPtr, message.Length + 1)
			ENetSendData(bank, peer, True)
			bank = Null
			MemFree(msgPtr)
		End If
		Delay(1)
	Wend
		
	ENetDeInitialize()

EndFunction

Main()

Hope it helps.