Reflection is your best friend

BlitzMax Forums/BlitzMax Programming/Reflection is your best friend

JoshK

(Posted 2009) [#1]

OMG, reflection is teh best!

I set up a type for all my application settings:

SuperStrict

Import brl.reflection
Import "../../../Common/Propertygrid/Propertygrid.bmx"
Import "../../../Common/AppSettings.bmx"

Function WriteObject(stream:TStream,o:Object)
	Local typeid:TTypeId
	Local f:TField
	
	typeid=TTypeId.ForObject(o)
	For f=EachIn typeid.enumfields()
		stream.WriteLine(f.name()+"="+f.getstring(o))
	Next	
EndFunction

'Automatically save settings
OnEnd TSettings.Save_

'Load settings
TSettings.Load(StripExt(StripExt(AppFile))+".ini")

Type TSettings {label="Reflected settings"}
	
	Global list:TList=New TList
	
	Global map:TMap=New TMap
	
	Function Load:Int(url:Object)
		map.clear()
		Local stream:TStream=ReadStream(url)
		If Not stream Return 0
		Local s$,sarr$[]
		While Not stream.Eof()
			s=stream.ReadLine().Trim()
			If s
				sarr=s.split("=")
				If sarr.length=2
					TSettings.map.insert(sarr[0].Trim(),sarr[1].Trim())
				EndIf
			EndIf
		Wend
		stream.close()
		Return 1
	EndFunction
	
	Function Save_()
		Local stream:TStream=WriteFile(StripExt(StripExt(AppFile))+".ini")
		For Local s:TSettings=EachIn list
			s.save(stream)
		Next
		stream.close()
	EndFunction
	
	Method New()
		Rem
		Local typeid:TTypeId
		Local name$
		Local f:TField

		list.AddLast(Self)
		typeid=TTypeId.ForObject(Self)
		For f=EachIn typeid.enumfields()
			Notify f.name()+" "+String(map.valueforkey(f.name()))
			If map.contains(f.name())
				f.setstring(Self,String(map.valueforkey(f.name())))
				Notify 1
			EndIf
		Next
		EndRem
	EndMethod

	Method Start()
		Local typeid:TTypeId
		Local name$
		Local f:TField

		list.AddLast(Self)
		typeid=TTypeId.ForObject(Self)
		For f=EachIn typeid.enumfields()
			'Notify f.name()+" "+String(map.valueforkey(f.name()))
			If map.contains(f.name())
				f.setstring(Self,String(map.valueforkey(f.name())))
				'Notify 1
			EndIf
		Next
	EndMethod

	Method GetGroupName:String()
		Local name$
		Local typeid:TTypeId=TTypeId.ForObject(Self)
		name=typeid.metadata("label")
		If Not name name=typeid.name()
		Return name	
	EndMethod

	Method GetFieldName:String(f:TField)
		Local name$
		name=f.name().Replace("_"," ")
		Return name
	EndMethod

	Method Init(propertygrid:TPropertygrid)
		Local tag:String
		Local typeid:TTypeId=TTypeId.ForObject(Self)
		Local group:Tpropertygroup
		Local name$
		Local f:TField
		Local style:Int
		Local extra:String
		
		name=GetGroupName()
		group=propertygrid.FindGroup(name)
		
		For f=EachIn typeid.enumfields()
			name=getfieldname(f)
			If f.metadata("style")
				style=Int(f.metadata("style"))
			Else
				Select f.TypeId()
					Case FloatTypeId style=PROPERTY_FLOAT
					Case IntTypeId style=PROPERTY_INTEGER
					Case StringTypeId style=PROPERTY_STRING
					Case ArrayTypeId style=PROPERTY_COLOR
				EndSelect
			EndIf

			extra=f.metadata("extra")
			If extra extra="|"+extra
			
			group.AddProperty(name,f.getstring(Self)+extra,style)
		Next
	EndMethod

	Method Save(stream:TStream)
		stream.WriteLine("["+GetGroupName()+"]")
		ForEachFieldDo(func,stream)
		stream.WriteLine("")
		
		Function func(f:TField,o:Object,extra:Object)
			TStream(extra).WriteLine f.name()+"="+f.getstring(o)
		EndFunction
		
	EndMethod
	
	Method ForEachFieldDo(func(f:TField,o:Object,extra:Object),extra:Object)
		Local typeid:TTypeId
		Local f:TField
		typeid=TTypeId.ForObject(Self)		
		For f=EachIn typeid.enumfields()
			func(f,Self,extra)
		Next
	EndMethod

	Method Get(propertygrid:TPropertygrid)
		Local typeid:TTypeId
		Local f:TField
		typeid=TTypeId.ForObject(Self)		
		For f=EachIn typeid.enumfields()
			Local property:TProperty
			Local name$=getfieldname(f).tolower()
			property=tproperty(propertygrid.properties.valueforkey(name))
			If property=Null RuntimeError name
			property.setvalue(f.getstring(Self))
		Next
	EndMethod
	
	Method Update(propertygrid:TPropertygrid)
		ForEachFieldDo(func,propertygrid)
		
		Function func(f:TField,o:Object,extra:Object)
			f.setstring(o,TPropertyGrid(extra).getproperty(f.name().Replace("_"," ")))
		EndFunction
	EndMethod
	
	Method Set:Int(name:String,value:String)
		Local typeid:TTypeId=TTypeId.ForObject(Self)
		Local f:TField
		Local m:TMethod
		Local fname$
		
		name=name.Replace(" ","_")
		setappsetting name,value
		f=typeid.findfield(name)
		If f
			If f.getstring(Self)<>value
				f.setstring(Self,value)
				m=typeid.findmethod("Set"+name)
				If m
					m.invoke(Self,Null)
				EndIf
			EndIf
			Return 1
		EndIf
	EndMethod
	
EndType

Then to make actual settings I can use, I create an extended type like this:

SuperStrict

Import brl.reflection
Import "Settings.bmx"

Global configurationsettings:TConfigurationSettings=New TConfigurationSettings
configurationsettings.start()

Type TConfigurationSettings Extends TSettings {label="Configuration"}
	
	Field Trilinear_Filter:Int=1 {style=5}
	Field Anisotropic_Filter:Float {extra="1,16"}
	Field Texture_Quality:Int=4 {style=1 extra="Very low,Low,Medium,High,Very high"}
	Field Physics_Quality:Int=1 {style=1 extra="Fast,Normal,Exact"}
	Field Volumetric_Lighting:Int=0 {style=5}
	Field SSAO:Int=0 {style=5}
	
EndType

All I have to do is declare the field, and it is accessible by writing the configurationsettings.ssao variable, and the interface is automatically created. The setting is loaded, saved, and the user can edit it in a property grid gadget, and I don't have to manage any of that. When they edit the field with the property gadget, it is just automatically updated, and I can use that value right away without doing anything myself.

Next up I am going to link gadgets so they control variables directly, with no need to actually evaluate the events.

ziggy

(Posted 2009) [#2]

Yes, that's great. I remember someone did write also a XML serializer based on reflection, so the objects where stored using a XML based file format.

Arowx

(Posted 2009) [#3]

Yes reflection is cool!

I was working on a Reflection to database storage system got it to work with basic types.

But needed a lot more work to get ...
Arrays of objects
interlinked objects
binary objects e.g. images/databanks to work

to correctly retrieve/recall and update a database.

@Leadworkds What's with the {} curly brackets haven't seen them used with BMax before?

plash

(Posted 2009) [#4]

What's with the {} curly brackets haven't seen them used with BMax before?

That is metadata.

Space_guy

(Posted 2009) [#5]

Metadata is really cool and so is reflection.

Wiebo

(Posted 2009) [#6]

Interesting. How is metadata used here? Or in blitzmax in general?

EDIT: nm , I did some digging and found an example. I did not know you could add 'secret' messages to fields or methods. MUST you need reflection to access the metadata?

Jim Teeuwen

(Posted 2009) [#7]

Yes.

johnnyfreak

(Posted 2009) [#8]

are metadata like c# annotations?

JoshK

(Posted 2009) [#9]

And you thought you would never see {} in BlitzMax.

N	(Posted 2009) [#10]

are metadata like c# annotations?

No. Metadata is strictly keys and values. Values may be literal strings or numbers (can't use the value of a constant), keys may be any valid identifier (last I checked).

beanage

(Posted 2009) [#11]

Indeed, reflection is extremely powerful. Yet using it for an upcoming project, wrote some of a powerful skripting thing with it.. got all in all a little disencouraged when learning to use lua, but kept working on it.. maybe ending summer theres something ready to show..

BLaBZ

(Posted 2013) [#12]

Josh you're brilliant!

I downloaded your property grid awhile ago and added a bunch of new features and got the idea to do exactly this metadata+reflection! You always beat me to the punch with these great ideas!

I wish I knew then what I know now.