Monitor Refresh Rate Question

Strict
Graphics 800,600
Repeat
Cls
DrawText refresh_rate(),10,10
Flip
Delay 1000
Until KeyHit(KEY_ESCAPE)
End

Function refresh_rate()
	Local ms,fps
	Flip(1)
	ms=MilliSecs()
	Flip(1)
	fps=1000/(MilliSecs()-ms)
	Return fps
End Function

Strict

?Win32
	Import Pub.Win32
	
	Extern "Win32"
		Function ReleaseDC(hWnd, hdc)
	End Extern
	
	Local hWnd = GetDesktopWindow()
	Local hdc = GetDC(hWnd)
	If hdc = Null Then End
	
	Print
	Print "Desktop Refresh Rate = " + GetDeviceCaps(hdc, VREFRESH)
	
	ReleaseDC(hWnd, hdc)
?

End

VREFRESH - Windows NT only

Import chaos.desktopext

Strict
?Win32
	Import Pub.Win32
	Extern "Win32"
		Function ReleaseDC(hWnd, hdc)
	End Extern
	Global grefresh_rate=0
	Local hWnd = GetDesktopWindow()
	Local hdc = GetDC(hWnd)
	If hdc <> Null Then grefresh_rate=GetDeviceCaps(hdc, VREFRESH)
	ReleaseDC(hWnd, hdc)
?

Global gwindow=False
If graphics_set(800,600)=False Then Notify("Unable to set graphics mode 800x600");End
Global gbig_screen=False

Repeat
	display()
	Flip(1)
	WaitEvent()
	Local ed=EventData()
	Select EventID()
		Case EVENT_APPTERMINATE;End '****
		Case EVENT_KEYDOWN
			Select ed
				Case KEY_ESCAPE;End
				Case KEY_F;gbig_screen=Not gbig_screen;screen_set()
				Case KEY_W;gwindow=Not gwindow;screen_set()
			End Select
	End Select
Forever
End 

?MacOS
' use the maximum acceptable refresh rate
Function graphics_set(w,h)
	Local mode:TGraphicsMode,fmax=0,d
	If gwindow
		Graphics(w,h);Return True'****
	Else
		d=32 ' try depth 32 first
		For mode:TGraphicsMode=EachIn GraphicsModes()
			If mode.width=w And mode.height=h And mode.depth=d
				If mode.hertz>fmax Then fmax=mode.hertz
			End If
		Next
		If fmax=0
			' no luck so try depth 16
			d=16
			For mode:TGraphicsMode=EachIn GraphicsModes()
				If mode.width=w And mode.height=h And mode.depth=d
					If mode.hertz>fmax Then fmax=mode.hertz
				End If
			Next
		End If
		If fmax=0
			Return False'****
		Else
			Graphics(w,h,d,fmax);Return True'****
		End If
	End If
End Function
?Win32
' use the same refresh rate as the desktop if available
Function graphics_set(w,h)
	Local d,f,mode:TGraphicsMode
	If gwindow
		Graphics(w,h);Return True'****
	Else
		If grefresh_rate ' current refresh rate retrieved at start of program
			For mode:TGraphicsMode=EachIn GraphicsModes()
				d=mode.depth;f=mode.hertz
				If mode.width=w And mode.height=h And d=32 And f=grefresh_rate ' try 32 first
					Graphics w,h,d,f; Return True '****
				End If
			Next
			For mode:TGraphicsMode=EachIn GraphicsModes()
				d=mode.depth;f=mode.hertz
				If mode.width=w And mode.height=h  And d=16 And f=grefresh_rate ' now try 16
					Graphics w,h,d,f; Return True '****
				End If
			Next
		Else ' default to depth 16 and 60 Hz
			For mode:TGraphicsMode=EachIn GraphicsModes()
				d=mode.depth
				If mode.width=w And mode.height=h  And d=16
					Graphics w,h,d; Return True '****
				End If
			Next
		End If	
		Return False '****
	End If
End Function
?
	
Function display()
	Local s$
	SetClsColor 255,255,255;Cls;SetColor 0,0,0
	s$="width:"+GraphicsWidth()+" height:"+GraphicsHeight()
	s$=s$+" depth:"+GraphicsDepth()+" freq:"+GraphicsHertz()
	DrawText s$,10,10
End Function

Function screen_set()
	If gbig_screen
		graphics_set(1024,768)
	Else
		graphics_set(800,600)
	End If
End Function