Compile error "Undefined symbols for architecture"

BlitzMax Forums/BlitzMax Programming/Compile error "Undefined symbols for architecture"

Pineapple

(Posted 2015) [#1]

I've been working on this code for a little while and now, without apparent cause, I get this error when I attempt to compile. I'm using 1.50 on OSX Mavericks. Help?

Compiling:Collection.bmx
Compiling:CollectionIndexed.bmx
Linking:CollectionIndexed
Undefined symbols for architecture i386:
  "__7", referenced from:
      __bb_CollectionIndexed_set in CollectionIndexed.bmx.console.release.macos.x86.o
      __bb_CollectionIndexed_get in CollectionIndexed.bmx.console.release.macos.x86.o
      __bb_CollectionIndexed_push in CollectionIndexed.bmx.console.release.macos.x86.o
      __bb_CollectionIndexed_pop in CollectionIndexed.bmx.console.release.macos.x86.o
      __bb_CollectionIndexed_insert in CollectionIndexed.bmx.console.release.macos.x86.o
      __bb_CollectionIndexed_remove in CollectionIndexed.bmx.console.release.macos.x86.o
ld: symbol(s) not found for architecture i386
clang: error: linker command failed with exit code 1 (use -v to see invocation)
Build Error: Failed to link /_/_/_/_/collect/CollectionIndexed[Finished in 0.5s with exit code 255]
[cmd: ['/Applications/BlitzMax150/bin/bmk', 'makeapp', '-r', '-a', '-t', 'console', '-x', 'CollectionIndexed.bmx']]
[dir: /_/_/_/_/collect]

CollectionIndexed.bmx, which fails to compile:

superstrict
import "Collection.bmx"

type CollectionIndexed extends Collection abstract
    ' get/set at index
    method set:Collection( loc%, value:object )
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    method get:object( loc% )
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    
    ' push/pop highest index
    method push:Collection( value:object )
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    method pop:object()
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    
    ' insert/remove at arbitrary index
    method insert:Collection( loc%, value:object )
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    method remove:object( loc% )
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    
    method extend:Collection( other:Collection )
        ' compiler doesn't like using eachin here for some reason
        local itr:Enumerator = other.enum()
        while itr.hasnext()
            push( itr.nextitem() )
        wend
        return self
    end method
    method contains%( value:object )
        local itr:Enumerator = enum()
        while itr.hasnext()
            if itr.nextitem() = value return true
        wend
        return false
    end method
    method count%( value:object )
        local sum% = 0
        local itr:Enumerator = enum()
        while itr.hasnext()
            sum :+ itr.nextitem() = value
        wend
        return sum
    end method
    
    ' get string representation
    method tostring$()
        return csv()
    end method
    method csv$( delimiter$ = "," )
        local first% = true
        local str$ = ""
        local itr:Enumerator = enum()
        while itr.hasnext()
            if not first str :+ delimiter
            first = false
            str :+ itr.nextitem().tostring()
        wend
        return str
    end method
end type

' enumerate over the items contained within CollectionIndexed object
type EnumeratorIndexed extends Enumerator
    field target:CollectionIndexed
    field index%
    field bound%
    method init:EnumeratorIndexed( t:CollectionIndexed, b% )
        target = t
        bound = b
        return self
    end method
    method hasnext%()
        return index < bound
    end method
    method nextitem:object()
        local value:object = target.get( index )
        index :+ 1
        return value
    end method
end type

And Collection.bmx, the singular import, which compiles without incident:

superstrict

' base collection class
type Collection abstract

    ' object to throw when attempting to call a method that isn't implemented for some collection
    const EXCEPTION_UNIMPLEMENTED:object = "operation is not applicable to this class"

    ' return an enumerator for the items in the collection
    method enum:Enumerator()
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    ' clear all values from the collection
    method clear:Collection()
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    ' returns true if the collection is empty, false otherwise
    method empty%()
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    ' insert all items from another similar collection into this one
    method extend:Collection( other:Collection )
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    ' verify whether a value appears in the collection
    method contains%( value:object )
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    ' count the number of times a specified value appears in the collection
    method count%( value:object )
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    ' create a shallow copy of a Collection
    method copy:Collection()
        throw EXCEPTION_UNIMPLEMENTED; return null
    end method
    
end type

' base enumerator class (every collection class should have at least one accompanying enumerator)
type Enumerator abstract
    method hasnext%() abstract
    method nextitem:object() abstract
end type

Brucey

(Posted 2015) [#2]

Oh dear, you're building it on a Mac, aren't you? :-/

Pineapple

(Posted 2015) [#3]

I am indeed. This is the first time I've run into any such confounding issues, though.

Brucey

(Posted 2015) [#4]

Well done. You've discovered a bug in the compiler (bcc) !!

The issue is because of this line :

const EXCEPTION_UNIMPLEMENTED:object = "operation is not applicable to this class"

You should probably define it as a String.

On Linux, the error (in FASM) is :

/path/.bmx/CollectionIndexed.bmx.console.release.linux.x86.s [199]:
_3:
error: symbol already defined.
Build Error: Failed to assemble /path/.bmx/CollectionIndexed.bmx.console.release.linux.x86.s
Process complete

... in other news, my compiler also breaks. Thanks for giving me something to do ;-)

Pineapple

(Posted 2015) [#5]

Ah! Thanks for spotting that. How come it broke CollectionIndexed but not Collection?

Brucey

(Posted 2015) [#6]

The issue appears in the interface (.i) file for Collection that is generated by bcc :

...
Collection^Object{
EXCEPTION_UNIMPLEMENTED:Object="_3"
...

The interface file is loaded by bcc when compiling CollectionIndexed.bmx, providing it will all the Type and function definitions it needs to know about.

The "_3" is a reference to a string pointer in the generated Collection source. This of course, is not accessible outside of the compiled Collection .o file...
Hence you get interesting "number" errors when the generator tries to access imported references that don't exist.

Ooer!