Threading and Processors?

BlitzMax Forums/BlitzMax Programming/Threading and Processors?

BLaBZ

(Posted 2009) [#1]

Trying to figure this out....
Is this right?
When multi-threading is enabled, if you have multiple processors, BlitzMax will use them?

grable

(Posted 2009) [#2]

No, YOU have to use Threads yourself. and the OS will (maybe) spread them around your cores.

Brucey

(Posted 2009) [#3]

When multi-threading is enabled, if you have multiple processors, BlitzMax will use them?

Well, it's usually entirely up to the operating system to decide that, but generally, yes.

<EDIT>I just assumed you'd be employing threads as part of your question... Of course, if you simply compile your app with threading enabled but with no other changes, it will run as it would without threading enabled.

xlsior

(Posted 2009) [#4]

When multi-threading is enabled, if you have multiple processors, BlitzMax will use them?

Yes, as long as you TELL your when/program where to launch seperate threads, and have them work together nicely. It won't magically spread your program across multiple CPU's on its own.

ImaginaryHuman

(Posted 2009) [#5]

Basically, CPU's are not designed to work on more than one thing at a time (for the most part), which means that just as in the old days, one program runs on one cpu core. Rather than implement distribution of workload in hardware, you have to work around the separate between cpu cores by using software. That's what threads are for. You have to deliberately tell the cpu, effectively, which pieces of your program are `separate` enough to run elsewhere.

Winni

(Posted 2009) [#6]

There's also a feature called 'thread affinity', which is used to bind a thread to a specific CPU. However, as far as I know, BlitzMax does not implement that, so you have to rely on the load balancing mechanisms of your operating system to distribute the threads across the available CPU cores.

QuickSilva

(Posted 2009) [#7]

Are there any simple examples around that show off the threading features in an easy to understand way? I`m curious about looking into threads too. Are they pretty simple to implement?

Jason.

Arowx

(Posted 2009) [#8]

See next thread down http://www.blitzbasic.com/Community/posts.php?topic=86318

and a more complex one here...

http://www.blitzbasic.com/Community/posts.php?topic=80119#903018

Couple of bugs in the second one so here's an update...

'GUI Coffee, Inc.
SuperStrict

'Put something on the screen.

Import MaxGui.Drivers ' *************** Needs MaxGui!
Import brl.threads

AppTitle = "Coffee, Inc."

Global x:Int = 0
Global y:Int = 0
Global width:Int = 640
Global height:Int = 480

Global AppWindow:TGadget = CreateWindow (AppTitle, x, y, width, height)

Global fileMenu:TGadget = CreateMenu ("&File", 0, WindowMenu (AppWindow))
Global xit:TGadget = CreateMenu ("E&xit", 1, fileMenu)

Global helpMenu:TGadget = CreateMenu ("&Help", 2, WindowMenu (AppWindow))
Global about:TGadget = CreateMenu ("&About...", 3, helpMenu)

UpdateWindowMenu AppWindow
	
Global devStatus:TGadget[10]

For Local n:Int = 0 To 9
	devStatus[n] = CreateTextField (4, 4 + n*30, ClientWidth (AppWindow) - 8, 24, AppWindow)
Next

Global goHome:TGadget = CreateButton ("Go home, guys!", 240, 400, 140, 24, AppWindow, BUTTON_OK)


'Setup the office environment.

Const cupSize:Int = 200

'Your simple Italian coffee machine. One load is good for eight cups.
Type CoffeeMachine

	Field hasCups:Int = 10
	Field hasCoffee:Int
	Field isCooking:Int
	Field myMutex:TMutex
	
	Method Create()
		hasCoffee = 0
		myMutex = CreateMutex()
	End Method
	
	Method giveCoffee:Int( name: String, nPos:Int )
		LockMutex( myMutex )
		If hasCoffee <= 0
			Local boiler:String = ""
			For Local n:Int = 1 To 8
				boiler :+ "+++"
				SetGadgetText( devStatus[nPos], name + " is cooking fresh coffee: " + boiler )
				Delay 300
			Next
			hasCoffee = 8 * cupSize
		End If
		SetGadgetText( devStatus[nPos], name + " takes coffee." )
		hasCoffee :- cupSize
		Delay 750
		UnlockMutex( myMutex )
		Return cupSize
	End Method
	
	Method giveCup( name: String, nPos:Int )
		LockMutex( myMutex )
		SetGadgetText( devStatus[nPos], name + " takes a cup.")
		hasCups :- 1
		Delay 400
		UnlockMutex( myMutex )
	End Method		
	
	Method returnCup( name: String, nPos:Int )
		LockMutex( myMutex )
		SetGadgetText( devStatus[nPos], name + " returns his cup to the kitchen.")
		hasCups :+ 1
		Delay 1000
		If hasCups = 10
			SetGadgetText( devStatus[nPos], name + " is last, he turns off the coffee machine.")
			Delay 3000
			HideGadget( goHome )
		End If
		UnlockMutex( myMutex )
	End Method

End Type

'A very simple software developer. He only works as long as he has coffee.
Type Developer
	Field Name:String
	Field Position:Int
	Field hasCoffee:Int
	Field machine:CoffeeMachine
	Global EOB:Int = False
		
	Method Create:Developer( name:String, pos:Int, machine:CoffeeMachine )
		Self.Name = name
		Self.Position = pos
		Self.hasCoffee = 0
		Self.machine = machine
		Return Self
	End Method
	
	Function SignalEOB()
		SetGadgetText( goHome, "Office is closing!" )
		DisableGadget( goHome )
		EOB = True
	End Function
	
	Method Working()
		machine.giveCup( name, Position )
		Repeat
			hasCoffee :- Rand(1, Int(cupSize/4) )
			If hasCoffee <= 0
				SetGadgetText( devStatus[Position], name + " needs coffee !!!")
				hasCoffee = machine.GiveCoffee( name, Position )
			Else
				Local cupContents:String = ""
				For Local n:Int = 1 To Int( 1 + hasCoffee/10)
					cupContents :+ "#"
				Next
				SetGadgetText( devStatus[Position], name + " is happily working. Coffee left: " + cupContents + " ( " + hasCoffee + " ml)." )
			End If
			Delay 600
		Until EOB
		machine.returnCup( name, Position )
		SetGadgetText( devStatus[Position], name + " went home.")
	End Method
End Type

'The thread factory
Function BuildThread:Object( data:Object)
	Local myDev:Developer = Developer(data)
	myDev.Working()
End Function

'Start the coffee machine
Global Luigi:CoffeeMachine = New CoffeeMachine
Luigi.Create()

'Get the guys to work
Global DevTeam:Developer[10]
Global devName:String[] = [ "Mark", ..
							"Brucey", ..
							"Skidracer", ..
							"SebHoll", ..
							"SimonH", ..
							"SimonA", ..
							"FlameDuck", ..
							"MarkT", ..
							"RobH", ..
							"Merx"]

For Local n:Int = 0 To 9 
	DevTeam[n] = New Developer
	DevTeam[n].Create( devName[n], n, Luigi )
Next

'Ready, steady, go!
Global handles:TThread[10]

For Local n:Int = 0 To 9
	handles[n]=CreateThread( BuildThread,  Object(DevTeam[n]) )
Next

'Send the boys home
Function ShutDown()
	Developer.SignalEOB()
	For Local n:Int = 0 To 9
		DetachThread( handles[n] )
	Next
End Function


'Your good old fashioned GUI event loop
Repeat
	Select WaitEvent ()
		Case EVENT_GADGETACTION
			If (EventSource () = goHome)
				ShutDown()
			End If 
				
		Case EVENT_WINDOWCLOSE
			ShutDown()
			End

		Case EVENT_MENUACTION
			If EventData () = 1 Then 
				ShutDown()
				End
			End If
			
			If EventData () = 3 Then Notify ("Coffee, Inc. only works with coffee!")
			
	End Select
Forever

QuickSilva

(Posted 2009) [#9]

Neat, thanks.

Jason.