Opening a File with a specific Program

BlitzMax Forums/BlitzMax Programming/Opening a File with a specific Program

Hardcoal

(Posted March) [#1]

Hi.. Im trying to open a file, lets say for example a Note.txt with a specific program..

How can I do that via blitzmax code?

I know about OpenURL..but this only indicates a file to be opened
but it doesnt define with which to open with..

Rergards

Hardcoal

(Posted March) [#2]

Ok ive managed to do so by using system_ like this example..

system_("D:\MyFiles\Programming\BlitzMax\HCGameEngine\Externals\KeyNote\keynote.exe D:\MyFiles\Programming\BlitzMax\HCGameEngine\Docs\docs.knt")

but now my main program gets stuck for some reason..
any exaplantion?

Tnx

grable

(Posted March) [#3]

Since system_() is an implementation of system(), a libc function. It has to follow its spec and share its console AND wait for the process to terminate, giving you the process exit code in return.
To get around that, you can use CreateProcess in PUB.FreeProcess, though it does way more than you need.

Heres some win32 code doing basically the same thing as system_() just without waiting for the process.

Const DETACHED_PROCESS:Int = $00000008		' dont inherit parent console
Const CREATE_NEW_CONSOLE:Int = $00000010	' same as DETACHED_PROCESS in addition to creating a new console
Const CREATE_DEFAULT_ERROR_MODE:Int = $04000000	' only here because system_() uses it

' returns True on success, False otherwise
Function Exec:Int( cmd:String, flags:Int = 0)
	Type TProcessInformation
	  Field Process:Int
	  Field Thread:Int
	  Field ProcessId:Int
	  Field ThreadId:Int
	EndType
	
	Type TStartupInfo
	  Field Size:Int
	  Field Reserved0:Short Ptr
	  Field Desk:Short Ptr
	  Field Title:Short Ptr
	  Field X:Int
	  Field Y:Int
	  Field XSize:Int
	  Field YSize:Int
	  Field XCountChars:Int
	  Field YCountChars:Int
	  Field FillAttribute:Int
	  Field Flags:Int
	  Field ShowWindow:Short
	  Field Reserved1:Short
	  Field Reserved2:Byte Ptr
	  Field StdInput:Int
	  Field StdOutput:Int
	  Field StdError:Int
	EndType

	Extern "Win32"
		Function CreateProcessW:Int( appname$w, cmdline$w, procattrs:Byte Ptr, threadattrs:Byte Ptr, inherit:Int, createflags:Int, env$w, currdir$w, startinfo:Byte Ptr, procinfo:Byte Ptr)
		Function CloseHandle( handle:Int)
	EndExtern
	
	Local startinfo:TStartupInfo = New TStartupInfo
	startinfo.Size = SizeOf(TStartupInfo)
	Local procinfo:TProcessInformation = New TProcessInformation
	
	If CreateProcessW( Null, cmd, Null,Null, 0, CREATE_DEFAULT_ERROR_MODE | flags, Null,Null, startinfo,procinfo)
		CloseHandle(procinfo.Process)
		CloseHandle(procinfo.Thread)
		Return True
	EndIf
	Return False
EndFunction

Hardcoal

(Posted March) [#4]

Tnx Grable