Access to tImage Vertices?

BlitzMax Forums/BlitzMax Programming/Access to tImage Vertices?

CyBeRGoth

(Posted 2009) [#1]

Hi

Has anyone come across a way to get access to the vertices of the Quad which tImage uses to draw images with?
So we can for example move each vertex individually, or even better, is there a simple way to create a new Quad that tImage can use to draw images on, but this one has more than 4 corners (it is split into a grid, as the image below), this would allow you to do a lot of special effects directly to images, waves, pucker, bulge etc.

Thanks for any help.

GW	(Posted 2009) [#2]

not sure that it helps but i believe that LoadAnimImage is single surface, so that the model data is like the tree to the right. Then its just a matter of getting the vertex data.
if you look at d3d7max2d.bmx there is an array called vrts[]. Maybe a good place to start.

AndrewT

(Posted 2009) [#3]

I'm pretty sure an animated image is draw with four vertices, just like a regular image, but the texture is continuously scrolled to show the next frame of the animation.

However I agree that this would be a very useful feature, and it probably wouldn't be very hard to make yourself.

_Skully

(Posted 2009) [#4]

This would also rectify the projection matrix issue...

therevills

(Posted 2009) [#5]

but i believe that LoadAnimImage is single surface

According to this post:

http://www.blitzbasic.co.nz/Community/posts.php?topic=51647#576571

LoadAnimImage actually creates a new image for each frame... not sure if this was ever put into BlitzMax (the post was over 3 years ago...)

ImaginaryHuman

(Posted 2009) [#6]

What projection matrix issue are you talking about?

slenkar

(Posted 2009) [#7]

this would be useful for iso games too,
instead of having to skew images and save them in a square you can skew them in the game.

Zeke	(Posted 2009) [#8]

Graphics 800,600

Global cx#[4],cy#[4]

cx[0]=100 ; cy[0]=100 'top-left
cx[1]=228 ; cy[1]=100 'top-right
cx[2]=228 ; cy[2]=228 'bottom-right
cx[3]=100 ; cy[3]=228 'bottom-left

Global drag=-1

Global img:TImage=LoadImage("logo.png") 'CHANGE THIS!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!

While Not (KeyHit(key_escape) Or AppTerminate())

	'Draw box

	SetColor 255,255,255
	
	drawimagestretch img,cx[0],cy[0],cx[1],cy[1],cx[2],cy[2],cx[3],cy[3]
	
	'Draw small cornerboxes
	For Local i=0 To 3
		If MouseX()=>cx[i]-5 And MouseX()<cx[i]+5 And MouseY()=>cy[i]-5 And MouseY()<cy[i]+5
			SetColor 250,0,0
			If MouseDown(MOUSE_LEFT)
				drag=i
			EndIf
		Else
			SetColor 255,255,255
		EndIf
		If drag=>0
			If Not MouseDown(MOUSE_LEFT)
				drag=-1
			Else
				cx[drag]=MouseX() ; cy[drag]=MouseY()
			EndIf
		EndIf
		DrawRect cx[i]-5,cy[i]-5,10,10
	Next
	Flip
	Cls
Wend

Function DrawImageStretch(Image:TImage,x0#,y0#,x1#,y1#,x2#,y2#,x3#,y3#,fram#=0)
	If TGLMax2DDriver(_max2ddriver)
		'not yet
	Else
		Local d:TD3D7Max2DDriver=TD3D7Max2DDriver(_max2ddriver)
		If Not d.IsValid() Return
		Local Frame:Td3d7imageframe=Td3d7imageframe(Image.frame(fram))
		Local xx0#=-image.handle_x,xx1#=xx0
		Local yy0#=-image.handle_y,yy1#=yy0
		Local ox#,oy#
		Local uv:Float Ptr
		Local c:Int Ptr
		
		GetOrigin(ox,oy)
		x0:+ox ; y0:+oy ; x1:+ox ; y1:+oy ; x2:+ox ; y2:+oy ; x3:+ox ; y3:+ox

		uv=frame.xyzuv
		c=Int Ptr(uv)

		uv[0]=xx0*d.ix+yy0*d.iy+x0 'Top-Left
		uv[1]=xx0*d.jx+yy0*d.jy+y0
		c[3]=d.drawcolor		

		uv[6]=xx1*d.ix+yy0*d.iy+x1 'Top-Right
		uv[7]=xx1*d.jx+yy0*d.jy+y1
		c[9]=d.drawcolor

		uv[12]=xx1*d.ix+yy1*d.iy+x2 'Bottom-Right
		uv[13]=xx1*d.jx+yy1*d.jy+y2
		c[15]=d.drawcolor
		
		uv[18]=xx0*d.ix+yy1*d.iy+x3 'Bottom-Left
		uv[19]=xx0*d.jx+yy1*d.jy+y3
		c[21]=d.drawcolor
	
		d.SetActiveFrame frame		
		
		d.device.DrawPrimitive(6,D3DFVF_XYZ|D3DFVF_DIFFUSE|D3DFVF_TEX1,uv,4,0) '6
	EndIf
End Function

therevills

(Posted 2009) [#9]

Thats very cool Zeke!

Looking forward seeing the OpenGL part :)

slenkar

(Posted 2009) [#10]

very good zeke!

CyBeRGoth

(Posted 2009) [#11]

Nice stuff zeke :)

Now if only we could divide the image up into smaller vertices and play around with them too :)

Jesse

(Posted 2009) [#12]

these is really cool zeke. Thank you.