Using OpenSimplex Noise in BMax

BlitzMax Forums/BlitzMax Programming/Using OpenSimplex Noise in BMax

Krischan

(Posted 2016) [#1]

As Simplex Noise has a license restriction some guys created OpenSimplex in C++ a while ago but I don't know how to include it into Blitzmax and need some assistance here.

Here is the source on Github: OpenSimplex, see the lib subfolder.

There are strange language constructs I don't know like "struct osn_contect *ctx":
double open_simplex_noise2(struct osn_context *ctx, double x, double y);
double open_simplex_noise3(struct osn_context *ctx, double x, double y, double z);
double open_simplex_noise4(struct osn_context *ctx, double x, double y, double z, double w);

I would like to include it into this test code like I did with a different C++ variant of 4D Simplex Noise which can be downloaded here: simplexnoise.cpp

SuperStrict

Framework sidesign.minib3d
Import brl.pngloader

Import "simplexnoise.cpp"

Extern "C"

	Function octave_noise_2d:Float(octaves:Float, persistance:Float, Scale:Float, x:Float, y:Float)
	Function octave_noise_3d:Float(octaves:Float, persistance:Float, Scale:Float, x:Float, y:Float, z:Float)
	Function octave_noise_4d:Float(octaves:Float, persistence:Float, Scale:Float, x:Float, y:Float, z:Float, w:Float)
		
End Extern


Graphics3D 2048, 1024, 32, 2

Const seed:Int = 1
Const Size:Int = 256
Const Octaves:Int = 5
Const persistence:Float = 0.9
Const scale:Float = 1

Global width:Int = size
Global height:Int = size / 2

Local image:TPixmap = CreatePixmap(width, height, PF_RGB888)

'SavePixmapPNG(image, "planet.png", 0)

Local w:Float = 0.0

While Not AppTerminate()

	' ----------------------------------------------------------------------------
	' key strokes
	' ----------------------------------------------------------------------------
	If KeyHit(KEY_ESCAPE) Then End
	
	RenderWorld
	
	BeginMax2D()

		Local ms:Int = MilliSecs()
		
		For Local y:Int = 0 To height - 1
		
			For Local x:Int = 0 To width - 1
			
				Local theta:Float = Normalize(x, 0, width - 1, 0, 360)
				Local phi:Float = Normalize(y, 0, height - 1, 0, 180)
				
				Local x3d:Float = (Cos(theta) * Sin(phi))
				Local y3d:Float = (Cos(phi))
				Local z3d:Float = (Sin(theta) * Sin(phi))
		
				Local p:Float = octave_noise_4d(octaves, persistence, Scale, x3d, y3d, z3d, w)
										
				p = Sin(p * 180)
					
				Local h:Int = (1 + p) * 127.5
									
				If h > 255 Then h = 255 Else If h < 0 Then h = 0
						
				WritePixel(image, x, y, CombineRGB(h, h, h))
				
			Next
		
		Next
		
		w:+0.01
		
		ms = MilliSecs() - ms
		
		SetColor 255, 255, 255
		DrawPixmap(image, 0, 0)
		
		SetColor 255, 0, 0
		DrawText ms, 0, 0
		
	EndMax2D()
	
	Flip
	
Wend
	
End

Function Normalize:Float(value:Float = 128.0, value_min:Float = 0.0, value_max:Float = 255.0, norm_min:Float = 0.0, norm_max:Float = 1.0)

	' normalize	
	Local result:Float=((value-value_min)/(value_max-value_min))*(norm_max-norm_min)+norm_min

	Return result
	
End Function

Function DBInt:Float(x:Float)

	If x >= 0 Then Return Floor(x) Else Return Ceil(x)
	
End Function

Function CombineRGB:Int(r:Int, g:Int, b:Int)

	Return b | (g Shl 8) | (r Shl 16)
	
End Function