Any Tiled .tmx Parser for BlitzMax?

BlitzMax Forums/BlitzMax Programming/Any Tiled .tmx Parser for BlitzMax?

braxton

(Posted 2015) [#1]

Does anyone have a sample, snippet or possibly a module to share that can read Tiled's xml .tmx map format (mapeditor.org) maps in BlitzMax?

I have been trying to convert some Monkey-X code but cannot seem to get it working :/

col	(Posted 2015) [#2]

Hiya,

Brucey has XML parsing module(s) here

Does that help?

braxton

(Posted 2015) [#3]

Hi col,

Thanks for your reply, I am indeed using Brucey's awesome bah.libxml to parse the xml map file, the problem appears to be interpreting the various nodes within the xml as they appear to use different methods depending on the version of tiled used, some have data exported within the xml as csv (which I can handle albeit crudely) while newer versions use base64+zlib data and I am not sure how to handle this to decompress the map to an array let alone handle multiple tilesets, which is why I have been looking for some code as a starting point.

I thought for sure that someone else might have encountered and tackled these issues as it is such a versatile tile map editor.

I did initially try to convert these c++ libs to BlitzMax

github.com/baylej/tmx ; github.com/jube/libtmx ; github.com/halsafar/libtmx-parser

without any luck though, the needed glue code is out of my depth, maybe it's just me and xml but it is all a bit over my head it seems :/

grable

(Posted 2015) [#4]

Does it have to be converted into BlitzMax?

github.com/baylej/tmx is pure C and even has a binary release, so if you dont mind extra dlls it is the easiest to interface with.

No need to reinvent the wheel ;)

EDIT: I Hacked together a bare bones module using the binary release if your interested:
tmx.bmx

Module GRB.tmx

SuperStrict

Import "tmx/lib/libtmx.dll.a"

Import "tmx_glue.c"
Include "tmx_glue.bmx"

Const TMX_FLIPPED_HORIZONTALLY:Int = $80000000
Const TMX_FLIPPED_VERTICALLY:Int = $40000000
Const TMX_FLIPPED_DIAGONALLY:Int = $20000000
Const TMX_FLIP_BITS_REMOVAL:Int = $1FFFFFFF

Extern "C"
	Global tmx_alloc_func:Byte Ptr( address:Byte Ptr, size:Int)
	Global tmx_free_func( address:Byte Ptr)
	
	Global tmx_img_load_func:Byte Ptr( path$z)
	Global tmx_img_free_func( address:Byte Ptr)
EndExtern

' enum tmx_map_orient
Const TMX_O_NONE:Int = 0
Const TMX_O_ORT:Int = 1
Const TMX_O_ISO:Int = 2
Const TMX_O_STA:Int = 3

' enum tmx_map_renderorder
Const TMX_R_NONE:Int = 0
Const TMX_R_RIGHTDOWN:Int = 1
Const TMX_R_RIGHTUP:Int = 2
Const TMX_R_LEFTDOWN:Int = 3
Const TMX_R_LEFTUP:Int = 4

' enum tmx_layer_type
Const TMX_L_NONE:Int = 0
Const TMX_L_LAYER:Int = 1
Const TMX_L_OBJGR:Int = 2
Const TMX_L_IMAGE:Int = 3

' enum tmx_shape
Const TMX_S_NONE:Int = 0
Const TMX_S_SQUARE:Int = 1
Const TMX_S_POLYGON:Int = 2
Const TMX_S_POLYLINE:Int = 3
Const TMX_S_ELLIPSE:Int = 4
Const TMX_S_TILE:Int = 5

Extern "C"
	' struct tmx_property
	Type TmxProperty
		'Field Name:Byte Ptr
		Field Value:Byte Ptr
		Field NextProp:TmxProperty
	EndType
	
	' struct tmx_image
	Type TmxImage
		'Field Source:Byte Ptr
		Field Trans:Int ' bytes: RGB
		Field UsesTrans:Int
		Field Width:Int
		Field Height:Int
		Field ResourceImage:Byte Ptr
	EndType
	
	' struct tmx_tile
	Type TmxTile
		'Field ID:Int
		Field Image:TmxImage
		Field Properties:TmxProperty
		Field NextTile:TmxTile
	EndType
	
	' struct tmx_tileset
	Type TmxTileset
		'Field FirstGID:Int
		Field Name:Byte Ptr
		Field TileWidth:Int
		Field TileHeight:Int
		Field Spacing:Int
		Field Margin:Int
		Field XOffset:Int
		Field YOffset:Int
		Field Image:TmxImage
		Field Properties:TmxProperty
		Field Tiles:TmxTile
		Field NextTileset:TmxTileset
	EndType
	
	' struct tmx_object
	Type TmxObject
		'Field Name:Byte Ptr
		Field Shape:Int ' enum tmx_shape
		Field X:Double
		Field Y:Double
		Field Width:Double
		Field Height:Double
		Field GID:Int
		Field Points:Double Ptr Ptr
		Field PointsLen:Int
		Field Visible:Int
		Field Rotation:Double
		Field Properties:TmxProperty
		Field NextObject:TmxObject
	EndType
	
	' struct tmx_layer
	Type TmxLayer
		'Field Name:Byte Ptr
		Field Color:Int ' bytes: RGB
		Field Opacity:Double
		Field Visible:Int
		Field XOffset:Int
		Field YOffset:Int
		Field LayerType:Int ' enum tmx_layer_type
		Field LayerContent:Byte Ptr ' union { int32_t*, tmx_object*, tmx_image* }
		Field UserData:Byte Ptr
		Field NextLayer:TmxLayer
	EndType
	
	' struct tmx_map
	Type TmxMap
		'Field Orient:Int ' enum tmx_map_orient
		Field Width:Int
		Field Height:Int
		Field BackgroundColor:Int
		Field RenderOrder:Int ' enum tmx_map_renderorder
		Field Properties:TmxProperty
		Field Tilesets:TmxTileset
		Field Layers:TmxLayer
	EndType
	
	Function tmx_load:TmxMap( path$z)
	Function tmx_map_free( map:TmxMap)
	
	Function tmx_get_tileset:TmxTileset( map:TmxMap, gid:Int, x:Int Var, y:Int Var)
	Function tmx_get_tile:TmxTile( map:TmxMap, gid:Int)
EndExtern


' enum tmx_error_codes
Const TMX_E_NONE:Int = 0
Const TMX_E_UNKN:Int = 1
Const TMX_E_INVAL:Int = 2
Const TMX_E_ALLOC:Int = 8
Const TMX_E_ACCESS:Int = 10
Const TMX_E_NOENT:Int = 11
Const TMX_E_FORMAT:Int = 12
Const TMX_E_ENCCMP:Int = 13
Const TMX_E_FONCT:Int = 16
Const TMX_E_BDATA:Int = 20
Const TMX_E_ZDATA:Int = 21
Const TMX_E_XDATA:Int = 22
Const TMX_E_JDATA:Int = 23
Const TMX_E_CDATA:Int = 24
Const TMX_E_MISSEL:Int = 30

Extern "C"
	Global tmx_errno:Int ' enum tmx_error_codes
	
	Function tmx_perror( msg$z)
	Function tmx_strerror$z()
EndExtern

tmx_glue.bmx

Extern "C"
	Function tmx_property_name$z( prop:TmxProperty)
	Function tmx_property_value$z( prop:TmxProperty)
	
	Function tmx_image_source$z( img:TmxImage)
	
	Function tmx_tile_id:Long( tile:TmxTile)
	
	Function tmx_tileset_firstgid:Long( set:TmxTileset)
	
	Function tmx_object_name$z( obj:TmxObject)
	
	Function tmx_layer_name$z( lay:TmxLayer)	
	Function tmx_layer_gids:Int Ptr( lay:TmxLayer) = "tmx_layer_content"
	Function tmx_layer_objects:TmxObject( lay:TmxLayer) = "tmx_layer_content"
	Function tmx_layer_images:TmxImage( lay:TmxLayer) = "tmx_layer_content"
	
	Function tmx_map_orient:Int( map:TmxMap)
EndExtern

tmx_glue.c


#include "tmx/include/tmx.h"

// tmx_property
char* tmx_property_name( tmx_property* prop) {
	return prop->name;
}

char* tmx_property_value( tmx_property* prop) {
	return prop->value;
}

// tmx_image
char* tmx_image_source( tmx_image* img) {
	return img->source;
}

// tmx_tile
int64_t tmx_tile_id( tmx_tile* tile) {
	return (int64_t)tile->id;
}

// tmx_tileset
int64_t tmx_tileset_firstgid( tmx_tileset* set) {
	return (int64_t)set->firstgid;
}

// tmx_object
char* tmx_object_name( tmx_object* obj) {
	return obj->name;
}

// tmx_layer
char* tmx_layer_name( tmx_layer* lay) {
	return lay->name;
}

int32_t* tmx_layer_content( tmx_layer* lay) {
	return lay->content.gids;
}

// tmx_map
enum tmx_map_orient tmx_map_orient( tmx_map* map) {
	return map->orient;
}

Note: NOT tested!

braxton

(Posted 2015) [#5]

Hi grable, thank you so much I really do appreciate you taking the time to look at this, and for what you have done so far it is really awesome!

It definitely does not have to be in BlitzMax, I was only hoping to be able to access Tiled's .tmx maps from within BlitzMax using whatever libraries, modules and or code I could find or create.

I really do not mind using dlls at all, it is a lot better than reinventing the wheel, especially as Tiled is evolving with each new version.

I tried using "win32" instead of "C" among other things and wondered why it wasn't working right when I attempted wrapping the libraries. I certainly never got as far as you did in such a short space of time, and it has taken me a lot longer.

Your glue code is very impressive as is Brucey's. I have been trying my hand at wrapping nih.at/libzip as an exercise but it is not quite there yet.

I still have a lot to learn with regards to wrapping but it is what makes BlitzMax great in my opinion and expandable. I am going to study this carefully. I really am very grateful for what you have done.