Moving Cursor /w Zoom and Scroll

BlitzMax Forums/BlitzMax Programming/Moving Cursor /w Zoom and Scroll

FBEpyon

(Posted 2014) [#1]

***Double Post***

FBEpyon

(Posted 2014) [#2]

Hello,

Can someone help me fix this?

I'm trying to capture the location of an tile that has been moved and zoomed...

Here is me prototype of what I'm trying to do, as you can see the cursor isn't lining up :(


Strict

Global z:Float = 1
Global orgx:Float, orgy:Float

Type Map

	Field data:Int[]
	Field grid:Int[]
	Field x:Int, y:Int
	Field width:Int, height:Int
	Field offx:Int, offy:Int
	Field zoom:Float
	
	Method Init:Map(x:Int, y:Int)
	
		Self.x = x
		Self.y = y
		Self.width = 120
		Self.height = 80
		Self.zoom = 1
		Self.data = New Int[160 + 80 * 160]
		Self.grid = New Int[160 + 80 * 160]
		
		For Local gx:Int = 0 Until Self.width
		For Local gy:Int = 0 Until Self.height
			Self.SetGrid(gx, gy, Rnd(2))
		Next
		Next
		
		Return Self
	
	End Method
	
	Method Render:Map()
	
		SetScale Self.zoom, Self.zoom
	
		For Local x:Int = 0 Until Self.width
		For Local y:Int = 0 Until Self.height
			If grid[x + y * Self.width] = 1
				DrawRect ( (Self.x+(x*16))*Self.zoom, (Self.y+(y*16))*Self.zoom, (16), (16) )
			EndIf
		Next
		Next
		
		SetScale 1, 1
	
	End Method
	
	Method GetTile:TMap(nx:Float Var, ny:Float Var, tx:Int, ty:Int)
		nx = ((Self.x+(tx*16))*Self.zoom)
		ny = ((Self.y+(ty*16))*Self.zoom)
	End Method
	
	Method Move:Map(x:Int, y:Int)
		Self.x :+ x
		Self.y :+ y
	End Method
	
	Method SetGrid:Map(x:Int, y:Int, v:Int)
		Self.grid[x + y * Self.width] = v
		Return Self
	End Method
	
	Method SetZoom:Int(v:Float)
		If Self.zoom >= 0.5 And Self.zoom <= 5.0
			Self.zoom :+ v
		EndIf
		If Self.zoom < 0.5
			Self.zoom = 0.5
		EndIf
		If Self.zoom > 5.0
			Self.zoom = 5.0
		EndIf
		DebugLog zoom
	End Method
	
	Method GetZoom:Int(z:Float Var)
		Return Self.zoom
	End Method

End Type

Global m:Map = New Map.Init(-60*16,-40*16)

Graphics 1280,720

While Not KeyHit(KEY_ESCAPE)

	'SetOrigin (GraphicsWidth()*0.5, GraphicsHeight()*0.5)

	If KeyDown(KEY_A) Then m.move(2,0)
	If KeyDown(KEY_D) Then m.move(-2, 0)
	If KeyDown(KEY_W) Then m.move(0, 2)
	If KeyDown(KEY_S) Then m.move(0, -2)
	
	z = Float(MouseZSpeed())
	
		If z > 0 Or z < 0 Then m.SetZoom(z*0.2)
		
	MouseZSpeed()

	Cls
	
		SetOrigin (GraphicsWidth()*0.5, GraphicsHeight()*0.5)
	
		m.Render()
		
		'SetOrigin(0,0)
		
		m.GetTile(orgx, orgy, MouseX()/GraphicsWidth(), MouseY())
		
		SetScale m.zoom, m.zoom
				
		SetColor 255,0,255
			DrawRect ( orgx, orgy, 16, 16 )
			'DebugLog (m.x+(MouseX()/16)*16)
		SetColor 255,255,255
		
		SetScale 0,0
		
	Flip

Wend

EndGraphics
End

** UPDATED THE CODE A BIT, BUT STILL DOESN'T WORK **

Midimaster

(Posted 2014) [#3]

I think, it is like this:

Method GetTile:TMap(nx:Float Var, ny:Float Var, tx:Int, ty:Int)
		nx = tx/Self.zoom-Self.X
		ny = ty/Self.zoom-Self.Y
End Method

FBEpyon

(Posted 2014) [#4]

Tried that, it doesn't work.. :(

:UPDATED:

So I tried a few other things, Distance formulas which seem to work, but would like to have another option for displaying the cursor along the tile being selected.

Midimaster

(Posted 2014) [#5]

The function is working...

Strict

Global z:Float = 1
Global orgx:Float, orgy:Float

Type Map

	Field grid:Int[]
	Field x:Int, y:Int
	Field width:Int, height:Int
	Field offx:Int, offy:Int
	Field zoom:Float, SelectedX%, SelectedY%
	
	Method Init:Map(x:Int, y:Int)
	
		Self.x = x
		Self.y = y
		Self.width = 30
		Self.height = 30
		Self.zoom = 2
		Self.grid = New Int[width*height]
		
		For Local gx:Int = 0 Until Self.width
			For Local gy:Int = 0 Until Self.height
				Self.SetGrid(gx, gy, Rnd(2))
			Next
		Next
		
		Return Self
	
	End Method



	
	Method Render:Map()
	
		SetScale Self.zoom, Self.zoom
		SetColor 255,255,255
		For Local x:Int = 0 Until Self.width
			For Local y:Int = 0 Until Self.height
				If grid[x + y * Self.width] = 1
					DrawRect ( (Self.x+(x*16))*Self.zoom, (Self.y+(y*16))*Self.zoom, (16), (16) )
				EndIf
				If x=SelectedX And y=SelectedY
					SetColor 0,255,0
					DrawRect ( (Self.x+(x*16))*Self.zoom, (Self.y+(y*16))*Self.zoom, (16), (16) )
					SetColor 255,255,255
				EndIf
			Next
		Next
		SetScale 1, 1
	End Method



	
	Method GetTile:TMap(nx:Float Var, ny:Float Var, tx:Int, ty:Int)
			nx = (tx/zoom)-Self.X
			ny = (ty/zoom)-Self.Y
			SelectedX = nx/16
			SelectedY = ny/16
	End Method


	
	Method Move:Map(x:Int, y:Int)
		Self.x :+ x
		Self.y :+ y
	End Method


	
	Method SetGrid:Map(x:Int, y:Int, v:Int)
		Self.grid[x + y * Self.width] = v
	End Method


	
	Method SetZoom(v:Float)
		zoom :+ v
		If zoom < 0.5
			zoom = 0.5
		ElseIf zoom > 5.0
			zoom = 5.0
		EndIf
	End Method


	



End Type

Global m:Map = New Map.Init(-160,-160)
'Global m:Map = New Map.Init(0,0)

Graphics 800,600
Global FPS:TTimer=CreateTimer(10)


While Not KeyHit(KEY_ESCAPE)

	If KeyDown(KEY_A) Then m.move(2,0)
	If KeyDown(KEY_D) Then m.move(-2, 0)
	If KeyDown(KEY_W) Then m.move(0, 2)
	If KeyDown(KEY_S) Then m.move(0, -2)
	
	z = Float(MouseZSpeed())
	If z > 0 Or z < 0 Then m.SetZoom(z*0.2)

	Cls
		SetOrigin (GraphicsWidth()*0.5, GraphicsHeight()*0.5)
		m.Render()
		m.GetTile(orgx, orgy, MouseX()-GraphicsWidth()*0.5, MouseY()-GraphicsHeight()*0.5)
		SetOrigin 0,0
		SetColor 255,0,0
		DrawText  "X=" +  orgx  + " Y= " +  orgy,100,100
	Flip 0
	WaitTimer FPS
Wend

Additional I would suggest not to work with two offset systems like "Self.X" and "GraphicsWidth()/2". Self.X alone is enough to do the job.

	Cls
		m.Render()
		m.GetTile(orgx, orgy, MouseX(), MouseY() )
		SetColor 255,0,0
		DrawText  "X=" +  orgx  + " Y= " +  orgy,100,100
	Flip 0

Do you know, that you do not need all this "Self" inside Methods? See my version of SetZoom() function...

	Method SetZoom(v:Float)
		zoom :+ v
		If zoom < 0.5
			zoom = 0.5
		ElseIf zoom > 5.0
			zoom = 5.0
		EndIf
	End Method

FBEpyon

(Posted 2014) [#6]

Thank you so much for helping me out wit this..

I was pulling my hair out, I was getting their and then the zoom kept messing me up..

And Yes LOL .. I know I don't need all the selfs, My OCD kicks in and then I have to start adding them..

Once again thank you for all your help on this..

BTW the 2nd offset is to make up for the centering, I was trying to correct it so it zooms into the center of the screen

Regards,

FBEpyon