Serious Key Reader - Source Included

BlitzMax Forums/BlitzMax Programming/Serious Key Reader - Source Included

dw817

(Posted 2016) [#1]

dw817

(Posted 2016) [#2]

This is really a bit of a nightmare, but it does work perfectly now.

Try SHIFT keystrokes, CTRL, ALT, CAPS LOCK, NUM LOCK, and arrow keys with Testplay flag on.

Despite what it can do, I would be curious if any of you find a way of improving this so the code is not so lengthy yet still uses createwindow() as the main graphics driver.

One really tricky thing I got working was to write the code so it would disregard Windows' own Repeat key handler and use solely the custom one in this code.

'    ______________________________________
'   //                                   //
'  //    Serious Key Reader v3.8        //
' //    Written by David W - 01/15/16  //
'//___________________________________//

' What's up ?? Changed ShiftK$ so the source can be ported
' Online. Added custom repeat key both for delay and key
' repeat speed.

Strict
Import MaxGui.Drivers

Global deskrect[4]
GetDesktopArea(deskrect) '<- Get Desktop size

Local window:TGadget
Local mainview:tgadget
SetGraphicsDriver(GLMax2DDriver()) ' no problems
window=createwindow("",deskrect[0],deskrect[1],deskrect[2],deskrect[3],,0)
Global mx=clientwidth(window),my=clientheight(window),mk
mainview=createcanvas(0,0,mx,my,window,0)
activategadget mainview
SetGraphics canvasgraphics(mainview)
activategadget mainview
SetBlend alphablend
SetScale 2,2
Global testplay=0 ' set to one for repeat arrow movements
Global key:Byte[256],k$,lastkey,shiftkey,ctrlkey,altkey,capslock
Global numlock,timerkey,t$
Global rawkey$=".1bes.70f1.71f2.72f3.73f4.74f5.75f6.76f7.77f8.78f9.79f0.7af!.7bf@.300 .311 .322 .333 .344 .355 .366 .377 .388 .399 .bd- .bb= .08bs.24ho.23en.6fn/.6an*.6dn-.c0` .09ta.41a .42b .43c .44d .45e .46f .47g .48h .49i .4aj .4bk .4cl .4dm .4en .4fo .50p .51q .52r .53s .54t .55u .56v .57w .58x .59y .5az .db[ .dd] .dc\ .2ede.21pu.24ho.26up.21pu.6bn+.ba; .de' .0dcr.22pd.25lf.0cn5.27rt.bc, .be. .bf/ .23en.28dn.22pd.2din.20  .600 .611 .622 .633 .644 .655 .666 .677 .688 .699 .6e. "
Global shiftk$=".`7e.121.240.323.424.525.65e.726.82a.928.029.-5f.=2b.[7b.]7d.\7c.;3a.'22.,3c..3e./3f"
Global delaykey=32 ' number of cycles before repeat
Global repeatkey=3 ' speed of repeat, 1 is fastest

Repeat
  Cls
  nano ' call our key reader
  If k$="bs" ' backspace, so take out last viewed character
    t$=fnd$(t$)
  Else
    t$:+k$ ' otherwise add it to total
    If Len(t$)>60 Then t$="" ' too far across, clear the line
  EndIf
  DrawText t$+"_",0,0
  Flip
Until k$="es" ' exit on ESCAPE key

Function zz()
  End
EndFunction

Function nano()
Local ce,cd,c,i,cx,cy
  k$=""
  If lastkey>0 Then timerkey:+1
  If key[lastkey]>0 And timerkey>delaykey And timerkey Mod repeatkey=0
    cd=lastkey
    c=Instr(rawkey$,"."+Lower$(Right$(Hex$(cd),2))) ' search for keystroke
    If c
      k$=Trim$(Mid$(rawkey$,c+3,2)) ' return matching stroke
      If capslock And Len(k$)=1 Then k$=Upper$(k$) ' if CAPS and normal key, then uppercase it
      If k$="" Then k$=" " ' if blank, it is SPACEBAR
    EndIf
  EndIf
  If PollEvent()
    ce=CurrentEvent.id
    cd=CurrentEvent.data
    cx=EventX()
    cy=EventY()
    If ce=event_keydown
      If cd>=160 And cd<=165 ' key is special
        If cd=160 Or cd=161 Then shiftkey=1
        If cd=162 Or cd=163 Then ctrlkey=1
        If cd=164 Or cd=165 Then altkey=1
      ElseIf cd=20 And ce=event_keydown
        capslock=1-capslock ' caps lock is also special
      ElseIf cd=144 And ce=event_keydown
        numlock=1-numlock
      Else
        key[cd]=1
        lastkey=cd
        c=Instr(rawkey$,"."+Lower$(Right$(Hex$(cd),2))) ' search for keystroke
        If c
          k$=Trim$(Mid$(rawkey$,c+3,2)) ' return matching stroke
          If capslock And Len(k$)=1 Then k$=Upper$(k$) ' if CAPS and normal key, then uppercase it
          If k$="" Then k$=" " ' if blank, it is SPACEBAR
        EndIf
      EndIf
    ElseIf ce=event_keyup
      timerkey=0
      lastkey=0
      If cd=160 Or cd=161 Then shiftkey=0 ' turn off keys if not held
      If cd=162 Or cd=163 Then ctrlkey=0
      If cd=164 Or cd=165 Then altkey=0
      For i=0 To 255
        If i<>20 And (i<160 Or i>165) Then key[i]=0 ' erase all except special keys
      Next
      k$=""
    ElseIf ce=event_windowclose Or ce=event_appterminate
      zz
    ElseIf ce=event_mousemove
      mx=EventX()
      my=EventY()
    ElseIf ce=event_mousedown
      mk=cd
    ElseIf ce=event_mouseup
      mk=0
    ElseIf ce=event_appsuspend Or ce=event_mouseleave
      mk=0
      For i=0 To 255
        key[i]=0
      Next
      ce=0
      Repeat
        If PollEvent()
          ce=CurrentEvent.id
        EndIf
        Delay 100
      Until ce=event_mouseenter Or ce=event_appresume
      k$=""
      lastkey=0
      Return
    EndIf
  EndIf
  If shiftkey And k$>"" ' shift key, change character if matched
    If Len(k$)=2
      k$="#"+k$
    ElseIf k$>="a" And k$<="z"
      k$=Upper$(k$)
    Else
      c=Instr(shiftk$,"."+k$)
      If c Then k$=Chr$(val("$"+Mid$(shiftk$,c+2)))
    EndIf
  EndIf
  If ctrlkey And k$>"" Then k$="^"+k$ ' add carat for ctrl key
  If altkey And k$>"" Then k$="@"+k$ ' add at sign for alt key
  If testplay
    If key[37] Then k$="lf" ' if testplay mode, these keys
    If key[38] Then k$="up" ' will always read on if held
    If key[39] Then k$="rt"
    If key[40] Then k$="dn"
  EndIf
EndFunction

Function fnc$(a$,b) ' return single character from string
  Return Mid$(a$,b,1)
EndFunction

Function fnd$(a$) ' return string minus last character
  Return Left$(a$,Len(a$)-1)
EndFunction

Function val(t$) ' easy return value from string
  Return t$.toint()
EndFunction

Function getdesktoparea(lprect:Int Ptr) ' get desktop area
  systemparametersinfoa(spi_getworkarea,0,lprect,0)
End Function

Extern "Win32" ' library for desktop area
  Function SystemParametersInfoA:Int(action:Int, param:Int, param2:Byte Ptr, winini:Int)
EndExtern

Questions, compliments, comments, or kerosene, take your pick and lemme know what you think !